[gentoo-commits] repo/gentoo:master commit in: gnome-extra/evolution-ews/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     e573e3a772d6a8e8c03d7117f24dbe19fb2777ed
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sat Jul  4 17:59:54 2020 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sat Jul  4 21:18:18 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e573e3a7

gnome-extra/evolution-ews: bump to 3.36.4

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 gnome-extra/evolution-ews/Manifest                 |  1 +
 .../evolution-ews/evolution-ews-3.36.4.ebuild      | 65 ++++++++++++++++++++++
 2 files changed, 66 insertions(+)

diff --git a/gnome-extra/evolution-ews/Manifest b/gnome-extra/evolution-ews/Manifest
index 29fc0c62609..63c3b79291f 100644
--- a/gnome-extra/evolution-ews/Manifest
+++ b/gnome-extra/evolution-ews/Manifest
@@ -1 +1,2 @@
 DIST evolution-ews-3.36.3.tar.xz 553676 BLAKE2B ec9c0e167c05f7606585d5bbce8c0f53ec9c48b3f8b68c6ec5b6f3776cce12e34a75eae658df704519111022f60353a0b114d3aa186b93c8a8b3ded3240ccd79 SHA512 d625a70410db238ce0ad9dc8bb048346d20c43053406aa98bc81e0c087621b5d0701644a548d525be5a21b283923bb505499b8826e3a23a753465411f2c600a8
+DIST evolution-ews-3.36.4.tar.xz 558764 BLAKE2B 04823d04577b9d5597edf4b534d13f3bd82ac345bcfc5600a28f104917bb3f26513ae2fd7fad7b650728336fdbfac7cd94f4dd4b7cc77789570bf54def38feb0 SHA512 3b0ff6fec5dc857e49386adec9cf4ed962fc1bc95c23cca3852bbb4a63a4a3ae737511964adbccbbc52c409749dbdc71969231d4003ed284f12d655046f4ecdd

diff --git a/gnome-extra/evolution-ews/evolution-ews-3.36.4.ebuild b/gnome-extra/evolution-ews/evolution-ews-3.36.4.ebuild
new file mode 100644
index 00000000000..b3b87637eb3
--- /dev/null
+++ b/gnome-extra/evolution-ews/evolution-ews-3.36.4.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils gnome2
+
+DESCRIPTION="Evolution module for connecting to Microsoft Exchange Web Services"
+HOMEPAGE="https://wiki.gnome.org/Apps/Evolution"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+# libical-glib currently (2020-02-29) oddly behind USE=introspection
+RDEPEND="
+	dev-db/sqlite:3
+	>=dev-libs/glib-2.46:2
+	>=dev-libs/libical-3.0.5:0=[introspection(-)]
+	>=dev-libs/libmspack-0.4
+	dev-libs/libxml2:2
+	>=gnome-extra/evolution-data-server-${PV}:0=
+	>=mail-client/evolution-${PV}:2.0
+	>=net-libs/libsoup-2.58:2.4
+	>=x11-libs/gtk+-3.10:3
+"
+DEPEND="${RDEPEND}
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=dev-util/intltool-0.35.5
+	>=sys-devel/gettext-0.18.3
+	virtual/pkgconfig
+	test? ( net-libs/uhttpmock )
+"
+
+# Unittests fail to find libevolution-ews.so
+RESTRICT="test !test? ( test )"
+
+# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare
+# call; if needed, set them after cmake-utils_src_prepare call, if that works
+src_prepare() {
+	cmake-utils_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_MSPACK=ON
+		-DENABLE_TESTS=$(usex test)
+	)
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+}
+
+src_test() {
+	cmake-utils_src_test
+}
+
+src_install() {
+	cmake-utils_src_install
+}