[gentoo-commits] repo/gentoo:master commit in: gnome-extra/evolution-data-server/, gnome-extra/evolution-data-server/files/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     d849945a3cdffa402337ed5b85b72400df80c4ee
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sat Aug  8 15:30:30 2020 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sun Aug  9 07:22:08 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d849945a

gnome-extra/evolution-data-server: bump to 3.36.5, fix USE=gtk-doc build

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 gnome-extra/evolution-data-server/Manifest         |   1 +
 .../evolution-data-server-3.36.5.ebuild            | 150 +++++++++++++++++++++
 .../files/3.36.5-gtk-doc-1.32-compat.patch         |  32 +++++
 3 files changed, 183 insertions(+)

diff --git a/gnome-extra/evolution-data-server/Manifest b/gnome-extra/evolution-data-server/Manifest
index 04a74512747..0659915be7c 100644
--- a/gnome-extra/evolution-data-server/Manifest
+++ b/gnome-extra/evolution-data-server/Manifest
@@ -1 +1,2 @@
 DIST evolution-data-server-3.36.4.tar.xz 4636308 BLAKE2B d701e2220de9aa68a1c5e112de16675c53a33e31441fbfd88d6ac7afa08d60faa3c06d74ee4161f3329b1ba93950f97f32d3cf5714a0de68560053b506425707 SHA512 dea044e12aac92f1cfde18c10f793b75e68e40e27fb9b299c6bdb91e6f19df4224bda7ed32d54a8b8dd517580b69929cff6be0b340e377dbc3bda5c4860f5a3b
+DIST evolution-data-server-3.36.5.tar.xz 4636800 BLAKE2B 5708ec1f064b723cb5421dad50145d2377c2c683ef37fe82d24b6f27a895b89e43c55ae6c900797d477b1af052e0cc6381649c790744d8591010d928822917f1 SHA512 65ec23a665e3a547b10ad6a6be5f0533db269406c3e8db64a63cffb8e1b410e83b9c39bd7cd5dac5ecd5cf61ef96dc529ba1bd00ad0a09b3bf2c4e98f3d156e3

