[gentoo-commits] repo/gentoo:master commit in: app-admin/qtpass/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     d4cbbd4b2bd2b0f78b896ab451614d336d7e7dda
Author:     Vladimir Pavljuchenkov (SpiderX) <spiderx <AT> spiderx <DOT> dp <DOT> ua>
AuthorDate: Fri Dec  4 21:32:05 2020 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Thu Dec 10 07:30:59 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d4cbbd4b

app-admin/qtpass: fix metainfo install location

Closes: https://bugs.gentoo.org/744358
Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: Vladimir Pavljuchenkov <spiderx <AT> spiderx.dp.ua>
Closes: https://github.com/gentoo/gentoo/pull/18507
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 app-admin/qtpass/qtpass-1.3.2-r2.ebuild | 62 +++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)

diff --git a/app-admin/qtpass/qtpass-1.3.2-r2.ebuild b/app-admin/qtpass/qtpass-1.3.2-r2.ebuild
new file mode 100644
index 00000000000..68259ad478d
--- /dev/null
+++ b/app-admin/qtpass/qtpass-1.3.2-r2.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop qmake-utils virtualx
+
+DESCRIPTION="multi-platform GUI for pass, the standard unix password manager"
+HOMEPAGE="https://qtpass.org"
+SRC_URI="https://github.com/IJHack/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="test"
+
+RDEPEND="|| ( app-admin/pass app-admin/gopass )
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	net-misc/x11-ssh-askpass"
+DEPEND="${RDEPEND}
+	dev-qt/qtsvg:5
+	test? ( dev-qt/qttest:5 )"
+BDEPEND="dev-qt/linguist-tools:5"
+
+RESTRICT="!test? ( test )"
+
+S="${WORKDIR}/QtPass-${PV}"
+
+DOCS=( {CHANGELOG,CONTRIBUTING,FAQ,README}.md )
+
+src_prepare() {
+	default
+
+	if ! use test ; then
+		sed -i '/SUBDIRS += src /s/tests //' \
+			qtpass.pro || die "sed for qtpass.pro failed"
+	fi
+}
+
+src_configure() {
+	eqmake5 PREFIX="${D}"/usr
+}
+
+src_test() {
+	virtx default
+}
+
+src_install() {
+	default
+
+	insinto /usr/share/qtpass/translations
+	doins localization/*.qm
+
+	doman qtpass.1
+	domenu qtpass.desktop
+	newicon artwork/icon.png qtpass-icon.png
+	insinto /usr/share/metainfo
+	doins qtpass.appdata.xml
+}