[gentoo-commits] repo/gentoo:master commit in: dev-python/autobahn/

["Michał Górny" <mgorny@gentoo.org>]

commit:     d9f721b901aa0e8688cafcd7c870a344979057cc
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Dec 14 08:09:06 2020 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Dec 14 08:21:43 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d9f721b9

dev-python/autobahn: Bump to 20.12.1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/autobahn/Manifest                |   1 +
 dev-python/autobahn/autobahn-20.12.1.ebuild | 104 ++++++++++++++++++++++++++++
 2 files changed, 105 insertions(+)

diff --git a/dev-python/autobahn/Manifest b/dev-python/autobahn/Manifest
index 7eca849b769..2b69a81c52c 100644
--- a/dev-python/autobahn/Manifest
+++ b/dev-python/autobahn/Manifest
@@ -1,2 +1,3 @@
+DIST autobahn-20.12.1.tar.gz 1269156 BLAKE2B ff763accde6a2929fd777364c926132b8317d80f137d67768bf192fb72f45597ac115824783f01debacc773dcc9a60325692ac420e55b6f67f4ebc2cdc6187ae SHA512 df7c7065e050efb5f315055c05aa9b4fcf8636e7208f17b583ed0823a071c6484adcf610308e83df3b5bbb91a4df19266e739abc8405e34483b1bf3d9f2c74c7
 DIST autobahn-20.4.3.tar.gz 938992 BLAKE2B 259d18f4aa46f7eaeac75811c1c193f3046aca5c5e37627d9ac62eeaa3dc944d05a8d87a558e241bdef56c799be4d89f65d4c8ee7c1a2be20f892896227eb5f9 SHA512 c34f29951b8f9ff5161851cf3a7e964de136f6091b0231a8e78e7fe74cb085077be5078cee352b2c27412d9aa4303de1eb85aa1890b4fb583575638a9c47c6fb
 DIST autobahn-20.7.1.tar.gz 1260579 BLAKE2B 925d148836348c068d179d4871267bf79c8c42d27cacc6be09cca11396dbd213a5b86344142df886d4ff69d1214a86b49900ca3552bcdb640377cb0d6af7d0f0 SHA512 e2c241194da90ada86a2804683cb063320f75a69b76ddc016349c11614e7f298619c2eeba4fcccb8f8d65d84375681fb339d9f92f94f45f1015f4f12fa0c39b0

diff --git a/dev-python/autobahn/autobahn-20.12.1.ebuild b/dev-python/autobahn/autobahn-20.12.1.ebuild
new file mode 100644
index 00000000000..3633e2beeaa
--- /dev/null
+++ b/dev-python/autobahn/autobahn-20.12.1.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+MY_P=${PN}-$(ver_rs 3 -)
+
+DESCRIPTION="WebSocket and WAMP for Twisted and Asyncio"
+HOMEPAGE="https://pypi.org/project/autobahn/
+	https://crossbar.io/autobahn/
+	https://github.com/crossbario/autobahn-python"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="crypt scram test xbr"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/cbor-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/cbor2-5.1.0[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-2.9.2[${PYTHON_USEDEP}]
+	>=dev-python/flatbuffers-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/lz4-0.7.0[${PYTHON_USEDEP}]
+	>=dev-python/msgpack-0.6.1[${PYTHON_USEDEP}]
+	>=dev-python/py-ubjson-0.8.4[${PYTHON_USEDEP}]
+	>=dev-python/snappy-0.5[${PYTHON_USEDEP}]
+	>=dev-python/twisted-20.3.0[${PYTHON_USEDEP}]
+	>=dev-python/txaio-20.4.1[${PYTHON_USEDEP}]
+	>=dev-python/ujson-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/wsaccel-0.6.2[${PYTHON_USEDEP}]
+	>=dev-python/zope-interface-3.6[${PYTHON_USEDEP}]
+	crypt? (
+		>=dev-python/pyopenssl-16.2.0[${PYTHON_USEDEP}]
+		>=dev-python/pynacl-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/pytrie-0.2[${PYTHON_USEDEP}]
+		>=dev-python/pyqrcode-1.1.0[${PYTHON_USEDEP}]
+		>=dev-python/service_identity-18.1.0[${PYTHON_USEDEP}]
+	)
+	scram? (
+		dev-python/cffi[${PYTHON_USEDEP}]
+		dev-python/argon2-cffi[${PYTHON_USEDEP}]
+		dev-python/passlib[${PYTHON_USEDEP}]
+	)
+	"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		>=dev-python/pynacl-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/pytrie-0.2[${PYTHON_USEDEP}]
+		>=dev-python/pyqrcode-1.1.0[${PYTHON_USEDEP}]
+	)"
+
+python_prepare_all() {
+	if use xbr ; then
+		eerror "***************"
+		eerror "Required xbr dependencies are incomplete in Gentoo."
+		eerror "So this functionality will not yet work"
+		eerror "Please file a bug if this feature is needed"
+		eerror "***************"
+	else
+		# remove xbr components
+		export AUTOBAHN_STRIP_XBR="True"
+	fi
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	echo "Testing all, cryptosign using twisted"
+	export USE_TWISTED=true
+	cd "${BUILD_DIR}"/lib || die
+	"${EPYTHON}" -m twisted.trial autobahn || die
+	unset USE_TWISTED
+	echo "RE-testing cryptosign and component_aio using asyncio"
+	export USE_ASYNCIO=true
+	py.test -v autobahn/wamp/test/test_cryptosign.py || die
+	py.test -v autobahn/wamp/test/test_component_aio.py || die
+	unset USE_ASYNCIO
+	rm -r .pytest_cache || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	# delete the dropin.cache so we don't have collisions if it exists
+	rm "${D}"/usr/lib*/python*/site-packages/twisted/plugins//dropin.cache > /dev/null
+}
+
+pkg_postinst() {
+	python_foreach_impl twisted-regen-cache || die
+}
+
+pkg_postrm() {
+	python_foreach_impl twisted-regen-cache || die
+}