From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1208636-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 500A5138359
for <garchives@archives.gentoo.org>; Tue, 22 Sep 2020 14:48:38 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 596FFE0858;
Tue, 22 Sep 2020 14:48:37 +0000 (UTC)
Received: from smtp.gentoo.org (mail.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 35C1BE0858
for <gentoo-commits@lists.gentoo.org>; Tue, 22 Sep 2020 14:48:37 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id DAF57340E9E
for <gentoo-commits@lists.gentoo.org>; Tue, 22 Sep 2020 14:48:35 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 8EF892EC
for <gentoo-commits@lists.gentoo.org>; Tue, 22 Sep 2020 14:48:34 +0000 (UTC)
From: "Joonas Niilola" <juippis@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Joonas Niilola" <juippis@gentoo.org>
Message-ID: <1600786107.926ed964918fedbfd47b68fbbd9bddf16c01b0a4.juippis@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-libs/efl/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-libs/efl/efl-1.24.3-r1.ebuild
X-VCS-Directories: dev-libs/efl/
X-VCS-Committer: juippis
X-VCS-Committer-Name: Joonas Niilola
X-VCS-Revision: 926ed964918fedbfd47b68fbbd9bddf16c01b0a4
X-VCS-Branch: master
Date: Tue, 22 Sep 2020 14:48:34 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 528aa5e5-a659-4dce-88c6-ce7a2a688b07
X-Archives-Hash: 0b385eea46a878e481f028d3c19c0ab0
commit: 926ed964918fedbfd47b68fbbd9bddf16c01b0a4
Author: Joonas Niilola <juippis <AT> gentoo <DOT> org>
AuthorDate: Tue Sep 22 14:47:51 2020 +0000
Commit: Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Tue Sep 22 14:48:27 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=926ed964
dev-libs/efl: fix automagic dependency on libunwind
Closes: https://bugs.gentoo.org/743154
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>
dev-libs/efl/efl-1.24.3-r1.ebuild | 293 ++++++++++++++++++++++++++++++++++++++
1 file changed, 293 insertions(+)
diff --git a/dev-libs/efl/efl-1.24.3-r1.ebuild b/dev-libs/efl/efl-1.24.3-r1.ebuild
new file mode 100644
index 00000000000..f7493cc7904
--- /dev/null
+++ b/dev-libs/efl/efl-1.24.3-r1.ebuild
@@ -0,0 +1,293 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson xdg-utils
+
+DESCRIPTION="Enlightenment Foundation Libraries all-in-one package"
+HOMEPAGE="https://www.enlightenment.org"
+SRC_URI="https://download.enlightenment.org/rel/libs/${PN}/${P}.tar.xz"
+
+LICENSE="BSD-2 GPL-2 LGPL-2.1 ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86"
+IUSE="+X bmp connman cpu_flags_arm_neon dds debug doc drm +eet elogind examples
+ fbcon +fontconfig fribidi gif gles2-only gnutls glib +gstreamer harfbuzz
+ hyphen ibus ico libressl lua +luajit jpeg2k json nls mono opengl +pdf
+ physics pmaps postscript psd pulseaudio raw scim sdl +sound +ssl +svg
+ +system-lz4 systemd tga tgv tiff tslib unwind v4l vnc wayland webp xcf xim
+ xpm xpresent zeroconf"
+
+REQUIRED_USE="
+ ?? ( elogind systemd )
+ ?? ( gles2-only opengl )
+ ^^ ( lua luajit )
+ ssl
+ drm? ( gles2-only )
+ examples? ( eet svg )
+ gles2-only? ( || ( wayland X ) )
+ pulseaudio? ( sound )
+ wayland? ( gles2-only !opengl )
+ xim? ( X )
+ xpresent? ( X )
+"
+
+# Requires everything to be enabled unconditionally.
+RESTRICT="test"
+
+RDEPEND="
+ dev-libs/check
+ net-misc/curl
+ media-libs/giflib:=
+ media-libs/libpng:0=
+ sys-apps/dbus
+ sys-libs/zlib
+ virtual/jpeg:0=
+ X? (
+ media-libs/freetype
+ x11-libs/libX11
+ x11-libs/libXcomposite
+ x11-libs/libXcursor
+ x11-libs/libXdamage
+ x11-libs/libXdmcp
+ x11-libs/libXext
+ x11-libs/libXfixes
+ x11-libs/libXi
+ x11-libs/libXinerama
+ x11-libs/libXrandr
+ x11-libs/libXrender
+ x11-libs/libXtst
+ x11-libs/libXScrnSaver
+ wayland? ( x11-libs/libxkbcommon[X] )
+ )
+ connman? ( net-misc/connman )
+ drm? (
+ dev-libs/libinput
+ dev-libs/wayland
+ media-libs/mesa[gbm]
+ x11-libs/libdrm
+ x11-libs/libxkbcommon
+ )
+ elogind? (
+ sys-auth/elogind
+ virtual/libudev
+ )
+ fontconfig? ( media-libs/fontconfig )
+ fribidi? ( dev-libs/fribidi )
+ gles2-only? (
+ media-libs/mesa[egl,gles2]
+ virtual/opengl
+ )
+ glib? ( dev-libs/glib:2 )
+ gstreamer? (
+ media-libs/gstreamer:1.0
+ media-libs/gst-plugins-base:1.0
+ )
+ hyphen? ( dev-libs/hyphen )
+ ibus? ( app-i18n/ibus )
+ jpeg2k? ( media-libs/openjpeg:= )
+ json? ( >=media-libs/rlottie-0.0.1_pre20200424:= )
+ lua? ( dev-lang/lua:* )
+ luajit? ( dev-lang/luajit:* )
+ mono? ( dev-lang/mono )
+ opengl? ( virtual/opengl )
+ pdf? ( app-text/poppler:=[cxx] )
+ physics? ( sci-physics/bullet:= )
+ postscript? ( app-text/libspectre )
+ pulseaudio? ( media-sound/pulseaudio )
+ raw? ( media-libs/libraw:= )
+ scim? ( app-i18n/scim )
+ sdl? ( media-libs/libsdl2 )
+ sound? ( media-libs/libsndfile )
+ ssl? (
+ gnutls? ( net-libs/gnutls:= )
+ !gnutls? (
+ !libressl? ( dev-libs/openssl:0= )
+ libressl? ( dev-libs/libressl:= )
+ )
+ )
+ svg? ( gnome-base/librsvg )
+ system-lz4? ( app-arch/lz4 )
+ systemd? ( sys-apps/systemd:= )
+ tiff? ( media-libs/tiff:0= )
+ tslib? ( x11-libs/tslib:= )
+ unwind? ( sys-libs/libunwind )
+ v4l? ( media-libs/libv4l )
+ vnc? ( net-libs/libvncserver )
+ wayland? (
+ dev-libs/wayland
+ media-libs/mesa[gles2,wayland]
+ x11-libs/libxkbcommon
+ )
+ webp? ( media-libs/libwebp:= )
+ xpm? ( x11-libs/libXpm )
+ xpresent? ( x11-libs/libXpresent )
+ zeroconf? ( net-dns/avahi )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+ doc? ( app-doc/doxygen )
+ nls? ( sys-devel/gettext )"
+
+src_prepare() {
+ default
+
+ # Remove automagic unwind configure option, #743154
+ if ! use unwind; then
+ sed -i "/config_h.set('HAVE_UNWIND/,/eina_deps += unwind/d" src/lib/eina/meson.build ||
+ die "Failed to remove libunwind dep"
+ fi
+}
+
+src_configure() {
+ local emesonargs=(
+ --buildtype=release
+
+ -D buffer=false
+ -D cocoa=false
+ -D drm-deprecated=false
+ -D g-mainloop=false
+ -D install-eo-files=true
+ -D mono-beta=false
+ -D dotnet=false
+ -D pixman=false
+ -D wl-deprecated=false
+ -D dotnet-stylecop-severity=Warning
+
+ -D edje-sound-and-video=true
+ -D eeze=true
+ -D libmount=true
+ -D native-arch-optimization=true
+ -D xinput2=true
+ -D xinput22=true
+
+ $(meson_use X x11)
+ $(meson_use debug debug-threads)
+ $(meson_use drm)
+ $(meson_use elogind)
+ $(meson_use examples build-examples)
+ $(meson_use fbcon fb)
+ $(meson_use fontconfig)
+ $(meson_use fribidi)
+ $(meson_use glib)
+ $(meson_use gstreamer)
+ $(meson_use harfbuzz)
+ $(meson_use hyphen)
+ $(meson_use luajit elua)
+ $(meson_use nls)
+ $(meson_use physics)
+ $(meson_use pulseaudio)
+ $(meson_use sdl)
+ $(meson_use sound audio)
+ $(meson_use systemd)
+ $(meson_use tslib)
+ $(meson_use v4l v4l2)
+ $(meson_use vnc vnc-server)
+ $(meson_use wayland wl)
+ $(meson_use xpresent)
+ $(meson_use zeroconf avahi)
+
+ $(meson_use !system-lz4 embedded-lz4)
+ )
+
+ if use opengl; then
+ emesonargs+=( -D opengl=full )
+ elif use gles2-only; then
+ emesonargs+=( -D opengl=es-egl )
+ else
+ emesonargs+=( -D opengl=none )
+ fi
+
+ if use gnutls; then
+ emesonargs+=( -D crypto=gnutls )
+ else
+ emesonargs+=( -D crypto=openssl )
+ fi
+
+ if use connman; then
+ emesonargs+=( -D network-backend=connman )
+ else
+ emesonargs+=( -D network-backend=none )
+ fi
+
+ local disabledEvasLoaders=""
+ ! use bmp && disabledEvasLoaders+="bmp,wbmp,"
+ ! use dds && disabledEvasLoaders+="dds,"
+ ! use eet && disabledEvasLoaders+="eet,"
+ ! use gstreamer && disabledEvasLoaders+="gst,"
+ ! use ico && disabledEvasLoaders+="ico,"
+ ! use jpeg2k && disabledEvasLoaders+="jp2k,"
+ ! use json && disabledEvasLoaders+="json,"
+ ! use pdf && disabledEvasLoaders+="pdf,"
+ ! use pmaps && disabledEvasLoaders+="pmaps,"
+ ! use postscript && disabledEvasLoaders+="ps,"
+ ! use psd && disabledEvasLoaders+="psd,"
+ ! use raw && disabledEvasLoaders+="raw,"
+ ! use svg && disabledEvasLoaders+="rsvg,svg,"
+ ! use tga && disabledEvasLoaders+="tga,"
+ ! use tgv && disabledEvasLoaders+="tgv,"
+ ! use tiff && disabledEvasLoaders+="tiff,"
+ ! use webp && disabledEvasLoaders+="webp,"
+ ! use xcf && disabledEvasLoaders+="xcf,"
+ ! use xpm && disabledEvasLoaders+="xpm,"
+ [[ ! -z "$disabledEvasLoaders" ]] && disabledEvasLoaders=${disabledEvasLoaders::-1}
+ emesonargs+=( -D evas-loaders-disabler="${disabledEvasLoaders}" )
+
+ local disabledImfLoaders=""
+ ! use ibus && disabledImfLoaders+="ibus,"
+ ! use scim && disabledImfLoaders+="scim,"
+ ! use xim && disabledImfLoaders+="xim,"
+ [[ ! -z "$disabledImfLoaders" ]] && disabledImfLoaders=${disabledImfLoaders::-1}
+ emesonargs+=( -D ecore-imf-loaders-disabler="${disabledImfLoaders}" )
+
+ local bindingsList="cxx,"
+ use luajit && bindingsList+="luajit,"
+ use mono && bindingsList+="mono,"
+ [[ ! -z "$bindingsList" ]] && bindingsList=${bindingsList::-1}
+ emesonargs+=( -D bindings="${bindingsList}" )
+
+ local luaChoice=""
+ if use luajit; then
+ luaChoice+="luajit"
+ else
+ luaChoice+="lua"
+ fi
+ emesonargs+=( -D lua-interpreter="${luaChoice}" )
+
+ # Not all arm CPU's have neon instruction set, #722552
+ if use arm && ! use cpu_flags_arm_neon; then
+ emesonargs+=( -D native-arch-optimization=false )
+ fi
+
+ meson_src_configure
+}
+
+src_compile() {
+ meson_src_compile
+
+ if use doc; then
+ cd doc/ || die "Failed to switch into doc/ dir."
+ doxygen . || die "Doxygen failed to run."
+ fi
+}
+
+src_install() {
+ use doc && local HTML_DOCS=( "${S}"/doc/html/. )
+ meson_src_install
+
+ if use examples; then
+ docompress -x /usr/share/doc/${PF}/examples/
+ dodoc -r "${BUILD_DIR}"/src/examples/
+ fi
+}
+
+pkg_postinst() {
+ xdg_icon_cache_update
+ xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+ xdg_icon_cache_update
+ xdg_mimeinfo_database_update
+}