[gentoo-commits] repo/gentoo:master commit in: gnome-base/gnome-control-center/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     8f852e47f905f4f151f5179a1fba3f4fd0468883
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sun Jul 12 11:50:48 2020 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sun Jul 12 21:02:46 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8f852e47

gnome-base/gnome-control-center: bump to 3.36.4

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 gnome-base/gnome-control-center/Manifest           |   2 +
 .../gnome-control-center-3.36.4.ebuild             | 180 +++++++++++++++++++++
 2 files changed, 182 insertions(+)

diff --git a/gnome-base/gnome-control-center/Manifest b/gnome-base/gnome-control-center/Manifest
index d1ce1aa54c6..923d73fad03 100644
--- a/gnome-base/gnome-control-center/Manifest
+++ b/gnome-base/gnome-control-center/Manifest
@@ -1,2 +1,4 @@
 DIST gnome-control-center-3.34.5-patchset.tar.xz 7500 BLAKE2B 6ec377725fa81a2d49eb0496b31adf7a303505b4478781dd3d4f2c0b204996ae94e3bb5b9b43c324d8e317d66646ee28fa2e471ff884b709c03419fd0243f342 SHA512 c658f0515a7b72c78c3ec6c78a1586169d21f01a40211e14d9e70fade3d5a18e29639c2aa5ef37dc6c741df9f9b7478cb221c83e3f1b4e4876e6b854e38ff524
 DIST gnome-control-center-3.34.5.tar.xz 6234916 BLAKE2B 9c41ee8f24a66ff66173587f0f75bb743434f21315281db11577bed2c4770c9da5606df37020d4951b7e542171298abceef65ba02e66519737aeb30bb6bd3861 SHA512 564cf514345c45c39003e309d9d93a862cfe801e84968412f6c69031745df0683716423de2d85cde166fc9eb256a45be713e7eb62c8ac3e8e4a59e91ab160156
+DIST gnome-control-center-3.36.4-patchset.tar.xz 12320 BLAKE2B a387d793186c898a14d54060214fbd075389afe402b1ad937a00295eed339a529863752324ba26f691ad468f214acda60be5bc23167d95fdf842f26a24442e55 SHA512 6f11425f13590e7850114613efa82e8762bd62687839c9374d2618ab81a08f1abb871d2a8f452811e46fa53af7007167f7b9ca68e0822daee22e9de33e0be94b
+DIST gnome-control-center-3.36.4.tar.xz 6304992 BLAKE2B 7c52faf2a9a0f642f24f59e2035ae57e7816d69c8ee639cde76db7d69f8063c9eff2e068b95710d13316c267b5cf6c6647cb1359ac592968b1c5021730081130 SHA512 e6c398256215a139042e5bb0db7c83fc0e39f99ab893760e37ba303ec4c932a37da352b92487ed1bdc61f2e8f61352c752b48ab549269e3f84e21a71cdf32abf

