[gentoo-commits] repo/gentoo:master commit in: games-simulation/openrct2/

["Conrad Kostecki" <conikost@gentoo.org>]

commit:     5634e3dc81fbc76b2b1376854421761521e8c878
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Wed Aug 19 22:19:32 2020 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Wed Aug 19 22:44:59 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5634e3dc

games-simulation/openrct2: bump to version 0.3.0

Package-Manager: Portage-3.0.1, Repoman-2.3.23
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 games-simulation/openrct2/Manifest              |   1 +
 games-simulation/openrct2/openrct2-0.3.0.ebuild | 166 ++++++++++++++++++++++++
 2 files changed, 167 insertions(+)

diff --git a/games-simulation/openrct2/Manifest b/games-simulation/openrct2/Manifest
index 19c4c945e1d..4e6324b24d6 100644
--- a/games-simulation/openrct2/Manifest
+++ b/games-simulation/openrct2/Manifest
@@ -1,4 +1,5 @@
 DIST openrct2-0.2.6.tar.gz 11094308 BLAKE2B 4aed899fee4735a0237558c1c34f67f37ecc9b8138f8a66314a9abc013cf10ad3a9f80fd5159afc5860ded780d4c705fd9e394b38f981aac90c8cee883356996 SHA512 abe7c344b7588b169c95ffe0ab9028f72614d9b5783d81fa4f97f206d90d8cbaa0b91f04314c10926dbd5f68bba166558c428557f598abb343d306800611fb24
+DIST openrct2-0.3.0.tar.gz 11754657 BLAKE2B 66d956fd85829bc6b4825a59db9f3a3eebbb1e4565a4c8afdb8c05d9d7b3f339f75ff1d9fbc0a0f48d3c0673ac3fc335fb6bec5fe458513de2a0611ccfa3d48d SHA512 585bcd7a077114dc5332b95cb44f7c689e47fcbd7cff7c2ab32a24253a4fd87f50e79f40f9428c79ea6bc6d8cd88019b4edfce88509c03bc2d43854926d21317
 DIST openrct2-objects-1.0.14.zip 2237331 BLAKE2B 39a0c92674abc0d16fc3dd463b68e2ee8f3f7dd1c2a944d5448173ca58e6c3c4a79092a40e66ac8e919f75be2d2d691a76dc046e41caf7237138815a4e6ad526 SHA512 66e7a55ca894f2ea11af1c6300f934ef00f659137dded06f54bf749f490ff6063f95da800ae3cbfbbffe1c3e7d995e307d1281d57e4454ded6fed5affde84f8e
 DIST openrct2-objects-1.0.16.zip 3056214 BLAKE2B 7d8d938ba20ce612f7845dce1038134ec60d7e17e0f7d78a67480ae1ae2e6f8dd043f266742acd2dbd8539390349a2dcd7b8c73859a3caef3b5cd8565a4ec1c7 SHA512 2a8696467320f7894330d0fbb4894dd6effb2d6844fcf643e1f8e15a7b0b45411a7c205b75a9e9d7ea0627bc70b7a7e1e2213e0f7db1c7b489ae8b485670dba5
 DIST openrct2-replays-0.0.17.zip 1825315 BLAKE2B 9c22b52302c37abe5e802662eb4b6805fa3e229a71ab9f901b57eee30641ae4b86de9b1315476d158a3feb57c6be2a26c1ccca7c94328fe35bf57b46e2364c32 SHA512 103a8ba5b5b2dd76c18b642720d262553bb15ad26d59892f895327bf5e87b73e476b255af6556286faacb668aae49aa1ee29a14bcca2bb75d855383d12e60f4a

