[gentoo-commits] repo/gentoo:master commit in: dev-libs/json-glib/

["Matt Turner" <mattst88@gentoo.org>]

commit:     6900461fbe8242f73c683988aafad1e7b05accb9
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sun Nov  8 03:22:49 2020 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sun Nov  8 03:50:40 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6900461f

dev-libs/json-glib: Version bump to 1.6.0

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-libs/json-glib/Manifest               |  1 +
 dev-libs/json-glib/json-glib-1.6.0.ebuild | 58 +++++++++++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/dev-libs/json-glib/Manifest b/dev-libs/json-glib/Manifest
index 3318e9c31da..7af3068001a 100644
--- a/dev-libs/json-glib/Manifest
+++ b/dev-libs/json-glib/Manifest
@@ -1 +1,2 @@
 DIST json-glib-1.4.4.tar.xz 165584 BLAKE2B 0cdb518cd139b8dbdbf31c9bc00ddedca6385d7132843455a7898f3544fb43b62d6626d49944e83ef10ab9a555cf21c7e4548df7d784bcb4020f4026e0f3045e SHA512 cf56a99dce3938b5c0075810f105719836fac65392da33a49b26ebf33aee1fab89ca9fac58059a2008d688ecc75a3e524de60621a5b027d566963541f38b971f
+DIST json-glib-1.6.0.tar.xz 168648 BLAKE2B 45a323b49cb7e9b3b37fdceb0bd95585663983acee82fa8a54afb2c817e9b86332dd94775db0be81e7ff25cfd56515816487275165889f44fef918250b71115b SHA512 0025f913c54a223e6c5f7e65c081afc8ea65ab5a30ed9f30d2d2bb28d17c5695f6e308c64dfdf128e47ddc99d3178421204b5273e78305a096c0b7dfe67dd406

diff --git a/dev-libs/json-glib/json-glib-1.6.0.ebuild b/dev-libs/json-glib/json-glib-1.6.0.ebuild
new file mode 100644
index 00000000000..3723a06a554
--- /dev/null
+++ b/dev-libs/json-glib/json-glib-1.6.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit gnome.org meson multilib-minimal xdg-utils
+
+DESCRIPTION="Library providing GLib serialization and deserialization for the JSON format"
+HOMEPAGE="https://wiki.gnome.org/Projects/JsonGlib"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
+IUSE="gtk-doc +introspection"
+
+RDEPEND="
+	>=dev-libs/glib-2.54.0:2[${MULTILIB_USEDEP}]
+	introspection? ( >=dev-libs/gobject-introspection-0.9.5:= )
+"
+DEPEND="${RDEPEND}"
+# TODO: Can we use a newer docbook-xml-dtd, or is one needed at all?
+BDEPEND="
+	~app-text/docbook-xml-dtd-4.1.2
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+	dev-util/glib-utils
+	gtk-doc? ( >=dev-util/gtk-doc-1.20 )
+	>=sys-devel/gettext-0.18
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	xdg_environment_reset
+	default
+	# Disable installed-tests; this also indirectly removes build_aux/gen-installed-test.py calls, thus not needing python-any-r1.eclass
+	sed -e 's/install: true/install: false/g' -i json-glib/tests/meson.build || die
+	sed -e '/install_data/d' -i json-glib/tests/meson.build || die
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Dintrospection=$(multilib_native_usex introspection enabled disabled)
+		-Ddocs=$(multilib_native_usex gtk-doc enabled disabled)
+		-Dman=true
+	)
+	meson_src_configure
+}
+
+multilib_src_compile() {
+	meson_src_compile
+}
+
+multilib_src_install() {
+	meson_src_install
+}
+
+multilib_src_test() {
+	meson_src_test
+}