[gentoo-commits] proj/kde:master commit in: kde-apps/kross-interpreters/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     3e1efa85f8d73688c2d70b166ac24259915bfcd7
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Jul  7 09:20:31 2020 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Jul  7 09:20:31 2020 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=3e1efa85

kde-apps/kross-interpreters: 20.04.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../kross-interpreters-20.04.3.ebuild              | 42 ++++++++++++++++++++++
 1 file changed, 42 insertions(+)

diff --git a/kde-apps/kross-interpreters/kross-interpreters-20.04.3.ebuild b/kde-apps/kross-interpreters/kross-interpreters-20.04.3.ebuild
new file mode 100644
index 0000000000..1fb7b6795d
--- /dev/null
+++ b/kde-apps/kross-interpreters/kross-interpreters-20.04.3.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 )
+USE_RUBY="ruby25 ruby26 ruby27"
+KFMIN=5.70.0
+QTMIN=5.14.2
+inherit ecm kde.org python-single-r1 ruby-single
+
+DESCRIPTION="Kross interpreter plugins for programming languages"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+python ruby"
+
+REQUIRED_USE="|| ( python ruby ) python? ( ${PYTHON_REQUIRED_USE} )"
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kross-${KFMIN}:5
+	python? ( ${PYTHON_DEPS} )
+	ruby? ( ${RUBY_DEPS} )
+"
+RDEPEND="${DEPEND}"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_python=$(usex python)
+		-DBUILD_ruby=$(usex ruby)
+	)
+
+	ecm_src_configure
+}