[gentoo-commits] repo/gentoo:master commit in: dev-db/qt5-sqlcipher/

["Ulrich Müller" <ulm@gentoo.org>]

commit:     ff40993604b8bd131591d15da2c33abae38fefa7
Author:     Ulrich Müller <ulm <AT> gentoo <DOT> org>
AuthorDate: Sun May 31 09:55:49 2020 +0000
Commit:     Ulrich Müller <ulm <AT> gentoo <DOT> org>
CommitDate: Sun May 31 10:00:16 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ff409936

dev-db/qt5-sqlcipher: Version bump to 1.0.11.

Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Ulrich Müller <ulm <AT> gentoo.org>

 dev-db/qt5-sqlcipher/Manifest                    |  1 +
 dev-db/qt5-sqlcipher/qt5-sqlcipher-1.0.11.ebuild | 49 ++++++++++++++++++++++++
 2 files changed, 50 insertions(+)

diff --git a/dev-db/qt5-sqlcipher/Manifest b/dev-db/qt5-sqlcipher/Manifest
index 55ef4fe798a..b486b924395 100644
--- a/dev-db/qt5-sqlcipher/Manifest
+++ b/dev-db/qt5-sqlcipher/Manifest
@@ -1,2 +1,3 @@
 DIST qt5-sqlcipher-1.0.10-qt-5.15.0.tar.xz 8240 BLAKE2B 93541d04b1ce25e01438e7d9282645b4e9ae613390160e7a76ee106d9b4dcb42cd8b979918952ef151beac17e0bc3a1e52b03607c30c1005ce3d03875532830b SHA512 db506bf37373822c784aee533318a5899bdf46f5d89548b5ff8a6017e5e6f1ba7e5a4b856a28623e464ba34182382b8ada95b4f73dd47ba8e5b651dc6a747e35
 DIST qt5-sqlcipher-1.0.10.tar.gz 245054 BLAKE2B edb36a47881e2d5801cf07cc9b6094ea53b9e0e595c0078d3a09b493979222a6ad655b074b015c0a152073e0f39d1e31ecb9e2021f7788dda04a0547cd47eddd SHA512 1a23da7d7c6de020ee0739154abe83f94208a3a6d385fd58eff38d3ea27ce51b37a66994e8ad0ff5102525c3573134f9b9362accf2032b7386ea174b12ea1338
+DIST qt5-sqlcipher-1.0.11.tar.gz 267993 BLAKE2B e938f7de368af90cb3304eeb79afcc86354bcecd55e57b7fb73c979e5e40dbf1b0936db37c16b8e9cc3ca4646aac5cd773917eff14735f2eaf91ac67d9432d66 SHA512 6ed4bd6fa7155438266cae2ecaeaea648e9b55df23f7fb811daa7d90fda0ab36e489c28b3739a4cc1103fc5f550e16f9a58f9df4e001e72ac10937bc2115bad9

diff --git a/dev-db/qt5-sqlcipher/qt5-sqlcipher-1.0.11.ebuild b/dev-db/qt5-sqlcipher/qt5-sqlcipher-1.0.11.ebuild
new file mode 100644
index 00000000000..2c4d7596f41
--- /dev/null
+++ b/dev-db/qt5-sqlcipher/qt5-sqlcipher-1.0.11.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils
+
+DESCRIPTION="Qt SQL driver plugin for SQLCipher"
+HOMEPAGE="https://github.com/blizzard4591/qt5-sqlcipher"
+SRC_URI="https://github.com/blizzard4591/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1" # version 2.1 only
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND=">=dev-db/sqlcipher-3.4.1
+	>=dev-qt/qtcore-5.12.3:5=
+	>=dev-qt/qtsql-5.12.3:5=[sqlite] <dev-qt/qtsql-5.16:5=[sqlite]"
+DEPEND="${RDEPEND}"
+
+DOCS=(README.md)
+
+src_prepare() {
+	eapply "${FILESDIR}"/${PN}-1.0.10-install-path.patch
+	sed -i -e "s/@LIBDIR@/$(get_libdir)/" CMakeLists.txt || die
+
+	local v=$(best_version dev-qt/qtsql:5)
+	v=$(ver_cut 1-3 ${v#*/qtsql-})
+	[[ -n ${v} ]] || die "could not determine qtsql version"
+	if ! [[ -d qt-file-cache/${v} ]]; then
+		local vc
+		case $(ver_cut 1-2 ${v}) in
+			5.12) vc=5.12.5 ;;
+			5.13) vc=5.13.2 ;;
+			5.14) vc=5.14.2 ;;
+			5.15) vc=5.15.0 ;;
+			*) die "qtsql-${v} not supported" ;;
+		esac
+		elog "qtsql-${v} not in cache, using ${vc} instead"
+		cp -R qt-file-cache/${vc} qt-file-cache/${v} || die
+	fi
+
+	cmake-utils_src_prepare
+}
+
+src_test() {
+	cd "${BUILD_DIR}" || die
+	./qsqlcipher-test || die
+}