[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-shell-extension-gsconnect/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     b49a38748eebe63e428f48267fe6a6d139f94c3c
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Wed Jul 15 08:21:55 2020 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Wed Jul 15 08:22:35 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b49a3874

gnome-extra/gnome-shell-extension-gsconnect: Bump to v39

Closes: https://bugs.gentoo.org/732466
Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 .../gnome-shell-extension-gsconnect/Manifest       |  1 +
 .../gnome-shell-extension-gsconnect-39.ebuild      | 64 ++++++++++++++++++++++
 2 files changed, 65 insertions(+)

diff --git a/gnome-extra/gnome-shell-extension-gsconnect/Manifest b/gnome-extra/gnome-shell-extension-gsconnect/Manifest
index bcad0843b64..b6e02f4c3ff 100644
--- a/gnome-extra/gnome-shell-extension-gsconnect/Manifest
+++ b/gnome-extra/gnome-shell-extension-gsconnect/Manifest
@@ -1 +1,2 @@
 DIST gnome-shell-extension-gsconnect-33.tar.gz 314704 BLAKE2B fa4f2eb6325356a058b24b92b683ca7331af30112d27060e8ee191c21a3269639da58992d53434c7121ea511ee9e07869b082f908b59e19fc2434f3c07e09624 SHA512 26ef929b9b128db0cb29fba22203a3afd500c5b1c3bac6917926a60350d271e67bb0985866f84877355c079fe4a5656b8ac5e8dae976d17d9a068cc825293bce
+DIST gnome-shell-extension-gsconnect-39.tar.gz 306878 BLAKE2B 273d2841d39a7786f40062dbc60cbefd48cfa589d91c938c6fdb6e61c3ffefe3621613aa59cb2526165e20fd6f62c526a5150b369f7f8d3fa1d828b05c95d817 SHA512 e62b9acd5ec3fed6be602dfeba747913a8c0d9c243d6b9b67a9c42d635f693c168052957edbcf598869f3dd45e15822c045bf1ac545729da2d45557a47fa85dd

diff --git a/gnome-extra/gnome-shell-extension-gsconnect/gnome-shell-extension-gsconnect-39.ebuild b/gnome-extra/gnome-shell-extension-gsconnect/gnome-shell-extension-gsconnect-39.ebuild
new file mode 100644
index 00000000000..95d0c91e919
--- /dev/null
+++ b/gnome-extra/gnome-shell-extension-gsconnect/gnome-shell-extension-gsconnect-39.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit gnome2-utils meson readme.gentoo-r1
+
+DESCRIPTION="KDE Connect implementation for Gnome Shell"
+HOMEPAGE="https://github.com/andyholmes/gnome-shell-extension-gsconnect"
+SRC_URI="https://github.com/andyholmes/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nautilus"
+
+COMMON_DEPEND="dev-libs/glib:2"
+RDEPEND="${COMMON_DEPEND}
+	app-eselect/eselect-gnome-shell-extensions
+	>=dev-libs/gjs-1.48
+	=gnome-base/gnome-shell-3.36*
+	gnome-base/gvfs
+	gnome-extra/evolution-data-server
+	|| ( media-libs/libcanberra media-libs/gsound )
+	nautilus? (
+		dev-python/nautilus-python
+		gnome-base/nautilus[introspection] )
+"
+DEPEND="${COMMON_DEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="For knowing more about how to do the setup, please visit:
+https://github.com/andyholmes/gnome-shell-extension-gsconnect/wiki/Installation"
+
+src_configure() {
+	# nemo support relies on nemo-python from https://github.com/linuxmint/nemo-extensions
+	# https://bugs.gentoo.org/694388
+	meson_src_configure \
+		-Dnemo=false \
+		$(meson_use nautilus)
+}
+
+src_install() {
+	meson_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_preinst() {
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	ebegin "Updating list of installed extensions"
+	eselect gnome-shell-extensions update
+	eend $?
+	readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+}