From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1169250-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 9214413835A
for <garchives@archives.gentoo.org>; Fri, 8 May 2020 07:22:19 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 80C70E086B;
Fri, 8 May 2020 07:22:18 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 02A3DE086B
for <gentoo-commits@lists.gentoo.org>; Fri, 8 May 2020 07:22:17 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 5F31834F328
for <gentoo-commits@lists.gentoo.org>; Fri, 8 May 2020 07:22:16 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id B4AB222B
for <gentoo-commits@lists.gentoo.org>; Fri, 8 May 2020 07:22:13 +0000 (UTC)
From: "Mart Raudsepp" <leio@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Mart Raudsepp" <leio@gentoo.org>
Message-ID: <1588922519.2a242e4097da27de8ca851552cdeafe94393b79b.leio@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: gnome-extra/evolution-data-server/
X-VCS-Repository: repo/gentoo
X-VCS-Files: gnome-extra/evolution-data-server/Manifest gnome-extra/evolution-data-server/evolution-data-server-3.36.2.ebuild
X-VCS-Directories: gnome-extra/evolution-data-server/
X-VCS-Committer: leio
X-VCS-Committer-Name: Mart Raudsepp
X-VCS-Revision: 2a242e4097da27de8ca851552cdeafe94393b79b
X-VCS-Branch: master
Date: Fri, 8 May 2020 07:22:13 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: ea81ea34-663c-499c-a354-f31961392e22
X-Archives-Hash: aaba63312ac4e81e1d3cca5b929629ee
commit: 2a242e4097da27de8ca851552cdeafe94393b79b
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed May 6 15:55:49 2020 +0000
Commit: Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Fri May 8 07:21:59 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2a242e40
gnome-extra/evolution-data-server: Bump to 3.36.2
Bump to current stable 3.36.2. No changes in upstream CMake files.
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>
gnome-extra/evolution-data-server/Manifest | 1 +
.../evolution-data-server-3.36.2.ebuild | 149 +++++++++++++++++++++
2 files changed, 150 insertions(+)
diff --git a/gnome-extra/evolution-data-server/Manifest b/gnome-extra/evolution-data-server/Manifest
index f86c5f18a49..f6da9345be7 100644
--- a/gnome-extra/evolution-data-server/Manifest
+++ b/gnome-extra/evolution-data-server/Manifest
@@ -1 +1,2 @@
DIST evolution-data-server-3.34.4.tar.xz 4627704 BLAKE2B d1b93f17eec1dc71b31c9a842af369646c7412c63461a63a0c42026795d97f8b282c498ca56e14b258e7764ce333fad159d4fae534891cd02b99be6166bfbc23 SHA512 e353724591216f472faabaab468d6a8555e05cafda4a8b2c55fa3113226475f0ec9edad65d8acbf95c92844d33f36cf32d49ddc14fe934a2b8c127c32cc7b74f
+DIST evolution-data-server-3.36.2.tar.xz 4631984 BLAKE2B 946a2c30a631f3e7efa5f084bdc3a7267c6ebeea63fc84d8a5f23aeddbdd9c81d95ff87ae34519f9faf86fbac54cd4faa8749fc57017a7aad78b9a3eedcc2f66 SHA512 3549d8ce4cf47080c426a023b88d4a1f4432096018d69c1cf6628f96c4b56312b487ba53c4813968a7aea051c3cf9e8d5438bd3fbdb9605e49eb4f1402b8c8fa
diff --git a/gnome-extra/evolution-data-server/evolution-data-server-3.36.2.ebuild b/gnome-extra/evolution-data-server/evolution-data-server-3.36.2.ebuild
new file mode 100644
index 00000000000..0a7a2955df7
--- /dev/null
+++ b/gnome-extra/evolution-data-server/evolution-data-server-3.36.2.ebuild
@@ -0,0 +1,149 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+VALA_USE_DEPEND="vapigen"
+
+inherit cmake-utils db-use flag-o-matic gnome2 systemd vala virtualx
+
+DESCRIPTION="Evolution groupware backend"
+HOMEPAGE="https://wiki.gnome.org/Apps/Evolution"
+
+# Note: explicitly "|| ( LGPL-2 LGPL-3 )", not "LGPL-2+".
+LICENSE="|| ( LGPL-2 LGPL-3 ) BSD Sleepycat"
+SLOT="0/62-24-20" # subslot = libcamel-1.2/libedataserver-1.2/libebook-1.2.so soname version
+
+IUSE="berkdb +gnome-online-accounts +gtk gtk-doc +introspection ipv6 ldap kerberos oauth vala +weather"
+REQUIRED_USE="vala? ( introspection )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+
+# gdata-0.17.7 soft required for new gdata_feed_get_next_page_token API to handle more than 100 google tasks
+# berkdb needed only for migrating old addressbook data from <3.13 versions, bug #519512
+# libical-glib currently (2020-02-29) oddly behind USE=introspection; but introspection also needed if USE=introspection for eds
+gdata_depend=">=dev-libs/libgdata-0.17.7:="
+RDEPEND="
+ >=app-crypt/gcr-3.4
+ >=app-crypt/libsecret-0.5[crypt]
+ >=dev-db/sqlite-3.7.17:=
+ >=dev-libs/glib-2.46:2
+ >=dev-libs/libical-3.0.5:=[introspection(-)]
+ >=dev-libs/libxml2-2
+ >=dev-libs/nspr-4.4:=
+ >=dev-libs/nss-3.9:=
+ >=net-libs/libsoup-2.42:2.4
+
+ dev-libs/icu:=
+ sys-libs/zlib:=
+ virtual/libiconv
+
+ berkdb? ( >=sys-libs/db-4:= )
+ gtk? (
+ >=app-crypt/gcr-3.4[gtk]
+ >=x11-libs/gtk+-3.10:3
+ >=media-libs/libcanberra-0.25[gtk3]
+ )
+ oauth? (
+ >=dev-libs/json-glib-1.0.4
+ >=net-libs/webkit-gtk-2.11.91:4
+ ${gdata_depend}
+ )
+ gnome-online-accounts? (
+ >=net-libs/gnome-online-accounts-3.8:=
+ ${gdata_depend} )
+ introspection? ( >=dev-libs/gobject-introspection-0.9.12:= )
+ kerberos? ( virtual/krb5:= )
+ ldap? ( >=net-nds/openldap-2:= )
+ weather? ( >=dev-libs/libgweather-3.10:2= )
+"
+DEPEND="${RDEPEND}
+ dev-util/gdbus-codegen
+ dev-util/glib-utils
+ dev-util/gperf
+ gtk-doc? ( >=dev-util/gtk-doc-1.14
+ app-text/docbook-xml-dtd:4.1.2 )
+ >=dev-util/intltool-0.35.5
+ >=sys-devel/gettext-0.18.3
+ virtual/pkgconfig
+ vala? ( $(vala_depend)
+ net-libs/libsoup:2.4[vala]
+ dev-libs/libical[vala(-)]
+ )
+"
+
+# Some tests fail due to missing locales.
+# Also, dbus tests are flaky, bugs #397975 #501834
+# It looks like a nightmare to disable those for now.
+RESTRICT="test !test? ( test )"
+
+# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare call
+src_prepare() {
+ use vala && vala_src_prepare
+ cmake-utils_src_prepare
+ gnome2_src_prepare
+
+ # Make CMakeLists versioned vala enabled
+ sed -e "s;\(find_program(VALAC\) valac);\1 ${VALAC});" \
+ -e "s;\(find_program(VAPIGEN\) vapigen);\1 ${VAPIGEN});" \
+ -i "${S}"/CMakeLists.txt || die
+}
+
+src_configure() {
+ # /usr/include/db.h is always db-1 on FreeBSD
+ # so include the right dir in CPPFLAGS
+ use berkdb && append-cppflags "-I$(db_includedir)"
+
+ local google_enable
+ if use oauth || use gnome-online-accounts; then
+ google_enable="ON"
+ else
+ google_enable="OFF"
+ fi
+
+ # phonenumber does not exist in tree
+ local mycmakeargs=(
+ -DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+ -DENABLE_GTK_DOC=$(usex gtk-doc)
+ -DWITH_PRIVATE_DOCS=$(usex gtk-doc)
+ -DENABLE_SCHEMAS_COMPILE=OFF
+ -DENABLE_INTROSPECTION=$(usex introspection)
+ -DWITH_KRB5=$(usex kerberos)
+ -DWITH_KRB5_INCLUDES=$(usex kerberos "${EPREFIX}"/usr "")
+ -DWITH_KRB5_LIBS=$(usex kerberos "${EPREFIX}"/usr/$(get_libdir) "")
+ -DWITH_OPENLDAP=$(usex ldap)
+ -DWITH_PHONENUMBER=OFF
+ -DENABLE_SMIME=ON
+ -DENABLE_GTK=$(usex gtk)
+ -DENABLE_CANBERRA=$(usex gtk)
+ -DENABLE_OAUTH2=$(usex oauth)
+ -DENABLE_EXAMPLES=OFF
+ -DENABLE_GOA=$(usex gnome-online-accounts)
+ -DWITH_LIBDB=$(usex berkdb "${EPREFIX}"/usr OFF)
+ # ENABLE_BACKTRACES requires libdwarf ?
+ -DENABLE_IPV6=$(usex ipv6)
+ -DENABLE_WEATHER=$(usex weather)
+ -DENABLE_GOOGLE=${google_enable}
+ -DENABLE_LARGEFILE=ON
+ -DENABLE_VALA_BINDINGS=$(usex vala)
+ )
+
+ cmake-utils_src_configure
+}
+
+src_compile() {
+ cmake-utils_src_compile
+}
+
+src_test() {
+ virtx cmake-utils_src_test
+}
+
+src_install() {
+ cmake-utils_src_install
+
+ if use ldap; then
+ insinto /etc/openldap/schema
+ doins "${FILESDIR}"/calentry.schema
+ dosym ../../../usr/share/${PN}/evolutionperson.schema /etc/openldap/schema/evolutionperson.schema
+ fi
+}