[gentoo-commits] repo/gentoo:master commit in: sci-libs/xdmf2/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     d7a85e1f78219f0d5b2603f422d6e33297aaf68c
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Thu Jun  4 22:58:16 2020 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri Jun  5 00:39:24 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d7a85e1f

sci-libs/xdmf2: Drop eternally broken IUSE=python, EAPI-7 bump

- Switch to cmake.eclass
- Drop ~arm keyword (no revdeps)
- Drop obsolete c++14 flag

Closes: https://bugs.gentoo.org/664920
Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 sci-libs/xdmf2/xdmf2-1.0_p141226-r4.ebuild | 57 ++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

diff --git a/sci-libs/xdmf2/xdmf2-1.0_p141226-r4.ebuild b/sci-libs/xdmf2/xdmf2-1.0_p141226-r4.ebuild
new file mode 100644
index 00000000000..e196d6f8dd2
--- /dev/null
+++ b/sci-libs/xdmf2/xdmf2-1.0_p141226-r4.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="eXtensible Data Model and Format"
+HOMEPAGE="http://xdmf.org/index.php/Main_Page"
+SRC_URI="https://dev.gentoo.org/~jlec/distfiles/${P}.tar.xz"
+
+LICENSE="VTK"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	doc? ( app-doc/doxygen )
+"
+RDEPEND="
+	dev-libs/boost:=
+	dev-libs/libxml2:2
+	sci-libs/hdf5:=
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-module.patch
+	"${FILESDIR}"/${P}-cannot-find-hdf5-bug-591302.patch
+	"${FILESDIR}"/${P}-cmake-3.12.patch
+)
+
+src_prepare() {
+	sed \
+		-e "/DESTINATION/s:lib:$(get_libdir):g" \
+		-e "/INSTALL/s:lib:$(get_libdir):g" \
+		-i CMakeLists.txt core/CMakeLists.txt || die
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_SHARED_LIBS=1
+		-DXDMF_BUILD_DOCUMENTATION=$(usex doc)
+		-DBUILD_TESTING=$(usex test)
+		-DXDMF_WRAP_PYTHON=OFF
+		-DXDMF_WRAP_JAVA=OFF
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	dosym XdmfConfig.cmake /usr/share/cmake/Modules/${PN}Config.cmake
+}