[gentoo-commits] repo/gentoo:master commit in: dev-util/shards/

["Sergei Trofimovich" <slyfox@gentoo.org>]

commit:     8072397d1373efa6a3bf32fccb08a3a71dc5c6cf
Author:     Sergei Trofimovich <slyfox <AT> gentoo <DOT> org>
AuthorDate: Sat Aug  8 09:55:32 2020 +0000
Commit:     Sergei Trofimovich <slyfox <AT> gentoo <DOT> org>
CommitDate: Sat Aug  8 09:58:15 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8072397d

dev-util/shards: handle user's LDFLAGS

Reported-by: Agostino Sarubbo
Closes: https://bugs.gentoo.org/736374
Package-Manager: Portage-3.0.1, Repoman-2.3.23
Signed-off-by: Sergei Trofimovich <slyfox <AT> gentoo.org>

 dev-util/shards/shards-0.12.0-r1.ebuild | 46 +++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

diff --git a/dev-util/shards/shards-0.12.0-r1.ebuild b/dev-util/shards/shards-0.12.0-r1.ebuild
new file mode 100644
index 00000000000..fca8719df78
--- /dev/null
+++ b/dev-util/shards/shards-0.12.0-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit multiprocessing toolchain-funcs
+
+CRYSTAL_MOLINILLO_PV=0.1.0
+CRYSTAL_MOLINILLO_P=crystal-molinillo-${CRYSTAL_MOLINILLO_PV}
+
+DESCRIPTION="Dependency manager for the Crystal language"
+HOMEPAGE="https://github.com/crystal-lang/shards"
+SRC_URI="
+	https://github.com/crystal-lang/shards/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	https://github.com/crystal-lang/crystal-molinillo/archive/v${CRYSTAL_MOLINILLO_PV}.tar.gz -> ${CRYSTAL_MOLINILLO_P}.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND="
+	>dev-lang/crystal-0.11.1[yaml]
+"
+RDEPEND="${DEPEND}"
+
+RESTRICT=test # missing files in tarball
+
+src_prepare() {
+	default
+
+	# bundle crystal-molinillo to bootstrap 'shards'
+	mkdir -p lib || die
+	ln -s ../../${CRYSTAL_MOLINILLO_P} lib/molinillo || die
+
+	tc-export CC
+}
+
+src_compile() {
+	emake release=1 FLAGS="--link-flags=\"${LDFLAGS}\" --verbose --threads $(makeopts_jobs)"
+}
+
+src_install() {
+	dobin bin/${PN}
+	dodoc README.md
+}