[gentoo-commits] repo/gentoo:master commit in: dev-python/reflink/

["Georgy Yakovlev" <gyakovlev@gentoo.org>]

commit:     58a4bc81eb11c5a6c4a92cfeb97a561a38e94b71
Author:     Georgy Yakovlev <gyakovlev <AT> gentoo <DOT> org>
AuthorDate: Tue Jun  9 03:16:44 2020 +0000
Commit:     Georgy Yakovlev <gyakovlev <AT> gentoo <DOT> org>
CommitDate: Tue Jun  9 03:20:15 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=58a4bc81

dev-python/reflink: add py3.{7,8}, improve ebuild

Closes: https://bugs.gentoo.org/719530
Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Georgy Yakovlev <gyakovlev <AT> gentoo.org>

 dev-python/reflink/reflink-0.2.1-r1.ebuild | 47 ++++++++++++++++++++++++++++++
 dev-python/reflink/reflink-0.2.1.ebuild    | 46 -----------------------------
 2 files changed, 47 insertions(+), 46 deletions(-)

diff --git a/dev-python/reflink/reflink-0.2.1-r1.ebuild b/dev-python/reflink/reflink-0.2.1-r1.ebuild
new file mode 100644
index 00000000000..ab5936518e0
--- /dev/null
+++ b/dev-python/reflink/reflink-0.2.1-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 2019-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+DISTUTILS_IN_SOURCE_BUILD=1
+
+inherit distutils-r1
+
+DESCRIPTION="Python wrapper around the reflink system calls"
+HOMEPAGE="https://gitlab.com/rubdos/pyreflink"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64"
+
+RDEPEND="virtual/python-cffi[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}"
+BDEPEND="${RDEPEND}
+	test? ( sys-fs/btrfs-progs )
+"
+
+distutils_enable_sphinx docs
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	sed -e 's|'\''pytest-runner'\'',\?||' -i setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local notestmsg="Tests need FEATURES='-usersandbox -userpriv -sandbox'"
+	if [[ ${EUID} != 0 ]]; then
+		ewarn "${notestmsg}"
+	elif
+		has sandbox ${FEATURES}; then
+			ewarn "${notestmsg}"
+	else
+		pushd "${BUILD_DIR}"/lib >/dev/null || die
+		# module import will fail with any other directory structure
+		cp -rv "${S}"/tests ./ || die
+		pytest -vv || die "Tests fail with ${EPYTHON}"
+		popd >/dev/null || die
+	fi
+}

diff --git a/dev-python/reflink/reflink-0.2.1.ebuild b/dev-python/reflink/reflink-0.2.1.ebuild
deleted file mode 100644
index c3df5d3b75b..00000000000
--- a/dev-python/reflink/reflink-0.2.1.ebuild
+++ /dev/null
@@ -1,46 +0,0 @@
-# Copyright 2019-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_6 )
-
-inherit distutils-r1
-
-DESCRIPTION="Python wrapper around the reflink system calls"
-HOMEPAGE="https://gitlab.com/rubdos/pyreflink"
-SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64"
-IUSE="doc test"
-
-BDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
-	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
-	test? (
-		dev-python/pytest[${PYTHON_USEDEP}]
-		dev-python/pytest-runner[${PYTHON_USEDEP}]
-		sys-fs/btrfs-progs
-	)
-"
-RDEPEND="virtual/python-cffi[${PYTHON_USEDEP}]"
-DEPEND="${RDEPEND}"
-
-# goes places, like writing to /dev or creating btrfs volumes
-RESTRICT="test"
-
-PATCHES=( "${FILESDIR}/${PV}-correct-test-deps.patch" )
-
-python_compile_all() {
-	use doc && emake -C docs html
-}
-
-python_install_all() {
-	use doc && local HTML_DOCS=( docs/_build/html/. )
-	distutils-r1_python_install_all
-}
-
-python_test() {
-	esetup.py test
-}