[gentoo-commits] repo/gentoo:master commit in: games-puzzle/xblockout/

[gentoo-commits] repo/gentoo:master commit in: games-puzzle/xblockout/

[Stefan Strogin]

commit:     56ef5bc1dfef2cfd2f27d8691fff510680b34c98
Author:     Alexey Sokolov <sokolov <AT> google <DOT> com>
AuthorDate: Sun Nov 22 22:34:37 2020 +0000
Commit:     Stefan Strogin <steils <AT> gentoo <DOT> org>
CommitDate: Tue Nov 24 19:14:41 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=56ef5bc1

games-puzzle/xblockout: fix build, bump EAPI

Closes: https://bugs.gentoo.org/710592
Package-Manager: Portage-3.0.8, Repoman-3.0.2
Signed-off-by: Alexey Sokolov <alexey+gentoo <AT> asokolov.org>
Signed-off-by: Stefan Strogin <steils <AT> gentoo.org>

 games-puzzle/xblockout/xblockout-1.1.6-r2.ebuild | 65 ++++++++++++++++++++++++
 1 file changed, 65 insertions(+)

diff --git a/games-puzzle/xblockout/xblockout-1.1.6-r2.ebuild b/games-puzzle/xblockout/xblockout-1.1.6-r2.ebuild
new file mode 100644
index 00000000000..914ab6d1ac1
--- /dev/null
+++ b/games-puzzle/xblockout/xblockout-1.1.6-r2.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools desktop flag-o-matic toolchain-funcs
+
+DESCRIPTION="X Window block dropping game in 3 Dimension"
+HOMEPAGE="http://perso.univ-lyon1.fr/thierry.excoffier/XBL/"
+SRC_URI="http://perso.univ-lyon1.fr/thierry.excoffier/XBL/xbl-${PV}.tar.gz"
+
+LICENSE="GPL-1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	x11-libs/libX11
+	x11-libs/libXext
+"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/xbl-${PV}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-font.patch
+)
+
+src_prepare() {
+	default
+	sed -i \
+		-e '/^CC/d' \
+		-e 's:-lm:-lm -lX11:' \
+		-e '/DGROUP_GID/d' \
+		-e 's:-g$:$(GENTOO_CFLAGS):' \
+		Makefile.in || die
+	# Don't know about other archs. --slarti
+	use amd64 && filter-flags "-fweb"
+
+	mv configure.in configure.ac || die
+	eautoreconf
+}
+
+src_compile() {
+	emake \
+		USE_SETGID= \
+		SCOREDIR="${EPREFIX}/usr/share/${PN}" \
+		RESOURCEDIR="${EPREFIX}/usr/share/${PN}" \
+		LDOPTIONS="${LDFLAGS}" \
+		GENTOO_CFLAGS="${CFLAGS}" \
+		CC="$(tc-getCC)"
+}
+
+src_install() {
+	newbin bl xbl
+
+	insinto /usr/share/${PN}
+	newins Xbl.ad Xbl
+
+	newman xbl.man xbl.6
+	dodoc README xbl-README
+	HTML_DOCS="*.html *.gif" einstalldocs
+
+	newicon xbl-game.gif ${PN}.gif
+	make_desktop_entry xbl XBlockOut /usr/share/pixmaps/${PN}.gif
+}

[gentoo-commits] repo/gentoo:master commit in: games-puzzle/xblockout/

[Stefan Strogin]

commit:     115c9995584faed1efb382954150558ba5cd7997
Author:     Alexey Sokolov <sokolov <AT> google <DOT> com>
AuthorDate: Sun Nov 22 22:35:21 2020 +0000
Commit:     Stefan Strogin <steils <AT> gentoo <DOT> org>
CommitDate: Tue Nov 24 19:14:50 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=115c9995

games-puzzle/xblockout: drop 1.1.6-r1

Package-Manager: Portage-3.0.8, Repoman-3.0.2
Signed-off-by: Alexey Sokolov <alexey+gentoo <AT> asokolov.org>
Closes: https://github.com/gentoo/gentoo/pull/18368
Signed-off-by: Stefan Strogin <steils <AT> gentoo.org>

 games-puzzle/xblockout/xblockout-1.1.6-r1.ebuild | 60 ------------------------
 1 file changed, 60 deletions(-)

diff --git a/games-puzzle/xblockout/xblockout-1.1.6-r1.ebuild b/games-puzzle/xblockout/xblockout-1.1.6-r1.ebuild
deleted file mode 100644
index 71a44a6d8c3..00000000000
--- a/games-puzzle/xblockout/xblockout-1.1.6-r1.ebuild
+++ /dev/null
@@ -1,60 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-inherit autotools desktop flag-o-matic
-
-DESCRIPTION="X Window block dropping game in 3 Dimension"
-HOMEPAGE="http://perso.univ-lyon1.fr/thierry.excoffier/XBL/"
-SRC_URI="http://perso.univ-lyon1.fr/thierry.excoffier/XBL/xbl-${PV}.tar.gz"
-
-LICENSE="GPL-1"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE=""
-
-RDEPEND="
-	x11-libs/libX11
-	x11-libs/libXext
-"
-DEPEND="${RDEPEND}"
-
-S="${WORKDIR}/xbl-${PV}"
-
-src_prepare() {
-	default
-	eapply "${FILESDIR}"/${P}-font.patch
-	sed -i \
-		-e '/^CC/d' \
-		-e 's:-lm:-lm -lX11:' \
-		-e '/DGROUP_GID/d' \
-		-e "s:-g$:${CFLAGS}:" \
-		Makefile.in || die
-	# Don't know about other archs. --slarti
-	use amd64 && filter-flags "-fweb"
-
-	mv configure.in configure.ac || die
-	eautoreconf
-}
-
-src_compile() {
-	emake \
-		USE_SETGID= \
-		SCOREDIR="/usr/share/${PN}" \
-		RESOURCEDIR="/usr/share/${PN}" \
-		LDOPTIONS="${LDFLAGS}"
-}
-
-src_install() {
-	newbin bl xbl
-
-	insinto /usr/share/${PN}
-	newins Xbl.ad Xbl
-
-	newman xbl.man xbl.6
-	dodoc README xbl-README
-	HTML_DOCS="*.html *.gif" einstalldocs
-
-	newicon xbl-game.gif ${PN}.gif
-	make_desktop_entry xbl XBlockOut /usr/share/pixmaps/${PN}.gif
-}