[gentoo-commits] repo/gentoo:master commit in: net-proxy/mitmproxy/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     d95bff3e80263a6351519fa03cd7d4d0f1536a2e
Author:     Matt Smith <matt <AT> offtopica <DOT> uk>
AuthorDate: Sun Nov  1 19:44:31 2020 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Thu Nov  5 12:32:03 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d95bff3e

net-proxy/mitmproxy: Bump to 5.3.0

Package-Manager: Portage-3.0.8, Repoman-3.0.2
Signed-off-by: Matt Smith <matt <AT> offtopica.uk>
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 net-proxy/mitmproxy/Manifest               |  1 +
 net-proxy/mitmproxy/mitmproxy-5.3.0.ebuild | 93 ++++++++++++++++++++++++++++++
 2 files changed, 94 insertions(+)

diff --git a/net-proxy/mitmproxy/Manifest b/net-proxy/mitmproxy/Manifest
index 9d905274683..e6a7ffdb534 100644
--- a/net-proxy/mitmproxy/Manifest
+++ b/net-proxy/mitmproxy/Manifest
@@ -1,2 +1,3 @@
 DIST mitmproxy-5.1.1.tar.gz 27223155 BLAKE2B 38369eb07c41bde9f8e8c246ab5cc4fc6edfcd222f353624f4d2ae193f176228471aafdadd1b65238ccd808d778a69e1d140035be9116b87a75c286493747fe8 SHA512 ac5cd82d4d89590b57625661c493aca6a702605c612ea1acd9e0d0806067d47f60085ee68260bba2a10dc343410ae6a76ea1575287a0e312e4467a4e8485c6e1
 DIST mitmproxy-5.2.tar.gz 27251381 BLAKE2B d6bc5de8a3840a880664f52e011736cb640d324c6aa3846d4f2b3c2fc0d49467ab8ad3e8268a591cbe19d9f6dda5acc37fa2de705b4de1c1920b5003e10ea457 SHA512 6073c73b24618d6f64c4e99f199ebb6bc4157a3f83bfa7aff10a113f8dde823715e95bdf4202a1526dc0856d120858d32842b814327c3b98452b629fccb1790d
+DIST mitmproxy-5.3.0.tar.gz 27272534 BLAKE2B 2a35824616ca0a63a9e432a110adf14423df229568636456aa9d3959fc306b9ba30d8069c78cbc7c5950ef3e44526882b028c6ed05af417ef667b07215c258c6 SHA512 3f52f5285869de49c7c04ef9b6c0f3ef66689eb45fb6f9e971111049bf1aa0777e3e84b51f7031c1bdf105ce3f17fa4b03036d72617985b92996c6eea7566c38

diff --git a/net-proxy/mitmproxy/mitmproxy-5.3.0.ebuild b/net-proxy/mitmproxy/mitmproxy-5.3.0.ebuild
new file mode 100644
index 00000000000..4b2fbaf868f
--- /dev/null
+++ b/net-proxy/mitmproxy/mitmproxy-5.3.0.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{7,8,9} )
+PYTHON_REQ_USE="sqlite"
+inherit distutils-r1
+
+DESCRIPTION="An interactive, SSL-capable, man-in-the-middle HTTP proxy"
+HOMEPAGE="https://mitmproxy.org/"
+SRC_URI="https://github.com/mitmproxy/mitmproxy/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="
+	>=app-arch/brotli-1.0.0[python,${PYTHON_USEDEP}]
+	>=dev-python/asgiref-3.2.10[${PYTHON_USEDEP}]
+	>=dev-python/blinker-1.4[${PYTHON_USEDEP}]
+	>=dev-python/certifi-2015.11.20.1[${PYTHON_USEDEP}]
+	>=dev-python/click-6.2[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-2.9[${PYTHON_USEDEP}]
+	>=dev-python/flask-1.0.4[${PYTHON_USEDEP}]
+	>=dev-python/hyper-h2-3.0.1[${PYTHON_USEDEP}]
+	>=dev-python/hyperframe-5.1.0[${PYTHON_USEDEP}]
+	>=dev-python/kaitaistruct-0.7[${PYTHON_USEDEP}]
+	>=dev-python/ldap3-2.8[${PYTHON_USEDEP}]
+	>=dev-python/msgpack-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/passlib-1.6.5[${PYTHON_USEDEP}]
+	>=dev-python/protobuf-python-3.6.0[${PYTHON_USEDEP}]
+	>=dev-python/publicsuffix-2.20190205[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-0.3.1[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-19.1[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-2.4.2[${PYTHON_USEDEP}]
+	>=dev-python/pyperclip-1.6.0[${PYTHON_USEDEP}]
+	>=dev-python/ruamel-yaml-0.16[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.1.1[${PYTHON_USEDEP}]
+	>=www-servers/tornado-4.3[${PYTHON_USEDEP}]
+	>=dev-python/urwid-2.1.1[${PYTHON_USEDEP}]
+	>=dev-python/wsproto-0.14.0[${PYTHON_USEDEP}]
+	>=dev-python/zstandard-0.11.0[${PYTHON_USEDEP}]
+"
+
+DEPEND="${RDEPEND}
+	test? (
+		>=dev-python/flask-1.0[${PYTHON_USEDEP}]
+		>=dev-python/hypothesis-4.50.8[${PYTHON_USEDEP}]
+		>=dev-python/parver-0.1[${PYTHON_USEDEP}]
+		>=dev-python/pytest-3.3[${PYTHON_USEDEP}]
+		>=dev-python/pytest-asyncio-0.10.0[${PYTHON_USEDEP}]
+		>=dev-python/requests-2.9.1[${PYTHON_USEDEP}]
+		>=dev-python/zstandard-0.8.1[${PYTHON_USEDEP}]
+	)"
+
+RESTRICT="!test? ( test )"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# loosen dependencies
+	sed -i \
+		-e '/>/s/>.*/",/g' \
+		-e '/urwid/s/==2\.0\.1,!=2\.1\.0//' \
+		setup.py || die
+
+	# remove failing test
+	sed -i 's/test_get_version/_&/g' test/mitmproxy/test_version.py || die
+
+	# https://github.com/mitmproxy/mitmproxy/issues/4136
+	# https://bugs.gentoo.org/740336
+	rm test/mitmproxy/addons/test_termlog.py || die
+
+	# requires asynctest
+	rm test/mitmproxy/addons/test_readfile.py || die
+
+	# Passes with OpenSSL 1.1.1g, fails with OpenSSL 1.1.1h
+	# https://github.com/gentoo/gentoo/pull/17411#discussion_r497270699
+	sed \
+		-e 's/test_mode_none_should_pass_without_sni/_&/g' \
+		-e 's/test_mode_strict_w_pemfile_should_pass/_&/g' \
+		-e 's/test_mode_strict_w_confdir_should_pass/_&/g' \
+		-i test/mitmproxy/net/test_tcp.py || die
+	sed \
+		-e 's/test_verification_w_confdir/_&/g' \
+		-e 's/test_verification_w_pemfile/_&/g' \
+		-i test/mitmproxy/proxy/test_server.py || die
+
+	distutils-r1_python_prepare_all
+}