[gentoo-commits] repo/gentoo:master commit in: net-misc/youtube-dl/

["Thomas Deutschmann" <whissi@gentoo.org>]

commit:     64e3792a9bb231bba9af78494e8027477a75b1ad
Author:     Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
AuthorDate: Mon Nov  2 14:25:10 2020 +0000
Commit:     Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
CommitDate: Mon Nov  2 14:27:14 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=64e3792a

net-misc/youtube-dl: bump to v2020.11.01

Closes: https://bugs.gentoo.org/752156
Closes: https://bugs.gentoo.org/745420
Package-Manager: Portage-3.0.8, Repoman-3.0.2
Signed-off-by: Thomas Deutschmann <whissi <AT> gentoo.org>

 net-misc/youtube-dl/Manifest                     |  1 +
 net-misc/youtube-dl/youtube-dl-2020.11.01.ebuild | 82 ++++++++++++++++++++++++
 2 files changed, 83 insertions(+)

diff --git a/net-misc/youtube-dl/Manifest b/net-misc/youtube-dl/Manifest
index 382bd3f1962..3ef7e395b2b 100644
--- a/net-misc/youtube-dl/Manifest
+++ b/net-misc/youtube-dl/Manifest
@@ -1 +1,2 @@
 DIST youtube-dl-2020.09.20.tar.gz 3188480 BLAKE2B c12ee589d112155207b59da9f710b2c776c07464d5c64a5d8355b963a81765b0dbc65df4f9564504fb963f30d5a11dc7e662c14d58ddf9fe6347352363cf70a5 SHA512 ed511016d0cfcbbee0cd651f793cb31cdb46d80243f86186de1cc54cb2a2055fae2f5cc3e16f838fc2ba47f3ff6f3b484219c8a707904fbc30193a2b28a1e30c
+DIST youtube-dl-2020.11.01.1.tar.gz 3190146 BLAKE2B 9f0a6d5041f12881d0f028459054e9cd6fbb91de35dc3d61782889f97611a39fe4a8e1c28fd45585d638ec179f6d9cd6587b06ee2d268a9f44f83f282961f367 SHA512 2c84305a71776808797a651e22690a396c1bd4c922ab6f15b086516b836aa6ac3acf5b08f556567b11f470c0d972adbf67fb110dc34ccfc5c0897e576e42ebab

diff --git a/net-misc/youtube-dl/youtube-dl-2020.11.01.ebuild b/net-misc/youtube-dl/youtube-dl-2020.11.01.ebuild
new file mode 100644
index 00000000000..9bb60f065e6
--- /dev/null
+++ b/net-misc/youtube-dl/youtube-dl-2020.11.01.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=(python3_{6,7,8,9})
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit bash-completion-r1 distutils-r1 readme.gentoo-r1
+
+DESCRIPTION="Download videos from YouTube.com (and more sites...)"
+HOMEPAGE="https://youtube-dl.org/ https://github.com/ytdl-org/youtube-dl/"
+SRC_URI="https://youtube-dl.org/downloads/latest/youtube-dl-2020.11.01.1.tar.gz"
+LICENSE="public-domain"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	test? (
+		dev-python/flake8[${PYTHON_USEDEP}]
+	)
+"
+
+RDEPEND="
+	dev-python/pycryptodome[${PYTHON_USEDEP}]
+"
+
+DEPEND="${RDEPEND}"
+
+distutils_enable_tests nose
+
+S=${WORKDIR}/${PN}
+
+src_compile() {
+	distutils-r1_src_compile
+}
+
+python_test() {
+	emake offlinetest
+}
+
+python_install_all() {
+	dodoc README.txt
+	doman ${PN}.1
+
+	newbashcomp ${PN}.bash-completion ${PN}
+
+	insinto /usr/share/zsh/site-functions
+	newins ${PN}.zsh _${PN}
+
+	insinto /usr/share/fish/vendor_completions.d
+	doins ${PN}.fish
+
+	distutils-r1_python_install_all
+
+	rm -r "${ED}"/usr/etc || die
+	rm -r "${ED}"/usr/share/doc/youtube_dl || die
+}
+
+pkg_postinst() {
+	elog "${PN}(1) / https://bugs.gentoo.org/355661 /"
+	elog "https://github.com/rg3/${PN}/blob/master/README.md#faq :"
+	elog
+	elog "${PN} works fine on its own on most sites. However, if you want"
+	elog "to convert video/audio, you'll need ffmpeg (media-video/ffmpeg)."
+	elog "On some sites - most notably YouTube - videos can be retrieved in"
+	elog "a higher quality format without sound. ${PN} will detect whether"
+	elog "ffmpeg is present and automatically pick the best option."
+	elog
+	elog "Videos or video formats streamed via RTMP protocol can only be"
+	elog "downloaded when rtmpdump (media-video/rtmpdump) is installed."
+	elog
+	elog "Downloading MMS and RTSP videos requires either mplayer"
+	elog "(media-video/mplayer) or mpv (media-video/mpv) to be installed."
+	elog
+	elog "If you want ${PN} to embed thumbnails from the metadata into the"
+	elog "resulting MP4 files, consider installing media-video/atomicparsley"
+}