From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1212563-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 1FE24138359
for <garchives@archives.gentoo.org>; Wed, 7 Oct 2020 13:22:46 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id CDEF2E0101;
Wed, 7 Oct 2020 13:22:44 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id AA656E0101
for <gentoo-commits@lists.gentoo.org>; Wed, 7 Oct 2020 13:22:44 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 47AAB340F5A
for <gentoo-commits@lists.gentoo.org>; Wed, 7 Oct 2020 13:22:43 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id C32FC332
for <gentoo-commits@lists.gentoo.org>; Wed, 7 Oct 2020 13:22:41 +0000 (UTC)
From: "Lars Wendler" <polynomial-c@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Lars Wendler" <polynomial-c@gentoo.org>
Message-ID: <1602076958.13a39f91ec37727d620a285aeca5e0ea45642a2f.polynomial-c@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: media-sound/mumble/
X-VCS-Repository: repo/gentoo
X-VCS-Files: media-sound/mumble/Manifest media-sound/mumble/mumble-1.3.3.ebuild
X-VCS-Directories: media-sound/mumble/
X-VCS-Committer: polynomial-c
X-VCS-Committer-Name: Lars Wendler
X-VCS-Revision: 13a39f91ec37727d620a285aeca5e0ea45642a2f
X-VCS-Branch: master
Date: Wed, 7 Oct 2020 13:22:41 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: b1403d36-b8ce-4d71-af45-bb3413f6f69f
X-Archives-Hash: 5297adbd50191ca50c318eda628601a3
commit: 13a39f91ec37727d620a285aeca5e0ea45642a2f
Author: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Wed Oct 7 13:17:50 2020 +0000
Commit: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Wed Oct 7 13:22:38 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=13a39f91
media-sound/mumble: Bump to version 1.3.3
Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>
media-sound/mumble/Manifest | 1 +
media-sound/mumble/mumble-1.3.3.ebuild | 161 +++++++++++++++++++++++++++++++++
2 files changed, 162 insertions(+)
diff --git a/media-sound/mumble/Manifest b/media-sound/mumble/Manifest
index 2586c579c1e..64cd425a932 100644
--- a/media-sound/mumble/Manifest
+++ b/media-sound/mumble/Manifest
@@ -1,2 +1,3 @@
DIST mumble-1.3.1.tar.gz 8587417 BLAKE2B e0ff9911727ce74035cef658ff8ce21bfab6dcfd94306abe4a206853a1b2e2e4ddc7215e757f89559c30be64df4329dffc81618a0509df2b281f5b5b59d7de2f SHA512 f622ae5e4f7cd00ef60d225ee6db3cc13fcae5fdc1b03252d17ad6a18156526517e7d019f796b5600219e90e8662d095102fc6d61033fb20fd109afdf427a6d7
DIST mumble-1.3.2.tar.gz 8586828 BLAKE2B 38af4a0a2ab934388607745a2e31ea7310b7bc040bbe6ac32cc7128f2ac2949f5754090b6eaed3b0baaca6f76c42f004fdd093d88b8486d84187d063d01976e9 SHA512 22e23a682bc9c11420c6ae1d8ff01a80906ebbfb4f073ee25c6d2923d345d12031ddfeca3dabaaf5cf183b82b22eb3c788c88fa0f5313bc399e15795a945b874
+DIST mumble-1.3.3.tar.gz 8591354 BLAKE2B e5bf4d0a21f3c9af761b0892c4a5a7d86244d3283070976fe7a779a10567ffd857e0c19dad750cdbae40d851ce1dcf17b66c63a2cb5142a13358af6f272445dd SHA512 be4c6d4de82a1059bf30d4c7e3c44e41e4bb50dc4a811b7d0def808c52059ff7bcccf65140db940f18cc1bb66d58ea4dab23ba5dcfae3b8b904866751f32edb3
diff --git a/media-sound/mumble/mumble-1.3.3.ebuild b/media-sound/mumble/mumble-1.3.3.ebuild
new file mode 100644
index 00000000000..df7176498fd
--- /dev/null
+++ b/media-sound/mumble/mumble-1.3.3.ebuild
@@ -0,0 +1,161 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop multilib-build qmake-utils xdg
+
+DESCRIPTION="Mumble is an open source, low-latency, high quality voice chat software"
+HOMEPAGE="https://wiki.mumble.info"
+if [[ "${PV}" == 9999 ]] ; then
+ inherit git-r3
+ EGIT_REPO_URI="https://github.com/mumble-voip/mumble.git"
+ EGIT_SUBMODULES=( '-*' celt-0.7.0-src celt-0.11.0-src themes/Mumble 3rdparty/rnnoise-src )
+else
+ if [[ "${PV}" == *_pre* ]] ; then
+ SRC_URI="https://dev.gentoo.org/~polynomial-c/dist/${P}.tar.xz"
+ else
+ MY_PV="${PV/_/-}"
+ MY_P="${PN}-${MY_PV}"
+ SRC_URI="https://github.com/mumble-voip/mumble/releases/download/${MY_PV}/${MY_P}.tar.gz
+ https://dl.mumble.info/${MY_P}.tar.gz"
+ S="${WORKDIR}/${P/_*}"
+ fi
+ KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+fi
+
+LICENSE="BSD MIT"
+SLOT="0"
+IUSE="+alsa +dbus debug g15 jack libressl +opus oss pch portaudio pulseaudio +rnnoise speech zeroconf"
+
+RDEPEND="
+ dev-qt/qtcore:5
+ dev-qt/qtgui:5
+ dev-qt/qtnetwork:5[ssl]
+ dev-qt/qtsql:5[sqlite]
+ dev-qt/qtsvg:5
+ dev-qt/qtwidgets:5
+ dev-qt/qtxml:5
+ >=dev-libs/protobuf-2.2.0:=
+ >=media-libs/libsndfile-1.0.20[-minimal]
+ >=media-libs/speex-1.2.0
+ media-libs/speexdsp
+ sys-apps/lsb-release
+ x11-libs/libX11
+ x11-libs/libXi
+ alsa? ( media-libs/alsa-lib )
+ dbus? ( dev-qt/qtdbus:5 )
+ g15? ( app-misc/g15daemon )
+ jack? ( virtual/jack )
+ !libressl? ( >=dev-libs/openssl-1.0.0b:0= )
+ libressl? ( dev-libs/libressl )
+ opus? ( >=media-libs/opus-1.0.1 )
+ portaudio? ( media-libs/portaudio )
+ pulseaudio? ( media-sound/pulseaudio )
+ speech? ( >=app-accessibility/speech-dispatcher-0.8.0 )
+ zeroconf? ( net-dns/avahi[mdnsresponder-compat] )
+"
+DEPEND="${RDEPEND}
+ >=dev-libs/boost-1.41.0
+ x11-base/xorg-proto
+"
+BDEPEND="
+ dev-qt/linguist-tools:5
+ virtual/pkgconfig
+"
+
+# NB: qmake does not support multilib but it's fine to configure
+# for the native ABI here
+src_configure() {
+ myuse() {
+ [[ -n "${1}" ]] || die "myuse: No use option given"
+ use ${1} || echo no-${1}
+ }
+
+ local conf_add=(
+ bundled-celt
+ no-bundled-opus
+ no-bundled-speex
+ no-embed-qt-translations
+ no-server
+ no-update
+ $(myuse alsa)
+ $(myuse dbus)
+ $(usex debug 'symbols debug' release)
+ $(myuse g15)
+ $(usex jack '' no-jackaudio)
+ $(myuse opus)
+ $(myuse oss)
+ $(myuse portaudio)
+ $(myuse pulseaudio)
+ $(myuse rnnoise)
+ $(usex speech '' no-speechd)
+ $(usex zeroconf '' no-bonjour)
+ )
+
+ use pch || conf_add+=( no-pch )
+
+ eqmake5 "${S}/main.pro" -recursive \
+ CONFIG+="${conf_add[*]}" \
+ DEFINES+="PLUGIN_PATH=/usr/$(get_libdir)/mumble"
+}
+
+multilib_src_compile() {
+ local emake_args=(
+ # place libmumble* in a subdirectory
+ DESTDIR_ADD="/${MULTILIB_ABI_FLAG}"
+ {C,L}FLAGS_ADD="$(get_abi_CFLAGS)"
+ )
+ # build only overlay library for other ABIs
+ multilib_is_native_abi || emake_args+=( -C overlay_gl )
+ emake "${emake_args[@]}"
+ emake clean
+}
+
+src_compile() {
+ multilib_foreach_abi multilib_src_compile
+}
+
+multilib_src_install() {
+ local dir=$(usex debug debug release)
+ insinto /usr/$(get_libdir)/${PN}
+ doins "${dir}/${MULTILIB_ABI_FLAG}"/libmumble.so*
+ if multilib_is_native_abi; then
+ dobin "${dir}"/mumble
+ doins "${dir}"/libcelt0.so* "${dir}"/plugins/lib*.so*
+ fi
+}
+
+src_install() {
+ multilib_foreach_abi multilib_src_install
+
+ newdoc README.Linux README
+ dodoc CHANGES
+ dobin scripts/mumble-overlay
+
+ insinto /usr/share/services
+ doins scripts/mumble.protocol
+
+ domenu scripts/mumble.desktop
+
+ doicon -s scalable icons/mumble.svg
+
+ doman man/mumble-overlay.1
+ doman man/mumble.1
+}
+
+pkg_preinst() {
+ xdg_pkg_preinst
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+ echo
+ elog "Visit https://wiki.mumble.info/ for futher configuration instructions."
+ elog "Run mumble-overlay to start the OpenGL overlay (after starting mumble)."
+ echo
+}
+
+pkg_postrm() {
+ xdg_pkg_postrm
+}