[gentoo-commits] repo/gentoo:master commit in: net-im/telegram-desktop/

["Georgy Yakovlev" <gyakovlev@gentoo.org>]

commit:     e00fefd0af765627ba482b00966b42ee60055f87
Author:     Georgy Yakovlev <gyakovlev <AT> gentoo <DOT> org>
AuthorDate: Sun Jun 14 19:52:56 2020 +0000
Commit:     Georgy Yakovlev <gyakovlev <AT> gentoo <DOT> org>
CommitDate: Sun Jun 14 20:30:00 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e00fefd0

net-im/telegram-desktop: drop old

Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Georgy Yakovlev <gyakovlev <AT> gentoo.org>

 net-im/telegram-desktop/Manifest                   |   1 -
 .../telegram-desktop/telegram-desktop-2.1.7.ebuild | 149 ---------------------
 2 files changed, 150 deletions(-)

diff --git a/net-im/telegram-desktop/Manifest b/net-im/telegram-desktop/Manifest
index 153db049cf4..1d8382f5c07 100644
--- a/net-im/telegram-desktop/Manifest
+++ b/net-im/telegram-desktop/Manifest
@@ -1,3 +1,2 @@
 DIST tdesktop-2.1.0-full.tar.gz 26133964 BLAKE2B c5eb476ea3ed02c2618e5b770bdce365bcf0d6124f75558570189e07e9dcd9f6f3282d53fec621be736cbd1269a9dd820629d4d9a36167d8f71109bfcd5a52e2 SHA512 46f5453c64d1dbd4cf8adde73fcc48e6b6f795972ab0f6516cb55112f47d5af990a049da356bedb81e6d3f7103c14a7be45369ff9a5a1812c07a1bfcda70646d
 DIST tdesktop-2.1.11-full.tar.gz 36548657 BLAKE2B 969ee0b680cb225c86bbab25e792b9fa21182227d73f062700ac56f08de83b249cca41d661c711e1a7dbcbeeeda70ddb13535403bee6f001ea10c4864b995c67 SHA512 9f2fba2814a5ab64f946913e32fce66dbc842d9607cbaee00994689ef6a661a04c2a8de5e075fc532e7d8926b51432c06c2b1510b019d729eef40da373d91d42
-DIST tdesktop-2.1.7-full.tar.gz 36509059 BLAKE2B 4a1bf5879e71e64f34024165f9db39f69d1d8e87b0387704bdb74415d60d6a1efd22ab1fec994116a72a6982a55f13cee0edb667060bbe9336cba4ce12e7472c SHA512 f942ce93d9671f3bb95a8fbba107fc851bfe3f28871c9651f6f2d97d711602f8a671f7b74750894b2175d33a67c25017562cd4ee455da7aa9b86755d1c3f1cfb

