[gentoo-commits] proj/kde:master commit in: kde-frameworks/plasma/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     423b90401a8fed2ce1f00d26f0631b49621e6b81
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Nov  7 21:12:36 2020 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Nov  7 21:12:36 2020 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=423b9040

kde-frameworks/plasma: 5.76.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-frameworks/plasma/plasma-5.76.0.ebuild | 74 ++++++++++++++++++++++++++++++
 1 file changed, 74 insertions(+)

diff --git a/kde-frameworks/plasma/plasma-5.76.0.ebuild b/kde-frameworks/plasma/plasma-5.76.0.ebuild
new file mode 100644
index 0000000000..3e2958b666
--- /dev/null
+++ b/kde-frameworks/plasma/plasma-5.76.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_ORG_NAME="${PN}-framework"
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.15.1
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Plasma framework"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="gles2-only wayland X"
+
+BDEPEND="
+	>=kde-frameworks/kdoctools-${PVCUT}:5
+"
+RDEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5[gles2-only=]
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	=kde-frameworks/kactivities-${PVCUT}*:5
+	=kde-frameworks/karchive-${PVCUT}*:5
+	=kde-frameworks/kconfig-${PVCUT}*:5
+	=kde-frameworks/kconfigwidgets-${PVCUT}*:5
+	=kde-frameworks/kcoreaddons-${PVCUT}*:5
+	=kde-frameworks/kdeclarative-${PVCUT}*:5
+	=kde-frameworks/kglobalaccel-${PVCUT}*:5
+	=kde-frameworks/kguiaddons-${PVCUT}*:5
+	=kde-frameworks/ki18n-${PVCUT}*:5
+	=kde-frameworks/kiconthemes-${PVCUT}*:5
+	=kde-frameworks/kio-${PVCUT}*:5
+	=kde-frameworks/kirigami-${PVCUT}*:5
+	=kde-frameworks/knotifications-${PVCUT}*:5
+	=kde-frameworks/kpackage-${PVCUT}*:5
+	=kde-frameworks/kservice-${PVCUT}*:5
+	=kde-frameworks/kwidgetsaddons-${PVCUT}*:5
+	=kde-frameworks/kwindowsystem-${PVCUT}*:5
+	=kde-frameworks/kxmlgui-${PVCUT}*:5
+	!gles2-only? ( virtual/opengl )
+	wayland? (
+		=kde-frameworks/kwayland-${PVCUT}*:5
+		media-libs/mesa[egl]
+	)
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libX11
+		x11-libs/libxcb
+	)
+"
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )
+"
+
+RESTRICT+=" test"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package !gles2-only OpenGL)
+		$(cmake_use_find_package wayland EGL)
+		$(cmake_use_find_package wayland KF5Wayland)
+		$(cmake_use_find_package X X11)
+		$(cmake_use_find_package X XCB)
+	)
+
+	ecm_src_configure
+}