[gentoo-commits] proj/sci:master commit in: dev-python/bokeh/

["Aisha Tammy" <gentoo@aisha.cc>]

commit:     278ea78681e753d7f372ae2ded55da98fc941f40
Author:     Aisha Tammy <gentoo <AT> aisha <DOT> cc>
AuthorDate: Wed Oct 21 21:40:54 2020 +0000
Commit:     Aisha Tammy <gentoo <AT> aisha <DOT> cc>
CommitDate: Wed Oct 21 21:41:04 2020 +0000
URL:        https://gitweb.gentoo.org/proj/sci.git/commit/?id=278ea786

dev-python/bokeh: version bump to 2.2.3

Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Aisha Tammy <gentoo <AT> aisha.cc>

 dev-python/bokeh/bokeh-2.2.3.ebuild | 85 +++++++++++++++++++++++++++++++++++++
 dev-python/bokeh/packs              | 21 ---------
 2 files changed, 85 insertions(+), 21 deletions(-)

diff --git a/dev-python/bokeh/bokeh-2.2.3.ebuild b/dev-python/bokeh/bokeh-2.2.3.ebuild
new file mode 100644
index 000000000..206e6962e
--- /dev/null
+++ b/dev-python/bokeh/bokeh-2.2.3.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# upstream hasn't tested python 3.8 fully
+PYTHON_COMPAT=( python3_{6..8} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+DISTUTILS_IN_SOURCE_BUILD=1
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Statistical and interactive HTML plots for Python"
+HOMEPAGE="https://bokeh.org/
+	https://github.com/bokeh/bokeh
+"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+# upstream authoritative dependencies
+# https://github.com/bokeh/bokeh/blob/master/conda.recipe/meta.yaml
+RDEPEND="
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pyparsing[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+	>=www-servers/tornado-5[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/ipython_genutils[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/networkx[${PYTHON_USEDEP}]
+		dev-python/nbconvert[${PYTHON_USEDEP}]
+		dev-python/nbformat[${PYTHON_USEDEP}]
+		dev-python/pydot[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		dev-python/selenium[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.2.1-conftest_py.patch
+)
+
+python_test() {
+	# disable tests having network calls
+	local SKIP_TESTS=" \
+		not (test___init__ and TestWarnings and test_filters) and \
+		not (test_json__subcommands and test_no_script) and \
+		not (test_standalone and Test_autoload_static) and \
+		not test_nodejs_compile_javascript and \
+		not test_nodejs_compile_less and \
+		not test_inline_extension and \
+		not (test_model and test_select) and \
+		not test_tornado__server and \
+		not test_client_server and \
+		not test_webdriver and \
+		not test_export and \
+		not test_server and \
+		not test_bundle and \
+		not test_ext \
+	"
+	pytest -m "not sampledata" tests/unit -k \
+		   "${SKIP_TESTS}" -vv || die "unittests fail with ${EPYTHON}"
+}
+
+pkg_postinst() {
+	optfeature "integration with amazon S3" dev-python/boto
+	optfeature "pypi integration to publish packages" dev-python/twine
+	optfeature "js library usage" net-libs/nodejs
+}

diff --git a/dev-python/bokeh/packs b/dev-python/bokeh/packs
deleted file mode 100644
index c6ffec3a0..000000000
--- a/dev-python/bokeh/packs
+++ /dev/null
@@ -1,21 +0,0 @@
-                dev-python/beautifulsoup
-                dev-python/boto
-                dev-python/colorama
-                dev-python/flaky
-                dev-python/ipython
-                dev-python/pandas
-                dev-python/pytest
-                dev-python/pytest-asyncio
-                dev-python/pytest-html
-                dev-python/pytest-xdist
-                dev-python/mypy
-                dev-python/mock
-                dev-python/networkx
-                dev-python/nbconvert
-                dev-python/nbformat
-                dev-python/pytest-rerunfailures
-                dev-python/pytest-xdist
-                dev-python/selenium
-                dev-ruby/selenium-webdriver
-                net-libs/nodejs
-                dev-python/scipy