[gentoo-commits] repo/gentoo:master commit in: sys-apps/fwupd/

["Lars Wendler" <polynomial-c@gentoo.org>]

commit:     b990ca0e7bbce015adc56b4cdc45eab8b3696014
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Tue Nov  3 09:52:50 2020 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Tue Nov  3 09:54:11 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b990ca0e

sys-apps/fwupd: Bump to version 1.5.1

Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 sys-apps/fwupd/Manifest           |   1 +
 sys-apps/fwupd/fwupd-1.5.1.ebuild | 159 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 160 insertions(+)

diff --git a/sys-apps/fwupd/Manifest b/sys-apps/fwupd/Manifest
index a46efc5fdce..a371645ae15 100644
--- a/sys-apps/fwupd/Manifest
+++ b/sys-apps/fwupd/Manifest
@@ -2,3 +2,4 @@ DIST fwupd-1.3.10.tar.gz 2255394 BLAKE2B 39f517b7648236f39df6f41b5950fcba45a1184
 DIST fwupd-1.3.11.tar.gz 2255359 BLAKE2B 0f91c32602459d31e53c63647762307cfe2313c553e16836cc646eb04e3ac54ebd53d2e8615afb7f43b8cd79b7e6315ed688ae04b57de851be62ed6065579ebf SHA512 e300a84a1c2d7e44e2a1d5d86300487783fc3990b20b540065f9899705569bee8996eae951f32b6fac559e76955ff9b661aa9b181e4dc0211a33a514613ffddd
 DIST fwupd-1.4.5.tar.gz 2318208 BLAKE2B 1e46137f5b72ff104d920771e54e3123bd0665cafd20c75327682a7e4284be93f8e284947db91892c29a153803013bab8ac45e5a0263fcda33b7491c53dd5558 SHA512 47eb40e8d84dc49af783b661db0fce0fb800c4581929becffb03b79c41ed8bfb0987f40fbb8262292b24af85b7f91978a6979ea7458058ee2bfc1a4353d0bd31
 DIST fwupd-1.4.6.tar.gz 2368201 BLAKE2B 86f4e8a3264b69eb72a357f59db082e81534dc28822934df328b1bf94aacb7ed1a219f8e5a03a9a37a0d07c248410822a3d12c4fd6b5df3a14157795e092a095 SHA512 c456704f40e7c5a5225255dbe3e4b794819d3fa982683a31b15a81f5467f007eef00cd80dac1844eca00ebab9ae12061139ae31c1fd7e2a6e012779d2a4b59f9
+DIST fwupd-1.5.1.tar.gz 2398842 BLAKE2B dce2da9807bc28c502281a75b98b21bab8fc34778ca1ed5e43b944cec2043ced7d3b997402d904eaceeb62d139182b883dfac0f4b6228750b18f8d0c66539d4f SHA512 57fa13d0c24cf9c8ec5341dca5392e054194861885233284a5a26d7c351ccdaab5a9ac9853681258882d42d21732302324719a709ff7e713885a9977430683ce