diff --git a/gnome-extra/evolution-data-server/evolution-data-server-3.36.5.ebuild b/gnome-extra/evolution-data-server/evolution-data-server-3.36.5.ebuild
new file mode 100644
index 00000000000..39aaaae43b5
--- /dev/null
+++ b/gnome-extra/evolution-data-server/evolution-data-server-3.36.5.ebuild
@@ -0,0 +1,150 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+VALA_USE_DEPEND="vapigen"
+
+inherit cmake-utils db-use flag-o-matic gnome2 systemd vala virtualx
+
+DESCRIPTION="Evolution groupware backend"
+HOMEPAGE="https://wiki.gnome.org/Apps/Evolution"
+
+# Note: explicitly "|| ( LGPL-2 LGPL-3 )", not "LGPL-2+".
+LICENSE="|| ( LGPL-2 LGPL-3 ) BSD Sleepycat"
+SLOT="0/62-24-20" # subslot = libcamel-1.2/libedataserver-1.2/libebook-1.2.so soname version
+
+IUSE="berkdb +gnome-online-accounts +gtk gtk-doc +introspection ipv6 ldap kerberos oauth vala +weather"
+REQUIRED_USE="vala? ( introspection )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+
+# gdata-0.17.7 soft required for new gdata_feed_get_next_page_token API to handle more than 100 google tasks
+# berkdb needed only for migrating old addressbook data from <3.13 versions, bug #519512
+gdata_depend=">=dev-libs/libgdata-0.17.7:="
+RDEPEND="
+	>=app-crypt/gcr-3.4
+	>=app-crypt/libsecret-0.5[crypt]
+	>=dev-db/sqlite-3.7.17:=
+	>=dev-libs/glib-2.46:2
+	>=dev-libs/libical-3.0.8:=[glib,introspection?]
+	>=dev-libs/libxml2-2
+	>=dev-libs/nspr-4.4:=
+	>=dev-libs/nss-3.9:=
+	>=net-libs/libsoup-2.58:2.4
+
+	dev-libs/icu:=
+	sys-libs/zlib:=
+	virtual/libiconv
+
+	berkdb? ( >=sys-libs/db-4:= )
+	gtk? (
+		>=app-crypt/gcr-3.4[gtk]
+		>=x11-libs/gtk+-3.10:3
+		>=media-libs/libcanberra-0.25[gtk3]
+	)
+	oauth? (
+		>=dev-libs/json-glib-1.0.4
+		>=net-libs/webkit-gtk-2.11.91:4
+		${gdata_depend}
+	)
+	gnome-online-accounts? (
+		>=net-libs/gnome-online-accounts-3.8:=
+		${gdata_depend} )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.12:= )
+	kerberos? ( virtual/krb5:= )
+	ldap? ( >=net-nds/openldap-2:= )
+	weather? ( >=dev-libs/libgweather-3.10:2= )
+"
+DEPEND="${RDEPEND}
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/gperf
+	gtk-doc? ( >=dev-util/gtk-doc-1.14
+		app-text/docbook-xml-dtd:4.1.2 )
+	>=dev-util/intltool-0.35.5
+	>=sys-devel/gettext-0.18.3
+	virtual/pkgconfig
+	vala? ( $(vala_depend)
+		net-libs/libsoup:2.4[vala]
+		dev-libs/libical[vala]
+	)
+"
+
+# Some tests fail due to missing locales.
+# Also, dbus tests are flaky, bugs #397975 #501834
+# It looks like a nightmare to disable those for now.
+RESTRICT="test !test? ( test )"
+
+# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare call
+src_prepare() {
+	use vala && vala_src_prepare
+	cmake-utils_src_prepare
+	gnome2_src_prepare
+
+	eapply "${FILESDIR}"/${PV}-gtk-doc-1.32-compat.patch
+
+	# Make CMakeLists versioned vala enabled
+	sed -e "s;\(find_program(VALAC\) valac);\1 ${VALAC});" \
+		-e "s;\(find_program(VAPIGEN\) vapigen);\1 ${VAPIGEN});" \
+		-i "${S}"/CMakeLists.txt || die
+}
+
+src_configure() {
+	# /usr/include/db.h is always db-1 on FreeBSD
+	# so include the right dir in CPPFLAGS
+	use berkdb && append-cppflags "-I$(db_includedir)"
+
+	local google_enable
+	if use oauth || use gnome-online-accounts; then
+		google_enable="ON"
+	else
+		google_enable="OFF"
+	fi
+
+	# phonenumber does not exist in tree
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+		-DENABLE_GTK_DOC=$(usex gtk-doc)
+		-DWITH_PRIVATE_DOCS=$(usex gtk-doc)
+		-DENABLE_SCHEMAS_COMPILE=OFF
+		-DENABLE_INTROSPECTION=$(usex introspection)
+		-DWITH_KRB5=$(usex kerberos)
+		-DWITH_KRB5_INCLUDES=$(usex kerberos "${EPREFIX}"/usr "")
+		-DWITH_KRB5_LIBS=$(usex kerberos "${EPREFIX}"/usr/$(get_libdir) "")
+		-DWITH_OPENLDAP=$(usex ldap)
+		-DWITH_PHONENUMBER=OFF
+		-DENABLE_SMIME=ON
+		-DENABLE_GTK=$(usex gtk)
+		-DENABLE_CANBERRA=$(usex gtk)
+		-DENABLE_OAUTH2=$(usex oauth)
+		-DENABLE_EXAMPLES=OFF
+		-DENABLE_GOA=$(usex gnome-online-accounts)
+		-DWITH_LIBDB=$(usex berkdb "${EPREFIX}"/usr OFF)
+		# ENABLE_BACKTRACES requires libdwarf ?
+		-DENABLE_IPV6=$(usex ipv6)
+		-DENABLE_WEATHER=$(usex weather)
+		-DENABLE_GOOGLE=${google_enable}
+		-DENABLE_LARGEFILE=ON
+		-DENABLE_VALA_BINDINGS=$(usex vala)
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+}
+
+src_test() {
+	virtx cmake-utils_src_test
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	if use ldap; then
+		insinto /etc/openldap/schema
+		doins "${FILESDIR}"/calentry.schema
+		dosym ../../../usr/share/${PN}/evolutionperson.schema /etc/openldap/schema/evolutionperson.schema
+	fi
+}

diff --git a/gnome-extra/evolution-data-server/files/3.36.5-gtk-doc-1.32-compat.patch b/gnome-extra/evolution-data-server/files/3.36.5-gtk-doc-1.32-compat.patch
new file mode 100644
index 00000000000..3a202bee154
--- /dev/null
+++ b/gnome-extra/evolution-data-server/files/3.36.5-gtk-doc-1.32-compat.patch
@@ -0,0 +1,32 @@
+From 24c7ca17eaf69211b75f2882c11aeff01a3cad01 Mon Sep 17 00:00:00 2001
+From: Mart Raudsepp <leio@gentoo.org>
+Date: Sat, 8 Aug 2020 18:59:25 +0300
+Subject: [PATCH] I#158 - Workaround build error with gtk-doc-1.32
+
+---
+ src/calendar/libecal/e-cal-time-util.h | 2 ++
+ 1 file changed, 2 insertions(+)
+
+diff --git a/src/calendar/libecal/e-cal-time-util.h b/src/calendar/libecal/e-cal-time-util.h
+index 8acb13061..11c9d3369 100644
+--- a/src/calendar/libecal/e-cal-time-util.h
++++ b/src/calendar/libecal/e-cal-time-util.h
+@@ -150,6 +150,7 @@ void		time_to_gdate_with_zone	(GDate *date,
+  * struct tm manipulation
+  **************************************************************************/
+ 
++#ifndef __GTK_DOC_IGNORE__
+ struct tm	e_cal_util_icaltime_to_tm
+ 					(const ICalTime *itt);
+ struct tm	e_cal_util_icaltime_to_tm_with_zone
+@@ -159,6 +160,7 @@ struct tm	e_cal_util_icaltime_to_tm_with_zone
+ ICalTime *	e_cal_util_tm_to_icaltime
+ 					(struct tm *tm,
+ 					 gboolean is_date);
++#endif
+ 
+ G_END_DECLS
+ 
+-- 
+2.20.1
+