From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1220864-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 16BBF138359
for <garchives@archives.gentoo.org>; Mon, 9 Nov 2020 01:06:54 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id C1119E079E;
Mon, 9 Nov 2020 01:06:52 +0000 (UTC)
Received: from smtp.gentoo.org (mail.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 9B3A5E079E
for <gentoo-commits@lists.gentoo.org>; Mon, 9 Nov 2020 01:06:51 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id A14B0335DAF
for <gentoo-commits@lists.gentoo.org>; Mon, 9 Nov 2020 01:06:46 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 50C9A3C7
for <gentoo-commits@lists.gentoo.org>; Mon, 9 Nov 2020 01:06:45 +0000 (UTC)
From: "Georgy Yakovlev" <gyakovlev@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Georgy Yakovlev" <gyakovlev@gentoo.org>
Message-ID: <1604883965.023537dc0c603d0811825c38407c415e137adcfd.gyakovlev@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: net-mail/notmuch/
X-VCS-Repository: repo/gentoo
X-VCS-Files: net-mail/notmuch/Manifest net-mail/notmuch/notmuch-0.31.2.ebuild
X-VCS-Directories: net-mail/notmuch/
X-VCS-Committer: gyakovlev
X-VCS-Committer-Name: Georgy Yakovlev
X-VCS-Revision: 023537dc0c603d0811825c38407c415e137adcfd
X-VCS-Branch: master
Date: Mon, 9 Nov 2020 01:06:45 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: b12e667e-ec1a-4b68-be71-8fd12962d000
X-Archives-Hash: d34ac7c835256f4779fa3fc9b56aab58
commit: 023537dc0c603d0811825c38407c415e137adcfd
Author: Georgy Yakovlev <gyakovlev <AT> gentoo <DOT> org>
AuthorDate: Mon Nov 9 01:05:06 2020 +0000
Commit: Georgy Yakovlev <gyakovlev <AT> gentoo <DOT> org>
CommitDate: Mon Nov 9 01:06:05 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=023537dc
net-mail/notmuch: bump to 0.31.2
crypt tests fixed
Bug: https://bugs.gentoo.org/749969
Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: Georgy Yakovlev <gyakovlev <AT> gentoo.org>
net-mail/notmuch/Manifest | 1 +
net-mail/notmuch/notmuch-0.31.2.ebuild | 277 +++++++++++++++++++++++++++++++++
2 files changed, 278 insertions(+)
diff --git a/net-mail/notmuch/Manifest b/net-mail/notmuch/Manifest
index 734ae5657a7..9456c2345c8 100644
--- a/net-mail/notmuch/Manifest
+++ b/net-mail/notmuch/Manifest
@@ -1,4 +1,5 @@
DIST database-v1.tar.xz 204876 BLAKE2B 846a8d2f17edb61ed1c3d3c655becd1f60b4046772058706f13d516f65421a5105593660f1c556907bb2bb9607a3c2521243d1be07bffb70817ad3b8461680ca SHA512 e2d87373e00b65756d7fea40c54fb236d7a37ce839145c3afd99ab26efdc17796e540c021e2c24e521df2d0a01ccbf918994f87a0d83235ff9b109a51555b3d0
DIST notmuch-0.29.3.tar.xz 660536 BLAKE2B bd5d62eba06102acbc0615cd97ac9ff5578c1f68d50b24a79ea9fb1ea77850d84e0713fb648cb04e74a61ac3321ea5ef82db714786adf38ea10d00c5846decff SHA512 b1e0b47ebf2d2de0ccd39976782eb8a7b417e36f2f9d78ef19e27e55719a02ee919508843a0eaf258f58138914ab2e8796d2fc1782b9cfe2d8937abb6184be65
DIST notmuch-0.30.tar.xz 711904 BLAKE2B fb1523f3939b78797e448e804fc52c4fe1e4e8ff87b346917488d3911027b9ccb67b9fddf611f0e960fd1e158463cbe005e038f31bb54549e2a922926dd512bd SHA512 a5c812eb141c293c61b5483eafd31d3e3ab19b2c84429a1558986c415d30ead4afa79db64b2672e9549a40f5eb4c69e54ea5ccccbeeaeb9c783051c3f965a65e
+DIST notmuch-0.31.2.tar.xz 713388 BLAKE2B 20029f55206b66e7956316fca2d16ae53a49fc196ea2e730ae5ebd96ce893fa2065b7eee9b625629bbb0d3816a70d98e8943920cf8895ef81a97a1d8dc59dd62 SHA512 b134ef79648cb6fe9f17b2f1b600d651d57359ae9fa576c808b794aa64a09955f0597a624cc3c498da4ef56e44bca6bb485bc402c2dff48cd000959f9a9ceeaa
DIST notmuch-0.31.tar.xz 713144 BLAKE2B 91b0a01543e438e6ccb40a01ad0a100a5c6ae15fe832bb29367d4bc288dae5a915f89a743ecee814041caf53430e2593cb4b5f69faaec396ad6dacfe8cc67d2f SHA512 928acc07b9dbed4275e7d39d94202bea7685e9d433a7bf4c07e40e191ed4fe8cf15ac04c18792e46f4605ffac548b942998005d8176a58ad76c82d4085a408e5
diff --git a/net-mail/notmuch/notmuch-0.31.2.ebuild b/net-mail/notmuch/notmuch-0.31.2.ebuild
new file mode 100644
index 00000000000..bf63e1d7f55
--- /dev/null
+++ b/net-mail/notmuch/notmuch-0.31.2.ebuild
@@ -0,0 +1,277 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_OPTIONAL=1
+NEED_EMACS="24.1"
+PYTHON_COMPAT=( python3_{6,7,8,9} pypy3 )
+
+inherit bash-completion-r1 desktop distutils-r1 elisp-common eutils flag-o-matic pax-utils toolchain-funcs xdg-utils
+
+DESCRIPTION="Thread-based e-mail indexer, supporting quick search and tagging"
+HOMEPAGE="https://notmuchmail.org/"
+SRC_URI="https://notmuchmail.org/releases/${P}.tar.xz
+ test? ( https://notmuchmail.org/releases/test-databases/database-v1.tar.xz )"
+
+LICENSE="GPL-3"
+# Sub-slot corresponds to major wersion of libnotmuch.so.X.Y. Bump of Y is
+# meant to be binary backward compatible.
+SLOT="0/5"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ppc64 ~x86"
+REQUIRED_USE="
+ apidoc? ( doc )
+ nmbug? ( python )
+ python? ( ${PYTHON_REQUIRED_USE} )
+ test? ( crypt emacs python valgrind )
+"
+IUSE="apidoc crypt doc emacs mutt nmbug python test valgrind"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+ virtual/pkgconfig
+ apidoc? (
+ app-doc/doxygen
+ dev-lang/perl
+ )
+ doc? (
+ dev-python/sphinx
+ sys-apps/texinfo
+ )
+ python? ( dev-python/pytest[${PYTHON_USEDEP}] )
+"
+
+COMMON_DEPEND="
+ dev-libs/glib
+ dev-libs/gmime:3.0[crypt]
+ >=dev-libs/xapian-1.4.0:=
+ sys-libs/talloc
+ sys-libs/zlib:=
+ emacs? ( >=app-editors/emacs-${NEED_EMACS}:* )
+ python? (
+ ${PYTHON_DEPS}
+ virtual/python-cffi[${PYTHON_USEDEP}]
+ )
+"
+
+DEPEND="${COMMON_DEPEND}
+ test? (
+ >=app-editors/emacs-${NEED_EMACS}:*[libxml2]
+ app-misc/dtach
+ sys-devel/gdb
+ crypt? (
+ app-crypt/gnupg
+ dev-libs/openssl
+ )
+ )
+ valgrind? ( dev-util/valgrind )
+"
+
+RDEPEND="${COMMON_DEPEND}
+ crypt? ( app-crypt/gnupg )
+ mutt? (
+ dev-perl/File-Which
+ dev-perl/Mail-Box
+ dev-perl/MailTools
+ dev-perl/String-ShellQuote
+ dev-perl/Term-ReadLine-Gnu
+ virtual/perl-Digest-SHA
+ virtual/perl-File-Path
+ virtual/perl-Getopt-Long
+ virtual/perl-Pod-Parser
+ )
+ nmbug? ( dev-vcs/git )
+"
+
+SITEFILE="50${PN}-gentoo.el"
+
+pkg_setup() {
+ use emacs && elisp-check-emacs-version
+}
+
+src_unpack() {
+ unpack "${P}".tar.xz
+ if use test; then
+ mkdir -p "${S}"/test/test-databases || die
+ cp "${DISTDIR}"/database-v1.tar.xz "${S}"/test/test-databases/ || die
+ fi
+}
+
+src_prepare() {
+ default
+
+ use python && distutils-r1_src_prepare
+
+ mv contrib/notmuch-mutt/README contrib/notmuch-mutt/README-mutt || die
+
+ # Override 'install' target, we want to install manpages with doman, but let it install texinfo files.
+ sed -i "s/all install-man install-info/all $(usex doc install-info '')/" "Makefile.local" || die
+
+ use test && append-flags '-g'
+
+ # Non-autoconf configure
+ [[ ${CHOST} == *-solaris* ]] && append-ldflags '-lnsl' '-lsocket'
+}
+
+src_configure() {
+ python_setup # For sphinx
+
+ tc-export CC CXX
+
+ local myconf=(
+ --bashcompletiondir="$(get_bashcompdir)"
+ --emacslispdir="${EPREFIX}/${SITELISP}/${PN}"
+ --emacsetcdir="${EPREFIX}/${SITEETC}/${PN}"
+ --without-desktop
+ --without-ruby
+ --zshcompletiondir="${EPREFIX}/usr/share/zsh/site-functions"
+ $(use_with apidoc api-docs)
+ $(use_with doc docs)
+ $(use_with emacs)
+ )
+
+ econf "${myconf[@]}"
+}
+
+python_compile() {
+ pushd bindings/python-cffi > /dev/null || die
+ distutils-r1_python_compile
+ popd > /dev/null || die
+
+ # TODO: we want to drop those, research revdeps
+ pushd bindings/python > /dev/null || die
+ distutils-r1_python_compile
+ popd > /dev/null || die
+}
+
+python_compile_all() {
+ use doc && emake -C bindings/python/docs html
+}
+
+src_compile() {
+ python_setup # For sphinx
+
+ # prevent race in emacs doc generation
+ # FileNotFoundError: [Errno 2] No such file or directory: '..work/notmuch-0.31/emacs/notmuch.rsti'
+ if use emacs; then
+ use doc && emake -j1 -C emacs docstring.stamp V=1 #nowarn
+ fi
+
+ emake V=1
+
+ use python && distutils-r1_src_compile
+
+ if use mutt; then
+ pushd contrib/notmuch-mutt > /dev/null || die
+ emake notmuch-mutt.1
+ popd > /dev/null || die
+ fi
+}
+
+python_test() {
+ # we only have tests for cffi bindings
+ pushd bindings/python-cffi > /dev/null || die
+ rm -f tox.ini || die
+ pytest -vv || die "Tests failed with ${EPYTHON}"
+ popd > /dev/null || die
+}
+
+src_test() {
+ local test_failures=()
+ pax-mark -m notmuch
+
+ # NOTMUCH_TEST_SERIALIZE is needed to avoid using gnu parallel (if it's installed)
+ NOTMUCH_TEST_SERIALIZE=1 \
+ LD_LIBRARY_PATH="${S}/lib" \
+ nonfatal emake test V=1 OPTIONS="--verbose --tee" || test_failures+=( "'emake tests'" )
+
+ pax-mark -ze notmuch
+
+ # both lib and bin needed for testsuite.
+ if use python; then
+ LD_LIBRARY_PATH="${S}/lib" \
+ PATH="${S}:${PATH}" \
+ nonfatal distutils-r1_src_test || test_failures+=( "'python tests'" )
+ fi
+
+ [[ ${test_failures} ]] && die "Tests failed: ${test_failures[@]}"
+}
+
+python_install() {
+ pushd bindings/python-cffi > /dev/null || die
+ distutils-r1_python_install
+ popd > /dev/null || die
+
+ pushd bindings/python > /dev/null || die
+ distutils-r1_python_install
+ popd > /dev/null || die
+}
+
+src_install() {
+ default
+
+ if use doc; then
+ pushd doc/_build/man/man1 > /dev/null || die
+ ln notmuch.1 notmuch-setup.1 || die
+ popd > /dev/null || die
+ if use apidoc; then
+ # rename overly generic manpage to avoid clashes
+ mv doc/_build/man/man3/deprecated.3 \
+ doc/_build/man/man3/notmuch-deprecated.3 || die
+ fi
+ doman doc/_build/man/man?/*.?
+ fi
+
+ if use emacs; then
+ elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die
+ domenu emacs/notmuch-emacs-mua.desktop
+ fi
+
+ if use nmbug; then
+ python_fix_shebang devel/nmbug/{nmbug,notmuch-report}
+ dobin devel/nmbug/{nmbug,notmuch-report}
+ fi
+
+ if use mutt; then
+ pushd contrib/notmuch-mutt > /dev/null || die
+ dobin notmuch-mutt
+ # this manpage is built by pod2man
+ doman notmuch-mutt.1
+ insinto /etc/mutt
+ doins notmuch-mutt.rc
+ dodoc README-mutt
+ popd > /dev/null || die
+ fi
+
+ local DOCS=( README{,.rst} INSTALL NEWS )
+ einstalldocs
+
+ if use python; then
+ use doc && local HTML_DOCS=( bindings/python/docs/html/. )
+ distutils-r1_src_install
+ fi
+}
+
+pkg_preinst() {
+ local _rcfile="/etc/mutt/notmuch-mutt.rc"
+ if use mutt && ! [[ -e ${ROOT}${_rcfile} ]]; then
+ elog "To enable notmuch support in mutt, add the following line"
+ elog "to your mutt config file:"
+ elog ""
+ elog " source ${_rcfile}"
+ fi
+}
+
+pkg_postinst() {
+ if use emacs; then
+ elisp-site-regen
+ xdg_desktop_database_update
+ fi
+}
+
+pkg_postrm() {
+ if use emacs; then
+ elisp-site-regen
+ xdg_desktop_database_update
+ fi
+}