[gentoo-commits] repo/gentoo:master commit in: sys-apps/s390-tools/

["Mike Frysinger" <vapier@gentoo.org>]

commit:     8dc7803dbae4e5c2adc80ed543cd5d5f95b45347
Author:     Mike Frysinger <vapier <AT> gentoo <DOT> org>
AuthorDate: Sun May 31 09:39:36 2020 +0000
Commit:     Mike Frysinger <vapier <AT> gentoo <DOT> org>
CommitDate: Sun May 31 09:46:21 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8dc7803d

sys-apps/s390-tools: version bump to 2.12.0

We need a newer version to build with current toolchain versions.
We don't go up to 2.13.0 as the new genprotimg has build issues.

Signed-off-by: Mike Frysinger <vapier <AT> gentoo.org>

 sys-apps/s390-tools/Manifest                 |  1 +
 sys-apps/s390-tools/s390-tools-2.12.0.ebuild | 66 ++++++++++++++++++++++++++++
 2 files changed, 67 insertions(+)

diff --git a/sys-apps/s390-tools/Manifest b/sys-apps/s390-tools/Manifest
index 6dbc72e437a..eeafe301b10 100644
--- a/sys-apps/s390-tools/Manifest
+++ b/sys-apps/s390-tools/Manifest
@@ -1 +1,2 @@
+DIST s390-tools-2.12.0.tar.gz 1186816 BLAKE2B bdf7975d236ec939539221ba548d67582836ae1ef8fab29ff19ac32596ba60686d41db47412bfe7a86d74a1728e3ee41356403ba21557cec4400a2aae98165df SHA512 4903ded5368966513e1090faca04482316870cf5fc53206d17ab98b821541e2836a016bd18cd1ca49ed6b5df0dff92dd1ed257ff712920a7aa3fd74e4a6bc6a0
 DIST s390-tools-2.9.0.tar.gz 1162090 BLAKE2B a86b8b1859d125f476a96546163881723cf87536a654871269c23ec6e72266776083f5d49bff3c65c2a01af7de985d2079cc9504a605e3d42de297a464b8ee69 SHA512 23315e8914a5c797b0678298ff51fd95a3c9f065b0fa9f6cf954573fd5ad394890d7f8dbd9cf2501d845c76c3fe31952b25cb7c2b2d59744305b2f37cf3a65bb

diff --git a/sys-apps/s390-tools/s390-tools-2.12.0.ebuild b/sys-apps/s390-tools/s390-tools-2.12.0.ebuild
new file mode 100644
index 00000000000..06c2fdd5d48
--- /dev/null
+++ b/sys-apps/s390-tools/s390-tools-2.12.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit toolchain-funcs udev
+
+DESCRIPTION="User space utilities for the zSeries (s390) Linux kernel and device drivers"
+HOMEPAGE="https://github.com/ibm-s390-tools/s390-tools"
+SRC_URI="https://github.com/ibm-${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="-* s390"
+IUSE="cryptsetup fuse ncurses openssl pfm snmp zlib"
+
+RDEPEND="fuse? ( sys-fs/fuse:0= )
+	ncurses? ( sys-libs/ncurses:0= )
+	openssl? (
+		dev-libs/openssl:0=
+		cryptsetup? (
+			>=sys-fs/cryptsetup-2.0.3:=
+			dev-libs/json-c:=
+		)
+	)
+	pfm? ( app-misc/pfm )
+	snmp? ( net-analyzer/net-snmp )
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}
+	dev-util/indent
+	app-admin/genromfs"
+
+src_prepare() {
+	default
+	sed -i -e 's/-lncurses/-lncurses -ltinfo/' "${S}"/hyptop/Makefile || die
+}
+
+src_configure() {
+	export MAKEOPTS+=" V=1"
+	export HAVE_DRACUT=0
+	export HAVE_FUSE=$(usex fuse 1 0)
+	export HAVE_NCURSES=$(usex ncurses 1 0)
+	export HAVE_SNMP=$(usex snmp 1 0)
+	export HAVE_PFM=$(usex pfm 1 0)
+	export HAVE_ZLIB=$(usex zlib 1 0)
+	export HAVE_OPENSSL=$(usex openssl 1 0)
+	export HAVE_CRYPTSETUP2=$(usex cryptsetup 1 0)
+	export HAVE_JSONC=$(usex cryptsetup 1 0)
+	tc-export AR BUILD_CC CC CXX LD NM OBJCOPY
+}
+
+src_compile() {
+	emake \
+		AR="${AR}" \
+		HOSTCC="${BUILD_CC}" \
+		CC="${CC}" LINK="${CC}" \
+		CXX="${CXX}" LINKXX="${CXX}" \
+		LD="${LD}" \
+		NM="${NM}" \
+		OBJCOPY="${OBJCOPY}"
+}
+
+src_install() {
+	default
+	udev_dorules etc/udev/rules.d/*.rules
+}