From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1196672-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id DE81D13835A
for <garchives@archives.gentoo.org>; Sat, 15 Aug 2020 17:46:04 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 0CBC8E08C4;
Sat, 15 Aug 2020 17:46:04 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id E82F0E08C4
for <gentoo-commits@lists.gentoo.org>; Sat, 15 Aug 2020 17:46:03 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 7633A34F409
for <gentoo-commits@lists.gentoo.org>; Sat, 15 Aug 2020 17:46:02 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 18DDB2EE
for <gentoo-commits@lists.gentoo.org>; Sat, 15 Aug 2020 17:46:01 +0000 (UTC)
From: "Louis Sautier" <sbraz@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Louis Sautier" <sbraz@gentoo.org>
Message-ID: <1597513536.3e7f1e4540edf3b33ec741fd2c2c03547b7de535.sbraz@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-libs/unittest++/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-libs/unittest++/unittest++-2.0.0-r1.ebuild
X-VCS-Directories: dev-libs/unittest++/
X-VCS-Committer: sbraz
X-VCS-Committer-Name: Louis Sautier
X-VCS-Revision: 3e7f1e4540edf3b33ec741fd2c2c03547b7de535
X-VCS-Branch: master
Date: Sat, 15 Aug 2020 17:46:01 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 3bfa4750-c45d-43e7-bd84-4d832d0ac09e
X-Archives-Hash: 0f6acd365ec186eee79134c07102f44b
commit: 3e7f1e4540edf3b33ec741fd2c2c03547b7de535
Author: Louis Sautier <sbraz <AT> gentoo <DOT> org>
AuthorDate: Sat Aug 15 17:39:53 2020 +0000
Commit: Louis Sautier <sbraz <AT> gentoo <DOT> org>
CommitDate: Sat Aug 15 17:45:36 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3e7f1e45
dev-libs/unittest++: bump to EAPI=7, migrate to cmake.eclass
Package-Manager: Portage-3.0.2, Repoman-2.3.23
Signed-off-by: Louis Sautier <sbraz <AT> gentoo.org>
dev-libs/unittest++/unittest++-2.0.0-r1.ebuild | 42 ++++++++++++++++++++++++++
1 file changed, 42 insertions(+)
diff --git a/dev-libs/unittest++/unittest++-2.0.0-r1.ebuild b/dev-libs/unittest++/unittest++-2.0.0-r1.ebuild
new file mode 100644
index 00000000000..0da36ef58d5
--- /dev/null
+++ b/dev-libs/unittest++/unittest++-2.0.0-r1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+MY_PN="unittest-cpp"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="A lightweight unit testing framework for C++"
+HOMEPAGE="https://unittest-cpp.github.io/"
+SRC_URI="https://github.com/${MY_PN}/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+# https://github.com/unittest-cpp/unittest-cpp/commit/2423fcac7668aa9c331a2dcf024c3ca06742942d
+PATCHES=( "${FILESDIR}/${P}-fix-tests-with-clang.patch" )
+
+src_prepare() {
+ cmake_src_prepare
+
+ # https://github.com/unittest-cpp/unittest-cpp/pull/163
+ sed -i '/run unit tests as post build step/,/Running unit tests/d' \
+ CMakeLists.txt || die
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DUTPP_INCLUDE_TESTS_IN_BUILD=$(usex test)
+ )
+ cmake_src_configure
+}
+
+src_test() {
+ "${BUILD_DIR}/TestUnitTest++" || die "Tests failed"
+}