diff --git a/sys-apps/fwupd/fwupd-1.5.1.ebuild b/sys-apps/fwupd/fwupd-1.5.1.ebuild
new file mode 100644
index 00000000000..3634529c96d
--- /dev/null
+++ b/sys-apps/fwupd/fwupd-1.5.1.ebuild
@@ -0,0 +1,159 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit linux-info meson python-single-r1 vala xdg toolchain-funcs
+
+DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and reliable"
+HOMEPAGE="https://fwupd.org"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="agent amt dell gtk-doc elogind minimal introspection +man nvme policykit synaptics systemd test thunderbolt tpm uefi"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	^^ ( elogind minimal systemd )
+	dell? ( uefi )
+	minimal? ( !introspection )
+"
+RESTRICT="!test? ( test )"
+
+BDEPEND="$(vala_depend)
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gtk-doc )
+	introspection? ( dev-libs/gobject-introspection )
+	man? (
+		app-text/docbook-sgml-utils
+		sys-apps/help2man
+	)
+	test? (
+		thunderbolt? ( dev-util/umockdev )
+		net-libs/gnutls[tools]
+	)
+"
+CDEPEND="${PYTHON_DEPS}
+	>=app-arch/gcab-1.0
+	app-arch/libarchive:=
+	dev-db/sqlite
+	>=dev-libs/glib-2.45.8:2
+	dev-libs/json-glib
+	dev-libs/libgpg-error
+	dev-libs/libgudev:=
+	>=dev-libs/libgusb-0.3.5[introspection?]
+	>=dev-libs/libjcat-0.1.0[gpg,pkcs7]
+	>=dev-libs/libxmlb-0.1.13:=
+	$(python_gen_cond_dep '
+		dev-python/pillow[${PYTHON_MULTI_USEDEP}]
+		dev-python/pycairo[${PYTHON_MULTI_USEDEP}]
+		dev-python/pygobject:3[cairo,${PYTHON_MULTI_USEDEP}]
+	')
+	>=net-libs/libsoup-2.51.92:2.4[introspection?]
+	virtual/libelf:0=
+	virtual/udev
+	dell? (
+		>=sys-libs/libsmbios-2.4.0
+	)
+	elogind? ( >=sys-auth/elogind-211 )
+	policykit? (
+		>=sys-auth/polkit-0.103
+	)
+	systemd? ( >=sys-apps/systemd-211 )
+	tpm? ( app-crypt/tpm2-tss )
+	uefi? (
+		app-crypt/tpm2-tss
+		media-libs/fontconfig
+		media-libs/freetype
+		sys-boot/gnu-efi
+		sys-boot/efibootmgr
+		x11-libs/cairo
+	)
+"
+# Block sci-chemistry/chemical-mime-data for bug #701900
+RDEPEND="
+	!<sci-chemistry/chemical-mime-data-0.1.94-r4
+	${CDEPEND}
+	sys-apps/dbus
+"
+
+DEPEND="
+	${CDEPEND}
+	x11-libs/pango[introspection]
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.3.9-logind_plugin.patch"
+)
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	if use nvme; then
+		kernel_is -ge 4 4 || die "NVMe support requires kernel >= 4.4"
+	fi
+}
+
+src_prepare() {
+	default
+	# c.f. https://github.com/fwupd/fwupd/issues/1414
+	sed -e "/test('thunderbolt-self-test', e, env: test_env, timeout : 120)/d" \
+		-i plugins/thunderbolt/meson.build || die
+	vala_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		--localstatedir "${EPREFIX}"/var
+		-Dbuild="$(usex minimal standalone all)"
+		$(meson_use agent)
+		$(meson_use amt plugin_amt)
+		$(meson_use dell plugin_dell)
+		$(meson_use elogind)
+		$(meson_use gtk-doc gtkdoc)
+		$(meson_use man)
+		$(meson_use nvme plugin_nvme)
+		$(meson_use introspection)
+		$(meson_use policykit polkit)
+		$(meson_use synaptics plugin_synaptics)
+		$(meson_use systemd)
+		$(meson_use test tests)
+		$(meson_use thunderbolt plugin_thunderbolt)
+		$(meson_use tpm)
+		$(meson_use uefi plugin_uefi)
+		# Although our sys-apps/flashrom package now provides
+		# libflashrom.a, meson still can't find it
+		-Dplugin_flashrom="false"
+		# Dependencies are not available (yet?)
+		-Dplugin_modem_manager="false"
+		-Dconsolekit="false"
+	)
+	export CACHE_DIRECTORY="${T}"
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if ! use minimal ; then
+		sed "s@%SEAT_MANAGER%@elogind@" \
+			"${FILESDIR}"/${PN}-r1 \
+			> "${T}"/${PN} || die
+		doinitd "${T}"/${PN}
+
+		if ! use systemd ; then
+			# Don't timeout when fwupd is running (#673140)
+			sed '/^IdleTimeout=/s@=[[:digit:]]\+@=0@' \
+				-i "${ED}"/etc/${PN}/daemon.conf || die
+		fi
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	elog "In case you are using openrc as init system"
+	elog "and you're upgrading from <fwupd-1.1.0, you"
+	elog "need to start the fwupd daemon via the openrc"
+	elog "init script that comes with this package."
+}