[gentoo-commits] repo/gentoo:master commit in: dev-python/backports-zoneinfo/

["Michał Górny" <mgorny@gentoo.org>]

commit:     975ee4c1c32d120af3d0d4265f0fe4db0b817afd
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Dec  3 10:23:47 2020 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Dec  3 10:50:24 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=975ee4c1

dev-python/backports-zoneinfo: New backport, dep of Babel

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/backports-zoneinfo/Manifest             |  1 +
 .../backports-zoneinfo-0.2.1.ebuild                | 45 ++++++++++++++++++++++
 dev-python/backports-zoneinfo/metadata.xml         |  7 ++++
 3 files changed, 53 insertions(+)

diff --git a/dev-python/backports-zoneinfo/Manifest b/dev-python/backports-zoneinfo/Manifest
new file mode 100644
index 00000000000..7beb8440024
--- /dev/null
+++ b/dev-python/backports-zoneinfo/Manifest
@@ -0,0 +1 @@
+DIST zoneinfo-0.2.1.tar.gz 85385 BLAKE2B a6382560dbe8c4207c5a53971431497126a3bad7374580f4a67ffd1ffe5940701f13a09bc3a5ba4b729ab8d2484516ea2dc71131b7276f5339b1f60fc39c4ab1 SHA512 1f17ce34eef489dcd263665d58780ab54cf8aa83a601d31148bb4316e600f94d0af1d0baa1d6554d069c0801af906e21b9d5535db2bf76de32333820c61e2364

diff --git a/dev-python/backports-zoneinfo/backports-zoneinfo-0.2.1.ebuild b/dev-python/backports-zoneinfo/backports-zoneinfo-0.2.1.ebuild
new file mode 100644
index 00000000000..a801aa6a0fe
--- /dev/null
+++ b/dev-python/backports-zoneinfo/backports-zoneinfo-0.2.1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..8} pypy3 )
+inherit distutils-r1
+
+MY_P=${P#backports-}
+DESCRIPTION="Backport of the standard library zoneinfo module"
+HOMEPAGE="https://github.com/pganssle/zoneinfo/"
+SRC_URI="
+	https://github.com/pganssle/zoneinfo/archive/${PV}.tar.gz
+		-> ${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/importlib_resources[${PYTHON_USEDEP}]
+	' python3_6 pypy3)"
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/dataclasses[${PYTHON_USEDEP}]
+		' python3_6)
+		$(python_gen_cond_dep '
+			dev-python/importlib_metadata[${PYTHON_USEDEP}]
+		' python3_{6,7})
+		>=dev-python/hypothesis-5.7.0[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)"
+
+# pytest is used only for one skip, and requires unpackaged
+# pytest-subtests
+distutils_enable_tests unittest
+
+python_install() {
+	# avoid file collisions
+	rm "${BUILD_DIR}"/lib/backports/__init__.py || die
+	distutils-r1_python_install
+}

diff --git a/dev-python/backports-zoneinfo/metadata.xml b/dev-python/backports-zoneinfo/metadata.xml
new file mode 100644
index 00000000000..266e3f19ca5
--- /dev/null
+++ b/dev-python/backports-zoneinfo/metadata.xml
@@ -0,0 +1,7 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+</pkgmetadata>