[gentoo-commits] repo/gentoo:master commit in: sys-apps/bolt/

["Matthew Thode" <prometheanfire@gentoo.org>]

commit:     3e5f5de3f8caaf44243b5b4c5c6dcad5f62c76c8
Author:     Matthew Thode <prometheanfire <AT> gentoo <DOT> org>
AuthorDate: Fri Oct 16 02:03:52 2020 +0000
Commit:     Matthew Thode <prometheanfire <AT> gentoo <DOT> org>
CommitDate: Fri Oct 16 02:04:27 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3e5f5de3

sys-apps/bolt: 0.9-r2 - work with newer kernels

Closes: https://bugs.gentoo.org/740724
Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Matthew Thode <prometheanfire <AT> gentoo.org>

 sys-apps/bolt/bolt-0.9-r2.ebuild | 57 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

diff --git a/sys-apps/bolt/bolt-0.9-r2.ebuild b/sys-apps/bolt/bolt-0.9-r2.ebuild
new file mode 100644
index 00000000000..ddf044ade35
--- /dev/null
+++ b/sys-apps/bolt/bolt-0.9-r2.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit linux-info meson systemd
+
+DESCRIPTION="Userspace system daemon to enable security levels for Thunderbolt 3"
+HOMEPAGE="https://gitlab.freedesktop.org/bolt/bolt"
+SRC_URI="https://gitlab.freedesktop.org/${PN}/${PN}/-/archive/${PV}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc systemd"
+
+DEPEND="
+	>=dev-libs/glib-2.56.0:2
+	dev-util/glib-utils
+	virtual/libudev
+	virtual/udev
+	dev-util/umockdev
+	sys-auth/polkit[introspection]
+	systemd? ( sys-apps/systemd )
+	doc? ( app-text/asciidoc )"
+RDEPEND="${DEPEND}"
+
+pkg_pretend() {
+	if use kernel_linux && kernel_is lt 5 6; then
+		CONFIG_CHECK="~THUNDERBOLT"
+		ERROR_THUNDERBOLT="This package requires the thunderbolt kernel driver."
+	else
+		CONFIG_CHECK="~USB4"
+		ERROR_USB4="This package requires the USB4 kernel driver for Thunderbolt support."
+	fi
+	check_extra_config
+
+	CONFIG_CHECK="~HOTPLUG_PCI"
+	ERROR_HOTPLUG_PCI="Thunderbolt requires PCI hotplug support."
+	check_extra_config
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dman=$(usex doc true false)
+		--sysconfdir=/etc
+		--localstatedir=/var
+		--sharedstatedir=/var/lib
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	newinitd "${FILESDIR}"/${PN}.openrc boltd
+	keepdir /var/lib/boltd
+}