[gentoo-commits] repo/gentoo:master commit in: app-office/gtg/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     cb82ba8ccd9ca739ee6d84c261067a0baa9b55a2
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Wed Jul  8 05:55:37 2020 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Wed Jul  8 05:58:33 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cb82ba8c

app-office/gtg: bump to 0.4.0

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 app-office/gtg/Manifest         |  1 +
 app-office/gtg/gtg-0.4.0.ebuild | 57 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 58 insertions(+)

diff --git a/app-office/gtg/Manifest b/app-office/gtg/Manifest
index 9da4a2b54e3..982ff10fe50 100644
--- a/app-office/gtg/Manifest
+++ b/app-office/gtg/Manifest
@@ -1 +1,2 @@
+DIST gtg-0.4.0.tar.xz 3744752 BLAKE2B fdeabe32135dea24ac6113a486650b66b5143aa745117029b03e26e1bb3f2e8629623b26efdae0c8217741a2b4964b5dc060f0e450c05c950e21ea360f3f3823 SHA512 f2677f6bbc0b6cb21b7882a2bd0342b4919581c12e4aa43c13b5dbc48740418c512a41619584d0d75bfa63ebc4a5460abfbc27360e1817c8832cbecf3c34a60e
 DIST gtg-0.4.0_pre20200613.tar.gz 4827071 BLAKE2B 80515f064b4a034066a86c1b63dcb4e2510e49493b067991b7135a3914b1d75ebfc7f18132d6db81e55fdec34a0225c3147b55dc1e0c891540b2b895f3768f2d SHA512 8d4c9460693f7a913c224bd22aacec5b7db67faa5e74e8575fe99d2e792e8f95f6480e1d0ecc3ac77b0533403b8baa41ece315bd14782fb3c783315aa3d7a5fb

diff --git a/app-office/gtg/gtg-0.4.0.ebuild b/app-office/gtg/gtg-0.4.0.ebuild
new file mode 100644
index 00000000000..135111e7c82
--- /dev/null
+++ b/app-office/gtg/gtg-0.4.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+PYTHON_COMPAT=( python3_{7..8} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit meson python-single-r1 xdg
+
+DESCRIPTION="Personal organizer for the GNOME desktop environment"
+HOMEPAGE="https://wiki.gnome.org/Apps/GTG/"
+SRC_URI="https://github.com/getting-things-gnome/gtg/releases/download/v0.4/${P}.tar.xz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		>=dev-python/liblarch-3.0[${PYTHON_USEDEP}]
+		dev-python/pyxdg[${PYTHON_USEDEP}]
+		dev-python/pycairo[${PYTHON_USEDEP}]
+	')
+	x11-libs/pango[introspection]
+	x11-libs/gdk-pixbuf[introspection]
+	x11-libs/gtk+:3[introspection]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	test? ( $(python_gen_cond_dep '
+			dev-python/nose[${PYTHON_USEDEP}]
+			dev-python/cheetah3[${PYTHON_USEDEP}]
+			dev-python/mock[${PYTHON_USEDEP}]
+		')
+		app-text/pdfjam
+		app-text/pdftk
+		dev-texlive/texlive-latex
+	)
+"
+
+src_install() {
+	meson_src_install
+	python_fix_shebang "${ED}"/usr/bin/gtg
+	python_optimize
+}
+
+src_test() {
+	nosetests -v || die
+}