[gentoo-commits] repo/gentoo:master commit in: media-sound/ncmpc/

["James Le Cuirot" <chewi@gentoo.org>]

commit:     48e127fdad838f0d15a89dd944e6ed0de31c6acd
Author:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
AuthorDate: Sun Sep 27 20:21:18 2020 +0000
Commit:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
CommitDate: Sun Sep 27 20:21:18 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=48e127fd

media-sound/ncmpc: Version bump to 0.39

No ebuild changes.

Closes: https://bugs.gentoo.org/701388
Package-Manager: Portage-3.0.6, Repoman-3.0.1
Signed-off-by: James Le Cuirot <chewi <AT> gentoo.org>

 media-sound/ncmpc/Manifest          |  1 +
 media-sound/ncmpc/ncmpc-0.39.ebuild | 69 +++++++++++++++++++++++++++++++++++++
 2 files changed, 70 insertions(+)

diff --git a/media-sound/ncmpc/Manifest b/media-sound/ncmpc/Manifest
index 5f4d9e99601..0bf169a9d63 100644
--- a/media-sound/ncmpc/Manifest
+++ b/media-sound/ncmpc/Manifest
@@ -1 +1,2 @@
 DIST ncmpc-0.34.tar.xz 227892 BLAKE2B 19d9d9abe3d85cb2567a222c8ce108889d4517272e2bb82f4064ef76af68d610ff4c7516102b976f66380e0e3d3ee7ed00023116cb6b2d1628e3d38796705a09 SHA512 e206cc2d61799a97edf1182de4cee1c0fa447bd1fac136dc48670cb624a7efc903c693b0c541fbc00fcb94e055c83be1ca6370386c99131a1b571f47b67c35f4
+DIST ncmpc-0.39.tar.xz 242968 BLAKE2B 1b270ed52aa884cecd3e1ce60bb2ed628ef79480697f388b48a09e0f22068dbbb7623b01171e5cfae9556446e404530f93c84ca3c3d5cc481c8431f37786c2f4 SHA512 bfadc58bf8b66bff08608f561f689a50fd412b87975998ce23751fd312fa009eeba4b48b4afe96391b2ecb184c00c366262e9b96e24d2ce2ab2af6a4002721d9

diff --git a/media-sound/ncmpc/ncmpc-0.39.ebuild b/media-sound/ncmpc/ncmpc-0.39.ebuild
new file mode 100644
index 00000000000..cad4074e5d6
--- /dev/null
+++ b/media-sound/ncmpc/ncmpc-0.39.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson
+
+DESCRIPTION="Ncurses client for the Music Player Daemon (MPD)"
+HOMEPAGE="https://www.musicpd.org/clients/ncmpc/ https://github.com/MusicPlayerDaemon/ncmpc"
+SRC_URI="https://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="async-connect chat-screen doc +help-screen key-screen +library-screen lirc lyrics-screen +mouse nls outputs-screen pcre search-screen +song-screen"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( dev-python/sphinx )
+"
+RDEPEND="
+	>=media-libs/libmpdclient-2.9
+	sys-libs/ncurses:0=[unicode]
+	lirc? ( app-misc/lirc )
+	pcre? ( dev-libs/libpcre )
+"
+DEPEND="${RDEPEND}
+	>=dev-libs/boost-1.62
+"
+
+src_prepare() {
+	default
+
+	# use correct docdir and don't install license file
+	sed -e "/^docdir =/s/meson.project_name()/'${PF}'/" \
+		-e "s/'COPYING', //" \
+		-i meson.build || die
+
+	# use correct (html) docdir
+	sed -e "/install_dir:.*doc/s/meson.project_name()/'${PF}'/" \
+		-i doc/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dcurses=ncursesw
+		-Dcolors=true
+		-Dmini=false
+		-Dlyrics_plugin_dir="${EPREFIX}/usr/$(get_libdir)/ncmpc/lyrics"
+		-Dasync_connect=$(usex async-connect true false)
+		-Dchat_screen=$(usex chat-screen true false)
+		-Ddocumentation=$(usex doc enabled disabled)
+		-Dhelp_screen=$(usex help-screen true false)
+		-Dkey_screen=$(usex key-screen true false)
+		-Dlibrary_screen=$(usex library-screen true false)
+		-Dlirc=$(usex lirc enabled disabled)
+		-Dlocale=$(usex nls enabled disabled)
+		-Dlyrics_screen=$(usex lyrics-screen true false)
+		-Dmouse=$(usex mouse enabled disabled)
+		-Dmultibyte=$(usex nls true false)
+		-Dnls=$(usex nls enabled disabled)
+		-Doutputs_screen=$(usex outputs-screen true false)
+		-Dregex=$(usex pcre enabled disabled)
+		-Dsearch_screen=$(usex search-screen true false)
+		-Dsong_screen=$(usex song-screen true false)
+	)
+
+	meson_src_configure
+}