[gentoo-commits] repo/gentoo:master commit in: dev-qt/qt-creator/

["Jason A. Donenfeld" <zx2c4@gentoo.org>]

commit:     30749a61ee688244ee70711461c063a531c052b3
Author:     Jason A. Donenfeld <zx2c4 <AT> gentoo <DOT> org>
AuthorDate: Wed May  6 02:35:37 2020 +0000
Commit:     Jason A. Donenfeld <zx2c4 <AT> gentoo <DOT> org>
CommitDate: Wed May  6 02:56:04 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=30749a61

dev-qt/qt-creator: bump to 4.12.0

Closes: https://bugs.gentoo.org/704540
Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Jason A. Donenfeld <zx2c4 <AT> gentoo.org>

 dev-qt/qt-creator/Manifest                 |   1 +
 dev-qt/qt-creator/qt-creator-4.12.0.ebuild | 204 +++++++++++++++++++++++++++++
 2 files changed, 205 insertions(+)

diff --git a/dev-qt/qt-creator/Manifest b/dev-qt/qt-creator/Manifest
index 9c766617a7d..d7586825807 100644
--- a/dev-qt/qt-creator/Manifest
+++ b/dev-qt/qt-creator/Manifest
@@ -1,2 +1,3 @@
 DIST qt-creator-opensource-src-4.10.1.tar.xz 26299716 BLAKE2B a72e05fc80cb4065851e5849f49c6ec8e35b08916e928a9fea856ba30710220d8632f4a1ffaf1d1d5e2cae8e9121ab188b8f9ed672f9c8695c9e572ae609397c SHA512 ec0ac4d37e4195e906b100405869cb8e6dff618b8862d8ab620e30e034553eb944de6e4a92478ab2e67b86bd4c3e9cff6fd6051411893be36387d7821d712ce3
+DIST qt-creator-opensource-src-4.12.0.tar.xz 32575196 BLAKE2B 193e10a790f35944473c2177ba84e6e15d00effc769b4d63a51a217e4da93a4d6ca0061976d0def31c625a73d49b0adcb40e551d02a70ab7225b40f441d9b6b6 SHA512 9c35ebf095c2874b89af54b06fd190976a27f7e753a23e47db3b26947bdba64e4fe7774ae8b252867cf7f6f0c86b35d773a4012cae6d4aaa9101d7a31973f215
 DIST qt-creator-opensource-src-4.8.2.tar.xz 24600872 BLAKE2B c686ea4f0ab981cba98319d8d7dd8eee9fd967d17e80f2602e8416145bddcbd7cae928d06a950914d677c9b2e82ed855812e66d64ce7cc998742357284f41865 SHA512 9900a82b1298a1cc74b33eab6a1063ed77e11f3150b8f82a72b7703b88f979e5a332efee9a622554df5238b44470e99a061b6c70f0d8cdfc352a07ce51a4c450

