[gentoo-commits] repo/gentoo:master commit in: kde-plasma/kscreenlocker/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     c58d0a1d310cc2361a9d1cefedf97da3f7c8c6dc
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Aug  1 17:48:34 2020 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Aug  1 22:57:20 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c58d0a1d

kde-plasma/kscreenlocker: Disable seccomp sandboxing in 5.19 too

If upstream dropped it in master for being problematic and ineffective,
then there's no reason to keep it in stable branch either.

Upstream commit f53b9b3275abd935fc81a60adcc38699f3ccec46

Package-Manager: Portage-3.0.1, Repoman-2.3.23
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../kscreenlocker/kscreenlocker-5.19.4-r1.ebuild   | 97 ++++++++++++++++++++++
 1 file changed, 97 insertions(+)

diff --git a/kde-plasma/kscreenlocker/kscreenlocker-5.19.4-r1.ebuild b/kde-plasma/kscreenlocker/kscreenlocker-5.19.4-r1.ebuild
new file mode 100644
index 00000000000..06317c83154
--- /dev/null
+++ b/kde-plasma/kscreenlocker/kscreenlocker-5.19.4-r1.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_TEST="forceoptional"
+KFMIN=5.71.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.14.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org pam
+
+DESCRIPTION="Library and components for secure lock screen architecture"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="consolekit +pam"
+
+RDEPEND="
+	dev-libs/wayland
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kidletime-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kpackage-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwayland-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	x11-libs/libX11
+	x11-libs/libXi
+	x11-libs/libxcb
+	x11-libs/xcb-util-keysyms
+	consolekit? ( sys-auth/consolekit )
+	pam? ( sys-libs/pam )
+"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto
+"
+PDEPEND="
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+"
+
+RESTRICT+=" test"
+
+src_prepare() {
+	ecm_src_prepare
+
+	if ! use test; then
+		sed -e "/add_subdirectory(autotests)/ s/^/#/" \
+			-i greeter/CMakeLists.txt || die
+	fi
+}
+
+src_test() {
+	# requires running environment
+	local myctestargs=(
+		-E x11LockerTest
+	)
+	ecm_src_test
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Seccomp=ON
+		$(cmake_use_find_package consolekit loginctl)
+		-DPAM_REQUIRED=$(usex pam)
+		$(cmake_use_find_package pam PAM)
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+
+	use pam && newpamd "${FILESDIR}/kde.pam" kde
+	use pam && newpamd "${FILESDIR}/kde-np.pam" kde-np
+
+	if ! use pam; then
+		chown root "${ED}"/usr/$(get_libdir)/libexec/kcheckpass || die
+		chmod +s "${ED}"/usr/$(get_libdir)/libexec/kcheckpass || die
+	fi
+}