diff --git a/games-simulation/openrct2/openrct2-0.3.0.ebuild b/games-simulation/openrct2/openrct2-0.3.0.ebuild
new file mode 100644
index 00000000000..24c511c6a59
--- /dev/null
+++ b/games-simulation/openrct2/openrct2-0.3.0.ebuild
@@ -0,0 +1,166 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake readme.gentoo-r1 xdg-utils
+
+MY_PN="OpenRCT2"
+MY_PN_OBJ="objects"
+MY_PN_RPL="replays"
+MY_PN_TS="title-sequences"
+MY_PV_OBJ="1.0.16"
+MY_PV_RPL="0.0.17"
+MY_PV_TS="0.1.2c"
+
+DESCRIPTION="An open source re-implementation of Chris Sawyer's RollerCoaster Tycoon 2"
+HOMEPAGE="https://openrct2.org/"
+SRC_URI="
+	https://github.com/${MY_PN}/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	https://github.com/${MY_PN}/${MY_PN_OBJ}/releases/download/v${MY_PV_OBJ}/${MY_PN_OBJ}.zip -> ${PN}-${MY_PN_OBJ}-${MY_PV_OBJ}.zip
+	https://github.com/${MY_PN}/${MY_PN_TS}/releases/download/v${MY_PV_TS}/${MY_PN_TS}.zip -> ${PN}-${MY_PN_TS}-${MY_PV_TS}.zip
+	test? ( https://github.com/${MY_PN}/${MY_PN_RPL}/releases/download/v${MY_PV_RPL}/${MY_PN_RPL}.zip -> ${PN}-${MY_PN_RPL}-${MY_PV_RPL}.zip )
+"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="dedicated libressl +lightfx +opengl scripting test +truetype"
+
+COMMON_DEPEND="
+	dev-libs/icu:=
+	dev-libs/jansson
+	dev-libs/libzip:=
+	media-libs/libpng:0=
+	net-misc/curl[ssl]
+	sys-libs/zlib
+	!dedicated? (
+		media-libs/libsdl2
+		media-libs/speexdsp
+		opengl? ( virtual/opengl )
+	)
+	libressl? ( dev-libs/libressl:0= )
+	!libressl? ( dev-libs/openssl:0= )
+	scripting? ( dev-lang/duktape )
+	truetype? (
+		media-libs/fontconfig:1.0
+		media-libs/freetype:2
+	)
+"
+
+RDEPEND="
+	${COMMON_DEPEND}
+	dedicated? (
+		acct-group/openrct2
+		acct-user/openrct2
+	)
+"
+
+DEPEND="
+	${COMMON_DEPEND}
+	test? ( dev-cpp/gtest )
+"
+
+BDEPEND="
+	app-arch/unzip
+	virtual/pkgconfig
+"
+
+RESTRICT="!test? ( test )"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.2.4-include-additional-paths.patch"
+	"${FILESDIR}/${PN}-0.2.6-gtest-1.10.patch"
+)
+
+src_unpack() {
+	unpack "${P}".tar.gz
+
+	mkdir -p "${S}"/data/sequence || die
+	cd "${S}"/data/sequence || die
+	unpack "${PN}-${MY_PN_TS}-${MY_PV_TS}".zip
+
+	mkdir -p "${S}"/data/object || die
+	cd "${S}"/data/object || die
+	unpack "${PN}-${MY_PN_OBJ}-${MY_PV_OBJ}".zip
+
+	if use test; then
+		mkdir -p "${S}"/testdata/replays || die
+		cd "${S}"/testdata/replays || die
+		unpack "${PN}-${MY_PN_RPL}-${MY_PV_RPL}".zip
+	fi
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	# Don't treat warnings as errors.
+	sed -e 's/-Werror//' -i CMakeLists.txt || die
+}
+
+src_configure() {
+	# Note: There is currently no support for Disord-RPC and Google Benchmark,
+	# as both packages do not exist in Gentoo, so support for them has been disabled.
+	local mycmakeargs=(
+		-DDISABLE_DISCORD_RPC=ON
+		-DDISABLE_GOOGLE_BENCHMARK=ON
+		-DDISABLE_GUI=$(usex dedicated)
+		-DDISABLE_HTTP=OFF
+		-DDISABLE_NETWORK=OFF
+		$(usex !dedicated "-DDISABLE_OPENGL=$(usex !opengl)" "")
+		-DDISABLE_TTF=$(usex !truetype)
+		-DDOWNLOAD_OBJECTS=OFF
+		-DDOWNLOAD_REPLAYS=OFF
+		-DDOWNLOAD_TITLE_SEQUENCES=OFF
+		-DENABLE_LIGHTFX=$(usex lightfx)
+		-DENABLE_SCRIPTING=$(usex scripting)
+		-DOPENRCT2_USE_CCACHE=OFF
+		-DPORTABLE=OFF
+		-DSTATIC=OFF
+		$(usex test "-DSYSTEM_GTEST=ON" "")
+		-DWITH_TESTS=$(usex test)
+		-DUSE_MMAP=ON
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	# Since the tests need the OpenRCT2 data,
+	# we need to symlink them into the build directory,
+	# otherwise some tests will fail, as they don't find the OpenRCT2 data.
+	# It is currently not possible to override that path.
+	# See: https://github.com/OpenRCT2/OpenRCT2/issues/6473
+	ln -s "${S}"/data "${BUILD_DIR}" || die
+
+	cmake_src_test
+}
+
+src_install() {
+	use scripting && DOCS+=( "distribution/scripting.md" "distribution/openrct2.d.ts" )
+
+	cmake_src_install
+
+	if use dedicated; then
+		newinitd "${FILESDIR}"/openrct2.initd openrct2
+		newconfd "${FILESDIR}"/openrct2.confd openrct2
+	fi
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}