diff --git a/net-im/telegram-desktop/telegram-desktop-2.1.7.ebuild b/net-im/telegram-desktop/telegram-desktop-2.1.7.ebuild
deleted file mode 100644
index e031bf3e1e7..00000000000
--- a/net-im/telegram-desktop/telegram-desktop-2.1.7.ebuild
+++ /dev/null
@@ -1,149 +0,0 @@
-# Copyright 2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{6,7,8} )
-
-inherit cmake desktop flag-o-matic python-any-r1 xdg-utils
-
-MY_P="tdesktop-${PV}-full"
-
-DESCRIPTION="Official desktop client for Telegram"
-HOMEPAGE="https://desktop.telegram.org"
-SRC_URI="https://github.com/telegramdesktop/tdesktop/releases/download/v${PV}/${MY_P}.tar.gz"
-
-LICENSE="GPL-3-with-openssl-exception"
-SLOT="0"
-KEYWORDS="~amd64 ~ppc64"
-IUSE="+alsa +dbus enchant +hunspell libressl pulseaudio +spell wayland +X"
-
-RDEPEND="
-	!net-im/telegram-desktop-bin
-	app-arch/lz4:=
-	app-arch/xz-utils
-	!libressl? ( dev-libs/openssl:0= )
-	libressl? ( dev-libs/libressl:0= )
-	dev-cpp/range-v3
-	dev-libs/xxhash
-	dev-qt/qtcore:5
-	dev-qt/qtgui:5[jpeg,png,wayland?,X(-)?]
-	dev-qt/qtimageformats:5
-	dev-qt/qtnetwork:5
-	dev-qt/qtsvg:5
-	dev-qt/qtwidgets:5[png,X(-)?]
-	media-fonts/open-sans
-	media-libs/fontconfig:=
-	>=media-libs/libtgvoip-2.4.4_p20200430[alsa?,pulseaudio?]
-	media-libs/openal[alsa?,pulseaudio?]
-	media-libs/opus:=
-	media-video/ffmpeg:=[alsa?,opus,pulseaudio?]
-	sys-libs/zlib[minizip]
-	virtual/libiconv
-	dbus? (
-		dev-qt/qtdbus:5
-		dev-libs/libdbusmenu-qt[qt5(+)]
-	)
-	enchant? ( app-text/enchant:= )
-	hunspell? ( >=app-text/hunspell-1.7:= )
-	pulseaudio? ( media-sound/pulseaudio )
-"
-
-DEPEND="
-	${PYTHON_DEPS}
-	${RDEPEND}
-"
-
-BDEPEND="
-	>=dev-util/cmake-3.16
-	virtual/pkgconfig
-"
-
-REQUIRED_USE="
-	|| ( alsa pulseaudio )
-	|| ( X wayland )
-	spell? (
-		^^ ( enchant hunspell )
-	)
-"
-
-S="${WORKDIR}/${MY_P}"
-
-PATCHES=(
-	"${FILESDIR}/${PN}-qt5.15.patch"
-)
-
-pkg_pretend() {
-	if has ccache ${FEATURES}; then
-		ewarn
-		ewarn "ccache does not work with ${PN} out of the box"
-		ewarn "due to usage of precompiled headers"
-		ewarn "check bug https://bugs.gentoo.org/715114 for more info"
-		ewarn
-	fi
-}
-
-src_configure() {
-	local mycxxflags=(
-		-Wno-deprecated-declarations
-		-Wno-error=deprecated-declarations
-		-Wno-switch
-	)
-
-	append-cxxflags "${mycxxflags[@]}"
-
-	# TODO: unbundle header-only libs, ofc telegram uses git versions...
-	# it fals with tl-expected-1.0.0, so we use bundled for now to avoid git rev snapshots
-	# EXPECTED VARIANT
-	# TODO: unbundle GSL, version 3.0.1 required and has nasty googletest dep
-	local mycmakeargs=(
-		-DDESKTOP_APP_DISABLE_CRASH_REPORTS=ON
-		-DDESKTOP_APP_USE_GLIBC_WRAPS=OFF
-		-DDESKTOP_APP_USE_PACKAGED=ON
-		-DDESKTOP_APP_USE_PACKAGED_EXPECTED=OFF
-		-DDESKTOP_APP_USE_PACKAGED_GSL=OFF
-		-DDESKTOP_APP_USE_PACKAGED_RLOTTIE=OFF
-		-DDESKTOP_APP_USE_PACKAGED_VARIANT=OFF
-		-DTDESKTOP_LAUNCHER_BASENAME="${PN}"
-		-DDESKTOP_APP_DISABLE_DBUS_INTEGRATION="$(usex dbus OFF ON)"
-		-DDESKTOP_APP_DISABLE_SPELLCHECK="$(usex spell OFF ON)" # enables hunspell (recommended)
-		-DDESKTOP_APP_USE_ENCHANT="$(usex enchant ON OFF)" # enables enchant and disables hunspell
-	)
-
-	if [[ -n ${MY_TDESKTOP_API_ID} && -n ${MY_TDESKTOP_API_HASH} ]]; then
-		einfo "Found custom API credentials"
-		mycmakeargs+=(
-			-DTDESKTOP_API_ID="${MY_TDESKTOP_API_ID}"
-			-DTDESKTOP_API_HASH="${MY_TDESKTOP_API_HASH}"
-		)
-	else
-		# https://github.com/telegramdesktop/tdesktop/blob/dev/snap/snapcraft.yaml
-		# Building with snapcraft API credentials by default
-		# Custom API credentials can be obtained here:
-		# https://github.com/telegramdesktop/tdesktop/blob/dev/docs/api_credentials.md
-		# After getting credentials you can export variables:
-		#  export MY_TDESKTOP_API_ID="17349""
-		#  export MY_TDESKTOP_API_HASH="344583e45741c457fe1862106095a5eb"
-		# and restart the build"
-		# you can set above variables (without export) in /etc/portage/env/net-im/telegram-desktop
-		# portage will use custom variable every build automatically
-		mycmakeargs+=(
-			-DTDESKTOP_API_ID="611335"
-			-DTDESKTOP_API_HASH="d524b414d21f4d37f08684c1df41ac9c"
-		)
-	fi
-
-	cmake_src_configure
-}
-
-pkg_postinst() {
-	xdg_desktop_database_update
-	xdg_icon_cache_update
-	xdg_mimeinfo_database_update
-}
-
-pkg_postrm() {
-	xdg_desktop_database_update
-	xdg_icon_cache_update
-	xdg_mimeinfo_database_update
-}