[gentoo-commits] repo/gentoo:master commit in: dev-embedded/esptool/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     bdfbde2775df19de4dbe17de259d64757c64eeea
Author:     Martin Dummer <martin.dummer <AT> gmx <DOT> net>
AuthorDate: Mon Oct  5 20:35:58 2020 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Sun Oct 11 09:29:59 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bdfbde27

dev-embedded/esptool: fix incorrect DISTUTILS_USE_SETUPTOOLS value

Closes: https://bugs.gentoo.org/746614
Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Martin Dummer <martin.dummer <AT> gmx.net>
Closes: https://github.com/gentoo/gentoo/pull/17807
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 dev-embedded/esptool/esptool-2.8-r2.ebuild | 40 ++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

diff --git a/dev-embedded/esptool/esptool-2.8-r2.ebuild b/dev-embedded/esptool/esptool-2.8-r2.ebuild
new file mode 100644
index 00000000000..e24cd7f15a7
--- /dev/null
+++ b/dev-embedded/esptool/esptool-2.8-r2.ebuild
@@ -0,0 +1,40 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1
+
+DESCRIPTION="Utility to communicate with the ROM bootloader in Espressif ESP8266 and ESP32"
+HOMEPAGE="https://github.com/espressif/esptool"
+SRC_URI="https://github.com/espressif/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/ecdsa[${PYTHON_MULTI_USEDEP}]
+		dev-python/pyaes[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/pyserial-3.0[${PYTHON_MULTI_USEDEP}]
+	')
+"
+BDEPEND="
+	test? ( $(python_gen_cond_dep 'dev-python/pyelftools[${PYTHON_MULTI_USEDEP}]') )
+"
+
+src_prepare() {
+	rm -rf pyaes/ ecdsa/ || die "unable to remove bundled modules"
+	default
+}
+
+python_test() {
+	${EPYTHON} test/test_imagegen.py || die "imagegen test failed with ${EPYTHON}"
+	${EPYTHON} test/test_espsecure.py || die "espsecure test failed with ${EPYTHON}"
+}