[gentoo-commits] repo/gentoo:master commit in: net-im/spectrum2/

["Conrad Kostecki" <conikost@gentoo.org>]

commit:     b43e934ebfdd14c72dc35cce2fab950bf4af2ccb
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Thu Jul 30 13:29:19 2020 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Thu Jul 30 13:37:53 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b43e934e

net-im/spectrum2: enable tests (stable)

Since python isn't needed at all for tests, it can be dropped.

Bug: https://bugs.gentoo.org/734558
Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 net-im/spectrum2/spectrum2-2.0.12-r3.ebuild | 107 ++++++++++++++++++++++++++++
 1 file changed, 107 insertions(+)

diff --git a/net-im/spectrum2/spectrum2-2.0.12-r3.ebuild b/net-im/spectrum2/spectrum2-2.0.12-r3.ebuild
new file mode 100644
index 00000000000..85771c62be5
--- /dev/null
+++ b/net-im/spectrum2/spectrum2-2.0.12-r3.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake systemd
+
+DESCRIPTION="An open source instant messaging transport"
+HOMEPAGE="https://www.spectrum.im"
+SRC_URI="https://github.com/SpectrumIM/spectrum2/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="amd64"
+IUSE="doc frotz irc mysql postgres purple sms +sqlite test twitter whatsapp xmpp"
+REQUIRED_USE="|| ( mysql postgres sqlite )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	acct-group/spectrum
+	acct-user/spectrum
+	dev-libs/boost:=[nls]
+	dev-libs/expat
+	dev-libs/libev:=
+	dev-libs/log4cxx
+	dev-libs/jsoncpp:=
+	dev-libs/openssl:0=
+	dev-libs/popt
+	dev-libs/protobuf:=
+	net-dns/libidn:0=
+	net-im/swift:=
+	net-misc/curl
+	sys-libs/zlib:=
+	frotz? ( !games-engines/frotz )
+	irc? ( net-im/libcommuni )
+	mysql? (
+		|| (
+			dev-db/mariadb-connector-c
+			dev-db/mysql-connector-c
+		)
+	)
+	postgres? ( >=dev-libs/libpqxx-6.4.5:= )
+	purple? (
+		dev-libs/glib
+		net-im/pidgin:=
+	)
+	sms? ( app-mobilephone/smstools )
+	sqlite? ( dev-db/sqlite:3 )
+	twitter? ( net-misc/curl )
+	whatsapp? ( net-im/transwhat )"
+
+DEPEND="
+	${RDEPEND}
+	doc? ( app-doc/doxygen )
+	test? (	dev-util/cppunit )
+"
+
+PATCHES="
+	"${FILESDIR}/${P}-boost-173-compatibility.patch"
+	"${FILESDIR}/${P}-gcc-10-compatibility.patch"
+"
+
+src_prepare() {
+	# Respect users LDFLAGS
+	sed -i -e "s/-Wl,-export-dynamic/& ${LDFLAGS}/" spectrum/src/CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_DOCS="$(usex doc)"
+		-DENABLE_FROTZ="$(usex frotz)"
+		-DENABLE_IRC="$(usex irc)"
+		-DENABLE_MYSQL="$(usex mysql)"
+		-DENABLE_PQXX="$(usex postgres)"
+		-DENABLE_PURPLE="$(usex purple)"
+		$(usex irc '-DENABLE_QT4=OFF' '')
+		-DENABLE_SMSTOOLS3="$(usex sms)"
+		-DENABLE_SQLITE3="$(usex sqlite)"
+		-DENABLE_TESTS="$(usex test)"
+		-DENABLE_TWITTER="$(usex twitter)"
+		-DENABLE_XMPP="$(usex xmpp)"
+		-DLIB_INSTALL_DIR="$(get_libdir)"
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	cd "${BUILD_DIR}/tests/libtransport" || die
+	./libtransport_test || die
+}
+
+src_install() {
+	cmake_src_install
+
+	diropts -o spectrum -g spectrum
+	keepdir /var/log/spectrum2 /var/lib/spectrum2
+	diropts
+
+	newinitd "${FILESDIR}"/spectrum2.initd spectrum2
+	systemd_newunit "${FILESDIR}"/spectrum2.service spectrum2.service
+	systemd_newtmpfilesd "${FILESDIR}"/spectrum2.tmpfiles-r1 spectrum2.conf
+
+	einstalldocs
+}