[gentoo-commits] repo/gentoo:master commit in: sys-fs/squashfs-tools/

["Michał Górny" <mgorny@gentoo.org>]

commit:     03590fb6c619d2c5e1c1d27be8afb550d6b9c7b3
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Nov  7 08:29:06 2020 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Nov  7 08:38:50 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=03590fb6

sys-fs/squashfs-tools: Clean the ebuild up

Remove USE=static.  Remove redundant USE=xz in favor of toggling both
LZMA variants via USE=lzma; they both have the same dependency anyway.
Remove obsolete gcc-5 hack.

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 sys-fs/squashfs-tools/squashfs-tools-4.4-r1.ebuild | 55 ++++++++++++++++++++++
 1 file changed, 55 insertions(+)

diff --git a/sys-fs/squashfs-tools/squashfs-tools-4.4-r1.ebuild b/sys-fs/squashfs-tools/squashfs-tools-4.4-r1.ebuild
new file mode 100644
index 00000000000..f330af3c97a
--- /dev/null
+++ b/sys-fs/squashfs-tools/squashfs-tools-4.4-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit flag-o-matic toolchain-funcs
+
+DESCRIPTION="tools to create and extract Squashfs filesystems"
+HOMEPAGE="https://github.com/plougher/squashfs-tools"
+SRC_URI="https://github.com/plougher/squashfs-tools/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="debug lz4 lzma lzo xattr zstd"
+
+RDEPEND="
+	sys-libs/zlib
+	lz4? ( app-arch/lz4 )
+	lzma? ( app-arch/xz-utils )
+	lzo? ( dev-libs/lzo )
+	xattr? ( sys-apps/attr )
+	zstd? ( app-arch/zstd )
+"
+DEPEND=${RDEPEND}
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.4-fno-common.patch
+)
+
+use10() { usex "${1}" 1 0; }
+
+src_configure() {
+	# set up make command line variables in EMAKE_SQUASHFS_CONF
+	EMAKE_SQUASHFS_CONF=(
+		LZMA_XZ_SUPPORT=$(use10 lzma)
+		LZO_SUPPORT=$(use10 lzo)
+		LZ4_SUPPORT=$(use10 lz4)
+		XATTR_SUPPORT=$(use10 xattr)
+		XZ_SUPPORT=$(use10 lzma)
+		ZSTD_SUPPORT=$(use10 zstd)
+	)
+
+	tc-export CC
+	use debug && append-cppflags -DSQUASHFS_TRACE
+}
+
+src_compile() {
+	emake "${EMAKE_SQUASHFS_CONF[@]}" -C squashfs-tools
+}
+
+src_install() {
+	dobin squashfs-tools/{mksquashfs,unsquashfs}
+	dodoc ACKNOWLEDGEMENTS CHANGES README*
+	dodoc -r RELEASE-READMEs
+}