[gentoo-commits] repo/gentoo:master commit in: games-action/moon-buggy/

[gentoo-commits] repo/gentoo:master commit in: games-action/moon-buggy/

[Austin English]

commit:     be888ef802411c0db150f2fdf7116989668cd691
Author:     Austin English <wizardedit <AT> gentoo <DOT> org>
AuthorDate: Tue Jul 12 22:39:58 2016 +0000
Commit:     Austin English <wizardedit <AT> gentoo <DOT> org>
CommitDate: Tue Jul 12 22:40:12 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=be888ef8

games-action/moon-buggy: remove deprecated games eclass

Also update to EAPI 6

Gentoo-Bug: https://bugs.gentoo.org/574082

Package-Manager: portage-2.3.0

 .../moon-buggy/moon-buggy-1.0.51-r1.ebuild         | 46 ++++++++++++++++++++++
 1 file changed, 46 insertions(+)

diff --git a/games-action/moon-buggy/moon-buggy-1.0.51-r1.ebuild b/games-action/moon-buggy/moon-buggy-1.0.51-r1.ebuild
new file mode 100644
index 0000000..e46b34d
--- /dev/null
+++ b/games-action/moon-buggy/moon-buggy-1.0.51-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit autotools eutils user
+
+DESCRIPTION="A simple console game, where you drive a car across the moon's surface"
+HOMEPAGE="http://www.seehuhn.de/comp/moon-buggy.html"
+SRC_URI="http://www.seehuhn.de/data/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86"
+IUSE=""
+
+RDEPEND="sys-libs/ncurses:0"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+pkg_setup(){
+	enewgroup gamestat 36
+}
+
+src_prepare() {
+	default
+	sed -i \
+		-e '/$(DESTDIR)$(bindir)\/moon-buggy -c/d' \
+		Makefile.am || die
+	rm -f missing
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--sharedstatedir="/var/games" \
+		--with-curses-libs="$(pkg-config ncurses --libs)"
+}
+
+src_install() {
+	default
+	touch "${D}/var/games/${PN}/mbscore"
+	fowners root:gamestat /usr/bin/${PN} /var/games/${PN} /var/games/${PN}/mbscore
+	fperms 2755 /usr/bin/${PN}
+	fperms 664 /var/games/${PN}/mbscore
+}

[gentoo-commits] repo/gentoo:master commit in: games-action/moon-buggy/

[James Le Cuirot]

commit:     50a7b58ac837c97364310075c5cbac2df45a090b
Author:     Ulrich Müller <ulm <AT> gentoo <DOT> org>
AuthorDate: Mon Jul  8 08:35:09 2019 +0000
Commit:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
CommitDate: Wed Jul 17 20:03:38 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=50a7b58a

games-action/moon-buggy: Depend on acct-group/gamestat.

Package-Manager: Portage-2.3.68, Repoman-2.3.16
Signed-off-by: Ulrich Müller <ulm <AT> gentoo.org>
Signed-off-by: James Le Cuirot <chewi <AT> gentoo.org>

 games-action/moon-buggy/moon-buggy-1.0.51-r1.ebuild | 11 ++++-------
 1 file changed, 4 insertions(+), 7 deletions(-)

diff --git a/games-action/moon-buggy/moon-buggy-1.0.51-r1.ebuild b/games-action/moon-buggy/moon-buggy-1.0.51-r1.ebuild
index 22373707aea..f3fd219803f 100644
--- a/games-action/moon-buggy/moon-buggy-1.0.51-r1.ebuild
+++ b/games-action/moon-buggy/moon-buggy-1.0.51-r1.ebuild
@@ -1,8 +1,8 @@
-# Copyright 1999-2016 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
-inherit autotools eutils user
+inherit autotools eutils
 
 DESCRIPTION="A simple console game, where you drive a car across the moon's surface"
 HOMEPAGE="http://www.seehuhn.de/comp/moon-buggy.html"
@@ -13,14 +13,11 @@ SLOT="0"
 KEYWORDS="~amd64 ~arm ~x86"
 IUSE=""
 
-RDEPEND="sys-libs/ncurses:0"
+RDEPEND="acct-group/gamestat
+	sys-libs/ncurses:0"
 DEPEND="${RDEPEND}
 	virtual/pkgconfig"
 
