[gentoo-commits] repo/gentoo:master commit in: dev-libs/libbase58/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     3d002a389dc3e77943ce1d689e85aa3548793dc6
Author:     Luke Dashjr <luke-jr+git <AT> utopios <DOT> org>
AuthorDate: Tue Sep 29 14:16:17 2020 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Mon Oct  5 05:46:48 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3d002a38

dev-libs/libbase58: Add multilib support to 0.1.4

Also adds a missing dependency on libgcrypt for test & USE=tools

Signed-off-by: Luke Dashjr <luke-jr+git <AT> utopios.org>
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 dev-libs/libbase58/libbase58-0.1.4-r1.ebuild | 48 ++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

diff --git a/dev-libs/libbase58/libbase58-0.1.4-r1.ebuild b/dev-libs/libbase58/libbase58-0.1.4-r1.ebuild
new file mode 100644
index 00000000000..6d58a9ccec7
--- /dev/null
+++ b/dev-libs/libbase58/libbase58-0.1.4-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools multilib-minimal
+
+DESCRIPTION="C implementation of Bitcoin's base58 encoding"
+HOMEPAGE="https://github.com/luke-jr/libbase58"
+LICENSE="MIT"
+
+SRC_URI="https://github.com/luke-jr/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+SLOT="0/0"
+KEYWORDS="~amd64 ~arm ~mips ~ppc ~ppc64 ~x86"
+IUSE="test tools"
+RESTRICT="!test? ( test )"
+
+# NOTE: If not testing, we don't need non-native libgcrypt
+RDEPEND="tools? ( dev-libs/libgcrypt )"
+DEPEND="${RDEPEND}
+	test? ( dev-libs/libgcrypt[${MULTILIB_USEDEP}] )
+"
+
+src_prepare() {
+	eapply_user
+	eautoreconf
+
+	# NOTE: Needed because test suite uses srcdir instead of builddir to set PATH
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	local myeconf=(
+		--disable-static
+		LIBGCRYPT_CONFIG="${EPREFIX}/usr/bin/${CHOST}-libgcrypt-config"
+	)
+	if multilib_is_native_abi && use tools; then
+		myeconf+=( --enable-tool )
+	elif use test; then
+		myeconf+=( --enable-tool --bindir='/TRASH' )
+	else
+		myeconf+=( --disable-tool )
+	fi
+	econf "${myeconf[@]}"
+}
+
+multilib_src_install_all() {
+	rm -rf "${ED}/TRASH" || die
+}