[gentoo-commits] repo/gentoo:master commit in: dev-python/symengine/

["Sam James" <sam@gentoo.org>]

commit:     60e3d1f856925292be9f579cbd088de3f7dedb9e
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun Aug  2 18:58:53 2020 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Aug  2 18:58:53 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=60e3d1f8

dev-python/symengine: bump to 0.6.1

* Bump to 0.6.1
* Add Python 3.{8,9}
* Use pytest to run tests instead of nose

Closes: https://bugs.gentoo.org/720762
Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-python/symengine/Manifest               |  1 +
 dev-python/symengine/symengine-0.6.1.ebuild | 60 +++++++++++++++++++++++++++++
 2 files changed, 61 insertions(+)

diff --git a/dev-python/symengine/Manifest b/dev-python/symengine/Manifest
index d0314bc5b09..4c55975bd99 100644
--- a/dev-python/symengine/Manifest
+++ b/dev-python/symengine/Manifest
@@ -1 +1,2 @@
 DIST symengine.py-0.5.1.tar.gz 110864 BLAKE2B 30309b87cc612df37fca94df5c3199401a2cff9fd782de2fa00910bf17a1bb2debfb851aefc6178a38eafe49055950b76373c6e9a81a2fe5814497c2894b5f8e SHA512 85df42245daad0387886f003a593e8d45f34e51db4ed207f6bb70f573704a33f24a1cbe30f1c67c2c1541f1e800208c90b3ce3ec35c9d4eab05bbdb5be570ef5
+DIST symengine.py-0.6.1.tar.gz 112123 BLAKE2B 3b55ddd834c7401a5a211e5e20bafbea68b172738c6388e72b1e6a6e62719e19f28356fb6156caa6cfbad59d051de45c0e103a89d675e3453136cc85e638f327 SHA512 09f452757e3c99dc9d896a322a07d58f57af6d57a9eaa615b9f4f3d834cfc91f6a79de955a36ad94bc30c962365272ef0afe401570583af49c015295ccd7c4ed

diff --git a/dev-python/symengine/symengine-0.6.1.ebuild b/dev-python/symengine/symengine-0.6.1.ebuild
new file mode 100644
index 00000000000..f75bf9e3ef3
--- /dev/null
+++ b/dev-python/symengine/symengine-0.6.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit distutils-r1
+
+MYP=${PN}.py-${PV}
+
+DESCRIPTION="Python wrappers to the symengine C++ library"
+HOMEPAGE="https://github.com/symengine/symengine.py"
+SRC_URI="https://github.com/symengine/symengine.py/archive/v${PV}.tar.gz -> ${MYP}.tar.gz"
+S="${WORKDIR}/${MYP}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	dev-util/cmake
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		dev-python/sympy[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	dev-python/numpy[${PYTHON_USEDEP}]
+	>=sci-libs/symengine-0.6
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	default
+
+	# Don't install tests
+	> "${S}/symengine/tests/CMakeLists.txt" || die
+}
+
+python_test() {
+	cd "${BUILD_DIR}" || die
+	pytest -vv || die "Tests failed with ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install
+	python_optimize
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	python_optimize
+
+	rm "${ED}"/usr/share/doc/${PF}/README.md || die
+	newdoc README.md ${PN}.py.md
+}