diff --git a/dev-qt/qt-creator/qt-creator-4.12.0.ebuild b/dev-qt/qt-creator/qt-creator-4.12.0.ebuild
new file mode 100644
index 00000000000..a4ca520e993
--- /dev/null
+++ b/dev-qt/qt-creator/qt-creator-4.12.0.ebuild
@@ -0,0 +1,204 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+LLVM_MAX_SLOT=9
+PLOCALES="cs da de fr ja pl ru sl uk zh-CN zh-TW"
+
+inherit llvm qmake-utils virtualx xdg
+
+DESCRIPTION="Lightweight IDE for C++/QML development centering around Qt"
+HOMEPAGE="https://doc.qt.io/qtcreator/"
+LICENSE="GPL-3"
+SLOT="0"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://code.qt.io/${PN}/${PN}.git"
+else
+	MY_PV=${PV/_/-}
+	MY_P=${PN}-opensource-src-${MY_PV}
+	[[ ${MY_PV} == ${PV} ]] && MY_REL=official || MY_REL=development
+	SRC_URI="https://download.qt.io/${MY_REL}_releases/${PN/-}/$(ver_cut 1-2)/${MY_PV}/${MY_P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~x86"
+	S=${WORKDIR}/${MY_P}
+fi
+
+# TODO: unbundle sqlite and KSyntaxHighlighting
+
+QTC_PLUGINS=(android +autotest baremetal beautifier boot2qt
+	'+clang:clangcodemodel|clangformat|clangpchmanager|clangrefactoring|clangtools' clearcase
+	cmake:cmakeprojectmanager cppcheck ctfvisualizer cvs +designer git glsl:glsleditor +help ios +lsp:languageclient
+	mercurial modeling:modeleditor nim perforce perfprofiler python qbs:qbsprojectmanager
+	+qmldesigner qmlprofiler qnx remotelinux scxml:scxmleditor serialterminal silversearcher subversion
+	valgrind winrt)
+IUSE="doc systemd test +webengine ${QTC_PLUGINS[@]%:*}"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+	clang? ( test? ( qbs ) )
+	qnx? ( remotelinux )
+	boot2qt? ( remotelinux )
+	python? ( lsp )
+"
+
+# minimum Qt version required
+QT_PV="5.12.3:5"
+
+CDEPEND="
+	>=dev-cpp/yaml-cpp-0.6.2
+	>=dev-qt/qtconcurrent-${QT_PV}
+	>=dev-qt/qtcore-${QT_PV}
+	>=dev-qt/qtdeclarative-${QT_PV}[widgets]
+	>=dev-qt/qtgui-${QT_PV}
+	>=dev-qt/qtnetwork-${QT_PV}[ssl]
+	>=dev-qt/qtprintsupport-${QT_PV}
+	>=dev-qt/qtquickcontrols-${QT_PV}
+	>=dev-qt/qtscript-${QT_PV}
+	>=dev-qt/qtsql-${QT_PV}[sqlite]
+	>=dev-qt/qtsvg-${QT_PV}
+	>=dev-qt/qtwidgets-${QT_PV}
+	>=dev-qt/qtx11extras-${QT_PV}
+	>=dev-qt/qtxml-${QT_PV}
+	clang? ( >=sys-devel/clang-9.0.1:= )
+	designer? ( >=dev-qt/designer-${QT_PV} )
+	help? (
+		>=dev-qt/qthelp-${QT_PV}
+		webengine? ( >=dev-qt/qtwebengine-${QT_PV}[widgets] )
+	)
+	perfprofiler? ( dev-libs/elfutils )
+	qbs? ( >=dev-util/qbs-1.13.1 )
+	serialterminal? ( >=dev-qt/qtserialport-${QT_PV} )
+	systemd? ( sys-apps/systemd:= )
+"
+DEPEND="${CDEPEND}
+	>=dev-qt/linguist-tools-${QT_PV}
+	virtual/pkgconfig
+	doc? ( >=dev-qt/qdoc-${QT_PV} )
+	test? (
+		>=dev-qt/qtdeclarative-${QT_PV}[localstorage]
+		>=dev-qt/qtquickcontrols2-${QT_PV}
+		>=dev-qt/qttest-${QT_PV}
+		>=dev-qt/qtxmlpatterns-${QT_PV}[qml]
+	)
+"
+RDEPEND="${CDEPEND}
+	sys-devel/gdb[client,python]
+	cmake? ( dev-util/cmake )
+	cppcheck? ( dev-util/cppcheck )
+	cvs? ( dev-vcs/cvs )
+	git? ( dev-vcs/git )
+	mercurial? ( dev-vcs/mercurial )
+	silversearcher? ( sys-apps/the_silver_searcher )
+	subversion? ( dev-vcs/subversion )
+	valgrind? ( dev-util/valgrind )
+"
+# qt translations must also be installed or qt-creator translations won't be loaded
+for x in ${PLOCALES}; do
+	IUSE+=" l10n_${x}"
+	RDEPEND+=" l10n_${x}? ( >=dev-qt/qttranslations-${QT_PV} )"
+done
+unset x
+
+pkg_setup() {
+	use clang && llvm_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# disable unwanted plugins
+	for plugin in "${QTC_PLUGINS[@]#[+-]}"; do
+		if ! use ${plugin%:*}; then
+			einfo "Disabling ${plugin%:*} plugin"
+			sed -i -re "s/(^\s+|\s*SUBDIRS\s*\+=.*)\<(${plugin#*:})\>(.*)/\1\3/" \
+				src/plugins/plugins.pro || die "failed to disable ${plugin%:*} plugin"
+		fi
+	done
+	sed -i -e '/updateinfo/d' src/plugins/plugins.pro || die
+
+	# avoid building unused support libraries and tools
+	if ! use clang; then
+		sed -i -e '/clangsupport/d' src/libs/libs.pro || die
+		sed -i -e '/clang\(\|pchmanager\|refactoring\)backend/d' src/tools/tools.pro || die
+	fi
+	if ! use glsl; then
+		sed -i -e '/glsl/d' src/libs/libs.pro || die
+	fi
+	if ! use lsp; then
+		sed -i -e '/languageserverprotocol/d' src/libs/libs.pro tests/auto/auto.pro || die
+	fi
+	if ! use modeling; then
+		sed -i -e '/modelinglib/d' src/libs/libs.pro || die
+	fi
+	if ! use perfprofiler; then
+		rm -rf src/tools/perfparser || die
+		if ! use qmlprofiler && ! use ctfvisualizer; then
+			sed -i -e '/tracing/d' src/libs/libs.pro tests/auto/auto.pro || die
+		fi
+	fi
+	if ! use qmldesigner; then
+		sed -i -e '/qml2puppet/d' src/tools/tools.pro || die
+		sed -i -e '/qmldesigner/d' tests/auto/qml/qml.pro || die
+	fi
+	if ! use valgrind; then
+		sed -i -e '/valgrindfake/d' src/tools/tools.pro || die
+		sed -i -e '/valgrind/d' tests/auto/auto.pro || die
+	fi
+
+	# automagic dep on qtwebengine
+	if ! use webengine; then
+		sed -i -e 's/isEmpty(QT\.webenginewidgets\.name)/true/' src/plugins/help/help.pro || die
+	fi
+
+	# disable broken or unreliable tests
+	sed -i -e 's/\(manual\|tools\|unit\)//g' tests/tests.pro || die
+	sed -i -e '/\(dumpers\|namedemangler\)\.pro/d' tests/auto/debugger/debugger.pro || die
+	sed -i -e '/CONFIG -=/s/$/ testcase/' tests/auto/extensionsystem/pluginmanager/correctplugins1/plugin?/plugin?.pro || die
+	sed -i -e 's/\<check\>//' tests/auto/qml/codemodel/codemodel.pro || die
+
+	# do not install test binaries
+	sed -i -e '/CONFIG +=/s/$/ no_testcase_installs/' tests/auto/{qttest.pri,json/json.pro} || die
+
+	# fix path to some clang headers
+	sed -i -e "/^CLANG_RESOURCE_DIR\s*=/s:\$\${LLVM_LIBDIR}:${EPREFIX}/usr/lib:" src/shared/clang/clang_defines.pri || die
+
+	# fix translations
+	local lang languages=
+	for lang in ${PLOCALES}; do
+		use l10n_${lang} && languages+=" ${lang/-/_}"
+	done
+	sed -i -e "/^LANGUAGES\s*=/s:=.*:=${languages}:" share/qtcreator/translations/translations.pro || die
+
+	# remove bundled qbs
+	rm -rf src/shared/qbs || die
+}
+
+src_configure() {
+	eqmake5 IDE_LIBRARY_BASENAME="$(get_libdir)" \
+		IDE_PACKAGE_MODE=1 \
+		$(use clang && echo LLVM_INSTALL_DIR="$(get_llvm_prefix ${LLVM_MAX_SLOT})") \
+		$(use qbs && echo QBS_INSTALL_DIR="${EPREFIX}/usr") \
+		CONFIG+=qbs_disable_rpath \
+		CONFIG+=qbs_enable_project_file_updates \
+		$(use systemd && echo CONFIG+=journald) \
+		$(use test && echo BUILD_TESTS=1)
+}
+
+src_test() {
+	cd tests/auto && virtx default
+}
+
+src_install() {
+	emake INSTALL_ROOT="${ED}/usr" install
+
+	dodoc dist/{changes-*,known-issues}
+
+	# install documentation
+	if use doc; then
+		emake docs
+		# don't use ${PF} or the doc will not be found
+		insinto /usr/share/doc/qtcreator
+		doins share/doc/qtcreator/qtcreator{,-dev}.qch
+		docompress -x /usr/share/doc/qtcreator/qtcreator{,-dev}.qch
+	fi
+}