diff --git a/gnome-base/gnome-control-center/gnome-control-center-3.36.4.ebuild b/gnome-base/gnome-control-center/gnome-control-center-3.36.4.ebuild
new file mode 100644
index 00000000000..f604537b2e2
--- /dev/null
+++ b/gnome-base/gnome-control-center/gnome-control-center-3.36.4.ebuild
@@ -0,0 +1,180 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit gnome.org gnome2-utils meson python-any-r1 xdg
+
+DESCRIPTION="GNOME's main interface to configure various aspects of the desktop"
+HOMEPAGE="https://git.gnome.org/browse/gnome-control-center/"
+SRC_URI+=" https://dev.gentoo.org/~leio/distfiles/${P}-patchset.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="2"
+IUSE="+bluetooth +cups debug elogind flickr +gnome-online-accounts +ibus input_devices_wacom kerberos networkmanager systemd test v4l wayland"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+	flickr? ( gnome-online-accounts )
+	^^ ( elogind systemd )
+" # Theoretically "?? ( elogind systemd )" is fine too, lacking some functionality at runtime, but needs testing if handled gracefully enough
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~x86"
+
+# kerberos unfortunately means mit-krb5; build fails with heimdal
+# display panel requires colord and gnome-settings-daemon[colord]
+# wacom panel requires gsd-enums.h from gsd at build time, probably also runtime support
+# printer panel requires cups and smbclient (the latter is not patched yet to be separately optional)
+# First block is toplevel meson.build deps in order of occurrence (plus deeper deps if in same conditional). Second block is dependency() from subdir meson.builds, sorted by directory name occurrence order
+DEPEND="
+	>=gui-libs/libhandy-0.0.9:0.0=
+	gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.25.3:= )
+	>=media-sound/pulseaudio-2.0[glib]
+	>=sys-apps/accountsservice-0.6.39
+	>=x11-misc/colord-0.1.34:0=
+	>=x11-libs/gdk-pixbuf-2.23.0:2
+	>=dev-libs/glib-2.56.0:2
+	>=gnome-base/gnome-desktop-3.27.90:3=
+	>=gnome-base/gnome-settings-daemon-3.27.90[colord,input_devices_wacom?]
+	>=gnome-base/gsettings-desktop-schemas-3.31.0
+	dev-libs/libxml2:2
+	>=sys-auth/polkit-0.114
+	>=sys-power/upower-0.99.8:=
+	>=dev-libs/libgudev-232
+	x11-libs/libX11
+	>=x11-libs/libXi-1.2
+	media-libs/libepoxy
+	flickr? ( >=media-libs/grilo-0.3.0:0.3= )
+	>=x11-libs/gtk+-3.22.0:3[X,wayland=]
+	cups? (
+		>=net-print/cups-1.7[dbus]
+		>=net-fs/samba-4.0.0[client]
+	)
+	v4l? (
+		>=media-video/cheese-3.28.0 )
+	ibus? ( >=app-i18n/ibus-1.5.2 )
+	networkmanager? (
+		>=net-libs/libnma-1.8.0
+		>=net-misc/networkmanager-1.12.0:=[modemmanager]
+		>=net-misc/modemmanager-0.7.990 )
+	bluetooth? ( >=net-wireless/gnome-bluetooth-3.18.2:= )
+	input_devices_wacom? ( >=dev-libs/libwacom-0.27 )
+	kerberos? ( app-crypt/mit-krb5 )
+
+	x11-libs/cairo[glib]
+	>=x11-libs/colord-gtk-0.1.24
+	net-libs/libsoup:2.4
+	media-libs/fontconfig
+	gnome-base/libgtop:2=
+	>=sys-fs/udisks-2.1.8:2
+	app-crypt/libsecret
+	media-libs/gsound
+	>=dev-libs/libpwquality-1.2.2
+"
+# systemd/elogind USE flagged because package manager will potentially try to satisfy a
+# "|| ( systemd ( elogind openrc-settingsd)" via systemd if openrc-settingsd isn't already installed.
+# libgnomekbd needed only for gkbd-keyboard-display tool
+# gnome-color-manager needed for gcm-calibrate and gcm-viewer calls from color panel
+# <gnome-color-manager-3.1.2 has file collisions with g-c-c-3.1.x
+#
+# mouse panel needs a concrete set of X11 drivers at runtime, bug #580474
+# Also we need newer driver versions to allow wacom and libinput drivers to
+# not collide
+#
+# system-config-printer provides org.fedoraproject.Config.Printing service and interface
+# cups-pk-helper provides org.opensuse.cupspkhelper.mechanism.all-edit policykit helper policy
+RDEPEND="${DEPEND}
+	systemd? ( >=sys-apps/systemd-31 )
+	elogind? ( app-admin/openrc-settingsd
+		sys-auth/elogind )
+	x11-themes/adwaita-icon-theme
+	>=gnome-extra/gnome-color-manager-3.1.2
+	cups? (
+		app-admin/system-config-printer
+		net-print/cups-pk-helper )
+	>=gnome-base/libgnomekbd-3
+	wayland? ( dev-libs/libinput )
+	!wayland? (
+		>=x11-drivers/xf86-input-libinput-0.19.0
+		input_devices_wacom? ( >=x11-drivers/xf86-input-wacom-0.33.0 ) )
+	flickr? ( media-plugins/grilo-plugins:0.3[flickr,gnome-online-accounts] )
+
+	!<gnome-base/gdm-2.91.94
+	!gnome-extra/gnome-media[pulseaudio]
+	!<gnome-extra/gnome-media-2.32.0-r300
+	!<net-wireless/gnome-bluetooth-3.3.2
+"
+# PDEPEND to avoid circular dependency; gnome-session-check-accelerated called by info panel
+# gnome-session-2.91.6-r1 also needed so that 10-user-dirs-update is run at login
+PDEPEND=">=gnome-base/gnome-session-2.91.6-r1
+	networkmanager? ( gnome-extra/nm-applet )" # networking panel can call into nm-connection-editor
+
+BDEPEND="
+	dev-libs/libxslt
+	app-text/docbook-xsl-stylesheets
+	app-text/docbook-xml-dtd:4.2
+	x11-base/xorg-proto
+	dev-libs/libxml2:2
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	test? ( $(python_gen_any_dep '
+		dev-python/dbusmock[${PYTHON_USEDEP}]
+	') )
+"
+
+PATCHES=(
+	# Patches from gnome-3-36 branch on top of 3.36.4
+	# Makes some panels and dependencies optional
+	# https://bugzilla.gnome.org/686840, 697478, 700145
+	# Fix some absolute paths to be appropriate for Gentoo
+	"${WORKDIR}"/patches/
+)
+
+python_check_deps() {
+	use test && \
+		has_version "dev-python/dbusmock[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	xdg_src_prepare
+	# Mark python tests with shebang executable, so that meson will launch them directly, instead
+	# of via its own python-single-r1 version, which might not match what we get from python_check_deps
+	chmod a+x tests/network/test-network-panel.py tests/datetime/test-datetime.py || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use bluetooth)
+		$(meson_use v4l cheese)
+		-Dcups=$(usex cups enabled disabled)
+		-Ddocumentation=true # manpage
+		-Dgoa=$(usex gnome-online-accounts enabled disabled)
+		-Dgrilo=$(usex flickr enabled disabled)
+		$(meson_use ibus)
+		-Dkerberos=$(usex kerberos enabled disabled)
+		$(meson_use networkmanager network_manager)
+		-Dprivileged_group=wheel
+		-Dsnap=false
+		$(meson_use test tests)
+		$(meson_use debug tracing)
+		$(meson_use input_devices_wacom wacom)
+		#$(meson_use wayland) # doesn't do anything in 3.34 and 3.36 due to unified gudev handling code
+		# bashcompletions installed to $datadir/bash-completion/completions by v3.28.2, which is the same as $(get_bashcompdir)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}