[gentoo-commits] repo/gentoo:master commit in: dev-lua/luv/

["Marek Szuba" <marecki@gentoo.org>]

commit:     3d7a21155571a2bf2a36df0ef1aeb527782f5d6a
Author:     Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Fri Nov 13 23:06:07 2020 +0000
Commit:     Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Fri Nov 13 23:08:36 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3d7a2115

dev-lua/luv: remove the lua-single prototype

Signed-off-by: Marek Szuba <marecki <AT> gentoo.org>

 dev-lua/luv/luv-1.32.0.0-r100.ebuild | 79 ------------------------------------
 1 file changed, 79 deletions(-)

diff --git a/dev-lua/luv/luv-1.32.0.0-r100.ebuild b/dev-lua/luv/luv-1.32.0.0-r100.ebuild
deleted file mode 100644
index 793fb2104a0..00000000000
--- a/dev-lua/luv/luv-1.32.0.0-r100.ebuild
+++ /dev/null
@@ -1,79 +0,0 @@
-# Copyright 2019-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-LUA_COMPAT=( lua5-{1..3} luajit )
-
-inherit cmake lua-single unpacker
-
-# e.g. MY_PV = a.b.c-d
-MY_PV="$(ver_rs 3 -)"
-MY_P="${PN}-${MY_PV}"
-
-DESCRIPTION="Bare libuv bindings for lua"
-HOMEPAGE="https://github.com/luvit/luv"
-
-LUA_COMPAT_PV="0.7"
-SRC_URI="
-	https://github.com/luvit/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz
-	https://github.com/keplerproject/lua-compat-5.3/archive/v${LUA_COMPAT_PV}.tar.gz -> ${PN}-lua-compat-${LUA_COMPAT_PV}.tar.gz
-"
-
-LICENSE="Apache-2.0 MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~x86"
-IUSE="test"
-RESTRICT="!test? ( test )"
-
-REQUIRED_USE="${LUA_REQUIRED_USE}"
-
-BDEPEND="virtual/pkgconfig"
-DEPEND="${LUA_DEPS}
-	>=dev-libs/libuv-1.32.0:="
-RDEPEND="${DEPEND}"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-1.32.0.0-cmake_lua_version.patch
-)
-
-S="${WORKDIR}/${MY_P}"
-
-src_prepare() {
-	# Fix libdir
-	# Match '/lib/' and '/lib"' without capturing / or ", replacing with libdir
-	sed -i -r "s/\/lib(\"|\/)/\/$(get_libdir)\1/g" CMakeLists.txt || die "Failed to sed CMakeLists.txt"
-	cmake_src_prepare
-}
-
-# TODO: try to make this multi-impl. Will need at least:
-#  - per-implementation install dirs for headers and the library
-#  - versioned .pc files (which may or may not break revdeps)
-src_configure() {
-	lua_compat_dir="${WORKDIR}/lua-compat-5.3-${LUA_COMPAT_PV}"
-
-	local mycmakeargs=(
-		-DBUILD_MODULE=OFF
-		-DLUA_BUILD_TYPE=System
-		-DLUA_COMPAT53_DIR="${lua_compat_dir}"
-		-DWITH_SHARED_LIBUV=ON
-	)
-	if [[ ${ELUA} == luajit ]]; then
-		mycmakeargs+=(
-			-DWITH_LUA_ENGINE=LuaJIT
-		)
-	else
-		mycmakeargs+=(
-			-DWITH_LUA_ENGINE=Lua
-			-DLUA_VERSION=$(ver_cut 1-2 $(lua_get_version))
-		)
-	fi
-
-	cmake_src_configure
-}
-
-src_test() {
-	# We need to copy the library back so that the tests see it
-	ln -s "${BUILD_DIR}/libluv.so" "./luv.so" || die "Failed to symlink library for tests"
-	${ELUA} "tests/run.lua" || die "Tests failed"
-}