[gentoo-commits] repo/gentoo:master commit in: dev-python/cython/

["Michał Górny" <mgorny@gentoo.org>]

commit:     9f67290e8ead6d4dac0c985f636d8475c4b92f87
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Jul 10 05:47:59 2020 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Jul 10 06:30:01 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9f67290e

dev-python/cython: Bump to 0.29.21

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/cython/Manifest              |  1 +
 dev-python/cython/cython-0.29.21.ebuild | 80 +++++++++++++++++++++++++++++++++
 2 files changed, 81 insertions(+)

diff --git a/dev-python/cython/Manifest b/dev-python/cython/Manifest
index d4a04a90b5e..f2ae5fe7002 100644
--- a/dev-python/cython/Manifest
+++ b/dev-python/cython/Manifest
@@ -3,3 +3,4 @@ DIST cython-0.29.17.gh.tar.gz 2080768 BLAKE2B f53f8593f4ab9ef87c8fff47a031d365a7
 DIST cython-0.29.18.gh.tar.gz 2083532 BLAKE2B 7e10a32f15542ed0d7d381223f6f20ec75d7ec39979ca58192cc0f95407cece31fb053776072b49e447ffb0ab5ad1918c6b53ad8cb277df08fabe0eab8ccf958 SHA512 5a1430345fbe42235a58fd44dd4e4ce17c68485349295af6c4e9a01a06117e18ee7700c34fb5974759f012acd5cf8400ed014ef16397539272c38881e905234a
 DIST cython-0.29.19.gh.tar.gz 2083634 BLAKE2B 47ed2c8b8c4d56889f4414b974edac878a454c2cefff77bb3ac5cb51f926c19e3466949e0c9f470d896589e881afa32d8873c71d54b3999d221ae94f2b2d4588 SHA512 402f95f82099db0ae99ca2f849a9aef97558c9c6be62d3b3c66c346ecc94efbbe824ffc77f3cc6dd1d7054a2fb0332b10fe855ca1b054095f2df2ee297fd96a7
 DIST cython-0.29.20.gh.tar.gz 2087315 BLAKE2B c429dd2aec6c6dec0a3430ad8aefd17b62b65d9e2e7be0d48e0ebb808897533ac724ba69bdd639e3cdab2da2399f7dccea524dd71a48594e44c7a737026a5b5a SHA512 5bd0506abf8e0a823316e697db021e1e12296fecef2165ea4b84fa595554ebcdcf2688cb675c77e0e1567ab44ed502757b5eb4ea55b84505ae350f70e4d90ecc
+DIST cython-0.29.21.gh.tar.gz 2088511 BLAKE2B 7a4ddabb65a519d3c71454ac8417438a3a9c46b47489c18e7c7e82ffcb5d5f2f0c5246d0b364f8317d374c53f0c83844c73c7d2ef6b9f75f10707aaf2931ce41 SHA512 2c0c3e3fff07106eb98862f71cd5dec9ff29460cf9b9e4de74537ca5e033f7523989beb5fbdc14723beaf94a535976f75c803e791b87e017961d9694b8c37679

diff --git a/dev-python/cython/cython-0.29.21.ebuild b/dev-python/cython/cython-0.29.21.ebuild
new file mode 100644
index 00000000000..722278a0cee
--- /dev/null
+++ b/dev-python/cython/cython-0.29.21.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{6,7,8,9} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 toolchain-funcs elisp-common
+
+DESCRIPTION="A Python to C compiler"
+HOMEPAGE="https://cython.org https://pypi.org/project/Cython/
+	https://github.com/cython/cython"
+SRC_URI="https://github.com/cython/cython/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+IUSE="emacs test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	emacs? ( >=app-editors/emacs-23.1:* )
+"
+BDEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		$(python_gen_cond_dep 'dev-python/numpy[${PYTHON_USEDEP}]' \
+			python3_{6,7,8})
+	)"
+
+PATCHES=(
+	"${FILESDIR}/cython-0.29.14-sphinx-update.patch"
+)
+
+SITEFILE=50cython-gentoo.el
+
+distutils_enable_sphinx docs
+
+python_compile() {
+	if ! python_is_python3; then
+		local CFLAGS="${CFLAGS} -fno-strict-aliasing"
+		local CXXFLAGS="${CXXFLAGS} -fno-strict-aliasing"
+	fi
+
+	# Python gets confused when it is in sys.path before build.
+	local -x PYTHONPATH=
+
+	distutils-r1_python_compile
+}
+
+python_compile_all() {
+	use emacs && elisp-compile Tools/cython-mode.el
+}
+
+python_test() {
+	tc-export CC
+	# https://github.com/cython/cython/issues/1911
+	local -x CFLAGS="${CFLAGS} -fno-strict-overflow"
+	"${PYTHON}" runtests.py -vv --work-dir "${BUILD_DIR}"/tests \
+		|| die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	local DOCS=( CHANGES.rst README.rst ToDo.txt USAGE.txt )
+	distutils-r1_python_install_all
+
+	if use emacs; then
+		elisp-install ${PN} Tools/cython-mode.*
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}