[gentoo-commits] repo/gentoo:master commit in: dev-libs/librdkafka/

["Thomas Deutschmann" <whissi@gentoo.org>]

commit:     da7832d7de1438aa7d7a5c5253bcaeea9d2acd17
Author:     Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
AuthorDate: Fri May  8 22:39:48 2020 +0000
Commit:     Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
CommitDate: Fri May  8 22:49:04 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=da7832d7

dev-libs/librdkafka: bump to v1.4.2

Closes: https://bugs.gentoo.org/710324
Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Thomas Deutschmann <whissi <AT> gentoo.org>

 dev-libs/librdkafka/Manifest                |  1 +
 dev-libs/librdkafka/librdkafka-1.4.2.ebuild | 73 +++++++++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/dev-libs/librdkafka/Manifest b/dev-libs/librdkafka/Manifest
index 4e8068c2eb4..a68cb4204ce 100644
--- a/dev-libs/librdkafka/Manifest
+++ b/dev-libs/librdkafka/Manifest
@@ -1 +1,2 @@
 DIST librdkafka-1.4.0.tar.gz 2722992 BLAKE2B 590fa90805bc2dc728dd32be333eaf9b2a4e6a840403838406684794ca68f2bcf9fc831e252a637622f9e6cd209d779ed20d503e49dac20bdb28f5d3fbd676bd SHA512 cd343597707d22490dfcd513a6b24ca5487dca5230a5a6775e7d6f10be2dc5481deb3a76968bb244d5f7514db92aceca541823c5841a7b54d8e00aeb9088731c
+DIST librdkafka-1.4.2.tar.gz 2732806 BLAKE2B 140160fef4f228d877bcfa9d892fd053d2b74547abdbeb7dc661bd4b2b7d576f1ebeecaccd1ac3c3669e059746f0c63be6468cd4f066a9862b8c60d8f2d014a4 SHA512 3d8e496466c103829f5fe11f1a6e68d1299c847b637c6fad55adbe1ad28bd5c463508f3f3fb8b3316b15a104f74e551cd5e520950d76c0e4f8c876083397ced5

diff --git a/dev-libs/librdkafka/librdkafka-1.4.2.ebuild b/dev-libs/librdkafka/librdkafka-1.4.2.ebuild
new file mode 100644
index 00000000000..c6121981cc1
--- /dev/null
+++ b/dev-libs/librdkafka/librdkafka-1.4.2.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit toolchain-funcs
+
+DESCRIPTION="Apache Kafka C/C++ client library"
+HOMEPAGE="https://github.com/edenhill/librdkafka"
+
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/edenhill/${PN}.git"
+
+	inherit git-r3
+else
+	SRC_URI="https://github.com/edenhill/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~sparc ~x86"
+fi
+
+LICENSE="BSD-2"
+
+# subslot = soname version
+SLOT="0/1"
+
+IUSE="lz4 sasl ssl static-libs zstd"
+
+LIB_DEPEND="
+	lz4? ( app-arch/lz4:=[static-libs(+)] )
+	sasl? ( dev-libs/cyrus-sasl:=[static-libs(+)] )
+	ssl? ( dev-libs/openssl:0=[static-libs(+)] )
+	zstd? ( app-arch/zstd:=[static-libs(+)] )
+	sys-libs/zlib:=[static-libs(+)]
+"
+
+RDEPEND="!static-libs? ( ${LIB_DEPEND//\[static-libs(+)]} )"
+
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+	static-libs? ( ${LIB_DEPEND} )
+"
+
+src_configure() {
+	tc-export CC CXX LD NM OBJDUMP PKG_CONFIG STRIP
+
+	local myeconf=(
+		--no-cache
+		--no-download
+		--disable-debug-symbols
+		$(use_enable lz4)
+		$(use_enable sasl)
+		$(usex static-libs '--enable-static' '')
+		$(use_enable ssl)
+		$(use_enable zstd)
+	)
+
+	econf ${myeconf[@]}
+}
+
+src_test() {
+	emake -C tests run_local
+}
+
+src_install() {
+	emake \
+		DESTDIR="${D}" \
+		docdir="/usr/share/doc/${PF}" \
+		install
+
+	if ! use static-libs; then
+		find "${ED}" -type f \( -name "*.a" -o -name "*.la" \) -delete || die
+	fi
+}