[gentoo-commits] repo/gentoo:master commit in: x11-terms/st/

["Jeroen Roovers" <jer@gentoo.org>]

commit:     d6bd49399f6378cfdd9c7f21b095d64eae85b11a
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Fri Jun 19 10:32:55 2020 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Fri Jun 19 10:33:04 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d6bd4939

x11-terms/st: Version 0.8.4

Package-Manager: Portage-2.3.101, Repoman-2.3.22
Signed-off-by: Jeroen Roovers <jer <AT> gentoo.org>

 x11-terms/st/Manifest        |  1 +
 x11-terms/st/st-0.8.4.ebuild | 68 ++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/x11-terms/st/Manifest b/x11-terms/st/Manifest
index 2d6b21e3c30..9c31eea1bba 100644
--- a/x11-terms/st/Manifest
+++ b/x11-terms/st/Manifest
@@ -1,2 +1,3 @@
 DIST st-0.8.2.tar.gz 44788 BLAKE2B cc7fc9040c6db1c903d0f7290e5cfd1c636b2d17b42645956583cc8fa883bc1f0631ffbd683e735a834ff96f90171d9d423801d84ce4c0686564498baa97bbc6 SHA512 eaaf5f2fe050ee768d16a9c8c295ba13315775b3a8a3201e020237a3dd217bfb811832d58477249000596289a6cb3287fbb39d6327fc90986af1c363e4b5bf8d
 DIST st-0.8.3.tar.gz 46292 BLAKE2B e84986dedd9aa8ff8e0b1c702cf5601c16cbed67f69623f41bc4908adb06fa29783b21de22576a50ccaa3cb49f515f284b1c4e72b6c5d9fd9b8efb05434b31c1 SHA512 2a824e43d9b3085d9c5c772e3411d744509be79301937c946b27f25451f68813f46c863dd37babbf67716506e86bc70d03645b39d7b124390b07f8f3e0c0c573
+DIST st-0.8.4.tar.gz 47330 BLAKE2B 709278a669414d7d44beba02ebb606853dbaa9cfe71650e40a11d3691d6bee2c0b2e8db57ca2df52776ca564a20f64f3ef7acec8dbad6d66408d314fe26fb794 SHA512 f6f95081f9d09d442228bac1149d75d36a9f4f049b5504cf5ce00b353563ff92c62a2628ce728663fec107a14bea0eeb22b7a72804c37090de33819243d7512a

diff --git a/x11-terms/st/st-0.8.4.ebuild b/x11-terms/st/st-0.8.4.ebuild
new file mode 100644
index 00000000000..c377bfcdc27
--- /dev/null
+++ b/x11-terms/st/st-0.8.4.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit desktop multilib savedconfig toolchain-funcs
+
+DESCRIPTION="simple terminal implementation for X"
+HOMEPAGE="https://st.suckless.org/"
+SRC_URI="https://dl.suckless.org/st/${P}.tar.gz"
+
+LICENSE="MIT-with-advertising"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc64 ~x86"
+IUSE="savedconfig"
+
+RDEPEND="
+	>=sys-libs/ncurses-6.0:0=
+	media-libs/fontconfig
+	x11-libs/libX11
+	x11-libs/libXft
+"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+	x11-base/xorg-proto
+"
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "/^X11LIB/{s:/usr/X11R6/lib:/usr/$(get_libdir)/X11:}" \
+		-e '/^STLDFLAGS/s|= .*|= $(LDFLAGS) $(LIBS)|g' \
+		-e '/^X11INC/{s:/usr/X11R6/include:/usr/include/X11:}' \
+		config.mk || die
+	sed -i \
+		-e '/tic/d' \
+		Makefile || die
+
+	restore_config config.h
+}
+
+src_configure() {
+	sed -i \
+		-e "s|pkg-config|$(tc-getPKG_CONFIG)|g" \
+		config.mk || die
+
+	tc-export CC
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}"/usr install
+
+	dodoc TODO
+
+	make_desktop_entry ${PN} simpleterm utilities-terminal 'System;TerminalEmulator;' ''
+
+	save_config config.h
+}
+
+pkg_postinst() {
+	if ! [[ "${REPLACING_VERSIONS}" ]]; then
+		elog "Please ensure a usable font is installed, like"
+		elog "    media-fonts/corefonts"
+		elog "    media-fonts/dejavu"
+		elog "    media-fonts/urw-fonts"
+	fi
+}