[gentoo-commits] repo/gentoo:master commit in: dev-util/conan/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     51801ad348fbf10ecc0978245aae1b1d85cdfb85
Author:     Azamat H. Hackimov <azamat.hackimov <AT> gmail <DOT> com>
AuthorDate: Sat Aug 15 13:51:30 2020 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Tue Sep 15 14:11:16 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=51801ad3

dev-util/conan: update to 1.28.1

Added Python 3.8 support, remove all dependency restrictions, exclude failing
tests.
Closes: https://bugs.gentoo.org/737344

Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Azamat H. Hackimov <azamat.hackimov <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/17130
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 dev-util/conan/Manifest            |  1 +
 dev-util/conan/conan-1.28.1.ebuild | 75 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 76 insertions(+)

diff --git a/dev-util/conan/Manifest b/dev-util/conan/Manifest
index 47c969ddeab..6887367eae8 100644
--- a/dev-util/conan/Manifest
+++ b/dev-util/conan/Manifest
@@ -1 +1,2 @@
 DIST conan-1.28.0.tar.gz 1135799 BLAKE2B 774f980b489bc2ee7973447829ac2f9062198ec85a1129e3cfcf34a490b969cb5c04546a8918b542bc15e429d75d8e7fe3bc29f9cd5c6cebb6f7270a921a47f2 SHA512 1366f37d774bcaeadaf27f459d9a3889424a21ad14cc0e59f978ccf77a2d4e1f3497e98533e325fe086735b9bdaee64fd2df6c228e62d7577533142ab28401c8
+DIST conan-1.28.1.tar.gz 1138639 BLAKE2B 91f277b88a2069efa3ad5f6209279888b4ac8cf5c359b7933ace6cc08c8b61a868dc8f7bb6a817fbdea378ce175229c91c9defb750326e2a5e31c4d6d528985d SHA512 b8eb4fe34b1614ebcb5e15bd0a827c5949e8588c6a04380632858e68eb4172361c96305154cc5a630254ed6236d7fd82e3a2c05962e312af3cedba41eac0a6e3

diff --git a/dev-util/conan/conan-1.28.1.ebuild b/dev-util/conan/conan-1.28.1.ebuild
new file mode 100644
index 00000000000..48fdacaef94
--- /dev/null
+++ b/dev-util/conan/conan-1.28.1.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_REQ_USE="sqlite"
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit distutils-r1
+
+DESCRIPTION="Distributed C/C++ package manager"
+HOMEPAGE="https://conan.io/"
+SRC_URI="https://github.com/conan-io/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+# overly strict requirements?
+# https://github.com/conan-io/conan/blob/develop/conans/requirements.txt
+# https://github.com/conan-io/conan/blob/develop/conans/requirements_server.txt
+RDEPEND="
+	>=dev-python/bottle-0.12.8[${PYTHON_USEDEP}]
+	>=dev-python/colorama-0.3.3[${PYTHON_USEDEP}]
+	>=dev-python/deprecation-2.0[${PYTHON_USEDEP}]
+	>=dev-python/distro-1.0.2[${PYTHON_USEDEP}]
+	>=dev-python/fasteners-0.14.1[${PYTHON_USEDEP}]
+	>=dev-python/future-0.16.0[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.10.1[${PYTHON_USEDEP}]
+	>=dev-python/node-semver-0.8[${PYTHON_USEDEP}]
+	>=dev-python/patch-ng-1.17.4[${PYTHON_USEDEP}]
+	>=dev-python/pluginbase-0.5[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.0[${PYTHON_USEDEP}]
+	>=dev-python/pyjwt-1.4[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.7.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.8.1[${PYTHON_USEDEP}]
+	>=dev-python/six-1.12.0[${PYTHON_USEDEP}]
+	>=dev-python/tqdm-4.28.1[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.7[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests nose
+DEPEND+="
+	test? (
+		dev-lang/go
+		dev-vcs/git
+		dev-vcs/subversion
+		>=dev-python/mock-1.3.0[${PYTHON_USEDEP}]
+		>=dev-python/nose-1.3.7[${PYTHON_USEDEP}]
+		>=dev-python/parameterized-0.6.3[${PYTHON_USEDEP}]
+		>=dev-python/webtest-2.0.18[${PYTHON_USEDEP}]
+		dev-util/cmake
+	)
+"
+
+src_prepare() {
+	default
+	# Fix strict dependencies
+	sed -i \
+		-e 's:,[[:space:]]\?<=\?[[:space:]]\?[[:digit:]|.]*::g' \
+		-e 's:==:>=:g' \
+		conans/requirements{,_server}.txt || die
+}
+
+python_test() {
+	nosetests -v conans.test \
+		-e test_ftp.* -e modify_values_test.* -e test_pkg_config_path.* \
+		-e rpath_optin_test -e test_variables -e system_package_tool_installed_test \
+		-e virtualbuildenv_test -e scm_test -e test_git_shallow -e tools_test \
+		-e test_environment_nested -e devflow_test -e shared_chain_test \
+		-e test_toolchain_linux_0_Debug -e test_toolchain_linux_1_Release \
+		-e virtualenv_test -e link_order_test -e test_version \
+		-A "not rest_api and not local_bottle" || die
+}