[gentoo-commits] repo/gentoo:master commit in: games-arcade/jvgs/, profiles/

[gentoo-commits] repo/gentoo:master commit in: games-arcade/jvgs/, profiles/

[Marek Szuba]

commit:     1425df15e4d5c03d9218692708a0201680f04553
Author:     Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Sun Nov 29 23:28:35 2020 +0000
Commit:     Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Sun Nov 29 23:31:16 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1425df15

games-arcade/jvgs: migrate to lua-single.eclass

There is no test phase but I have confirmed that cmake correctly finds
lua5.1 (upstream CMakeLists.txt is locked to that particular version),
that the compilation uses -I/usr/include/lua5.1 and that the linking of
the executable uses -llua5.1.

Signed-off-by: Marek Szuba <marecki <AT> gentoo.org>

 games-arcade/jvgs/jvgs-0.5-r100.ebuild | 42 ++++++++++++++++++++++++++++++++++
 profiles/package.mask                  |  1 +
 2 files changed, 43 insertions(+)

diff --git a/games-arcade/jvgs/jvgs-0.5-r100.ebuild b/games-arcade/jvgs/jvgs-0.5-r100.ebuild
new file mode 100644
index 00000000000..cad51405476
--- /dev/null
+++ b/games-arcade/jvgs/jvgs-0.5-r100.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-1 )
+
+inherit cmake desktop lua-single
+
+DESCRIPTION="An open-source platform game with a sketched and minimalistic look"
+HOMEPAGE="http://jvgs.sourceforge.net/"
+SRC_URI="mirror://sourceforge/jvgs/${P}-src.tar.gz"
+
+LICENSE="WTFPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+RDEPEND="${LUA_DEPS}
+	media-libs/libsdl[video]
+	media-libs/sdl-mixer[vorbis]
+	media-libs/freetype:2
+	sys-libs/zlib:=
+	virtual/opengl"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-lang/swig"
+
+S=${WORKDIR}/${P}-src
+PATCHES=( "${FILESDIR}"/${PN}-0.5-fix-build-system.patch )
+
+src_install() {
+	dobin src/${PN}
+
+	insinto /usr/share/${PN}
+	doins -r main.lua resources
+
+	newicon resources/drawing.svg ${PN}.svg
+	make_desktop_entry ${PN} ${PN}
+
+	einstalldocs
+}

diff --git a/profiles/package.mask b/profiles/package.mask
index 6cce1d5fd6d..219353df675 100644
--- a/profiles/package.mask
+++ b/profiles/package.mask
@@ -548,6 +548,7 @@ dev-lua/luacrypto
 >=dev-lua/toluapp-1.0.93_p20190513-r100
 >=dev-util/geany-plugins-1.37-r100
 =games-action/minetest-5.3.0-r100
+>=games-arcade/jvgs-0.5-r100
 >=games-engines/love-0.7.2-r100:0.7
 >=games-engines/love-0.8.0-r100:0.8
 >=games-engines/love-11.3-r100:0