-pkg_setup(){
-	enewgroup gamestat 36
-}
-
 src_prepare() {
 	default
 	sed -i \

[gentoo-commits] repo/gentoo:master commit in: games-action/moon-buggy/

[Aaron Bauman]

commit:     07fa7024f5ac4251da1606b15f0527b01954479c
Author:     Michael Mair-Keimberger <m.mairkeimberger <AT> gmail <DOT> com>
AuthorDate: Mon Jun 15 13:09:51 2020 +0000
Commit:     Aaron Bauman <bman <AT> gentoo <DOT> org>
CommitDate: Mon Jun 15 16:38:49 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=07fa7024

games-action/moon-buggy: use HTTPS

Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Michael Mair-Keimberger <m.mairkeimberger <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/16256
Signed-off-by: Aaron Bauman <bman <AT> gentoo.org>

 games-action/moon-buggy/moon-buggy-1.0.51-r1.ebuild | 6 +++---
 1 file changed, 3 insertions(+), 3 deletions(-)

diff --git a/games-action/moon-buggy/moon-buggy-1.0.51-r1.ebuild b/games-action/moon-buggy/moon-buggy-1.0.51-r1.ebuild
index f3fd219803f..828120c3cab 100644
--- a/games-action/moon-buggy/moon-buggy-1.0.51-r1.ebuild
+++ b/games-action/moon-buggy/moon-buggy-1.0.51-r1.ebuild
@@ -1,12 +1,12 @@
-# Copyright 1999-2019 Gentoo Authors
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
 inherit autotools eutils
 
 DESCRIPTION="A simple console game, where you drive a car across the moon's surface"
-HOMEPAGE="http://www.seehuhn.de/comp/moon-buggy.html"
-SRC_URI="http://www.seehuhn.de/data/${P}.tar.gz"
+HOMEPAGE="https://www.seehuhn.de/pages/moon-buggy.html"
+SRC_URI="https://m.seehuhn.de/programs/${P}.tar.gz"
 
 LICENSE="GPL-2"
 SLOT="0"

[gentoo-commits] repo/gentoo:master commit in: games-action/moon-buggy/

[Ionen Wolkens]

commit:     6723f7ac4d1431c7cebc595fbac079ea54857fe3
Author:     Michael Mair-Keimberger <mmk <AT> levelnine <DOT> at>
AuthorDate: Mon Jun 21 16:11:11 2021 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Thu Jun 24 00:48:19 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6723f7ac

games-action/moon-buggy: EAPI7, add missing eclass, fix LICENSE

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Michael Mair-Keimberger <mmk <AT> levelnine.at>
Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 games-action/moon-buggy/moon-buggy-1.0.51-r2.ebuild | 21 +++++++++++----------
 1 file changed, 11 insertions(+), 10 deletions(-)

diff --git a/games-action/moon-buggy/moon-buggy-1.0.51-r2.ebuild b/games-action/moon-buggy/moon-buggy-1.0.51-r2.ebuild
index 0347e5bfa29..9430a6baa4a 100644
--- a/games-action/moon-buggy/moon-buggy-1.0.51-r2.ebuild
+++ b/games-action/moon-buggy/moon-buggy-1.0.51-r2.ebuild
@@ -1,41 +1,42 @@
 # Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
-inherit autotools
+EAPI=7
 
-DESCRIPTION="A simple console game, where you drive a car across the moon's surface"
+inherit autotools toolchain-funcs
+
+DESCRIPTION="Simple console game, where you drive a car across the moon's surface"
 HOMEPAGE="https://www.seehuhn.de/pages/moon-buggy.html"
 SRC_URI="https://m.seehuhn.de/programs/${P}.tar.gz"
 
-LICENSE="GPL-2"
+LICENSE="GPL-2+"
 SLOT="0"
 KEYWORDS="~amd64 ~arm ~x86"
-IUSE=""
 
 RDEPEND="acct-group/gamestat
 	sys-libs/ncurses:0="
-DEPEND="${RDEPEND}
-	virtual/pkgconfig"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
 
 src_prepare() {
 	default
 	sed -i \
 		-e '/$(DESTDIR)$(bindir)\/moon-buggy -c/d' \
 		Makefile.am || die
-	rm -f missing
+	rm missing || die
 	eautoreconf
 }
 
 src_configure() {
 	econf \
-		--sharedstatedir="/var/games" \
+		--sharedstatedir="${EPREFIX}/var/games" \
 		--with-curses-libs="$($(tc-getPKG_CONFIG) ncurses --libs)"
 }
 
 src_install() {
 	default
-	touch "${D}/var/games/${PN}/mbscore"
+
+	touch "${ED}/var/games/${PN}/mbscore" || die
 	fowners root:gamestat /usr/bin/${PN} /var/games/${PN} /var/games/${PN}/mbscore
 	fperms 2755 /usr/bin/${PN}
 	fperms 664 /var/games/${PN}/mbscore

[gentoo-commits] repo/gentoo:master commit in: games-action/moon-buggy/

[Sam James]

commit:     48a5756b827ea777e5ee15c6c3cc2bc09bdd7ebb
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun Jul 17 15:30:23 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Jul 17 15:30:23 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=48a5756b

games-action/moon-buggy: filter LTO (type mismatch)

Closes: https://bugs.gentoo.org/858518
Signed-off-by: Sam James <sam <AT> gentoo.org>

 games-action/moon-buggy/moon-buggy-1.0.51-r2.ebuild | 7 +++++--
 1 file changed, 5 insertions(+), 2 deletions(-)

diff --git a/games-action/moon-buggy/moon-buggy-1.0.51-r2.ebuild b/games-action/moon-buggy/moon-buggy-1.0.51-r2.ebuild
index 9430a6baa4a0..f6dbd7d4292c 100644
--- a/games-action/moon-buggy/moon-buggy-1.0.51-r2.ebuild
+++ b/games-action/moon-buggy/moon-buggy-1.0.51-r2.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
 
-inherit autotools toolchain-funcs
+inherit autotools flag-o-matic toolchain-funcs
 
 DESCRIPTION="Simple console game, where you drive a car across the moon's surface"
 HOMEPAGE="https://www.seehuhn.de/pages/moon-buggy.html"
@@ -28,6 +28,9 @@ src_prepare() {
 }
 
 src_configure() {
+	# LTO warnings, bug #858518
+	filter-lto
+
 	econf \
 		--sharedstatedir="${EPREFIX}/var/games" \
 		--with-curses-libs="$($(tc-getPKG_CONFIG) ncurses --libs)"