[gentoo-commits] repo/gentoo:master commit in: app-crypt/libsecret/

["Matt Turner" <mattst88@gentoo.org>]

commit:     283e9b209978320c4faa31b3adf71661d3bbd182
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sun Apr 26 01:33:26 2020 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sun Apr 26 01:53:58 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=283e9b20

app-crypt/libsecret: Version bump to 0.20.3

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 app-crypt/libsecret/Manifest                |  1 +
 app-crypt/libsecret/libsecret-0.20.3.ebuild | 94 +++++++++++++++++++++++++++++
 2 files changed, 95 insertions(+)

diff --git a/app-crypt/libsecret/Manifest b/app-crypt/libsecret/Manifest
index 66647071754..8be7ee94fc1 100644
--- a/app-crypt/libsecret/Manifest
+++ b/app-crypt/libsecret/Manifest
@@ -1,2 +1,3 @@
 DIST libsecret-0.18.8.tar.xz 509432 BLAKE2B 3e3995d2c44367e31f3914087494764acfe82fb597b524c4982b4fca4e16612509c675f545191ee3cdae59698614395bef54ad82ae88a7e4e19898ba0be7828f SHA512 9e2ec8d458af6ed078bf3c6d956599f73f2cc7720332c424e9aede1f77f3d969c5122cf7b70899bc07ad96a3a628bf79bc5fffa88274d1ef2bcaaca6719f90d4
 DIST libsecret-0.20.2.tar.xz 526224 BLAKE2B cae93962480f65d2c91b1c26a23321d19c256692754ef37c658e346a6cb6b91cdebe134516c3c8652c5ee502b8f7a070a8d519ed878b2f6dfc124ea7b032613f SHA512 89143c8ccc8f6fa0cda2c98baef92e8cbf9b319a984826a09c527125e14712023ee65cada42a2c9232524528da8c1c3d2235ecbcb93e2f06e94121a601c22857
+DIST libsecret-0.20.3.tar.xz 526388 BLAKE2B ae2e64af61c269eb109fa7840cc7ff2362ac69eab4b452074c2cb3a80b26cc88e8d341a7649e0f16fa73541943d968dfbd6f3cc802d99a37f3a7d91e8b20cfe3 SHA512 020e1954e0965f33ee15f35e1f439b6c1650322a9112078f7a3e265cee83ad99d217ae3b363fbadc06c5cb0941f7e544d91da72e5be1c6b96992c071e6170c22

diff --git a/app-crypt/libsecret/libsecret-0.20.3.ebuild b/app-crypt/libsecret/libsecret-0.20.3.ebuild
new file mode 100644
index 00000000000..28696c25eb4
--- /dev/null
+++ b/app-crypt/libsecret/libsecret-0.20.3.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_{6,7} )
+VALA_USE_DEPEND=vapigen
+
+inherit gnome2 multilib-minimal python-any-r1 vala virtualx
+
+DESCRIPTION="GObject library for accessing the freedesktop.org Secret Service API"
+HOMEPAGE="https://wiki.gnome.org/Projects/Libsecret"
+
+LICENSE="LGPL-2.1+ Apache-2.0" # Apache-2.0 license is used for tests only
+SLOT="0"
+
+IUSE="+crypt +introspection test +vala"
+RESTRICT="!test? ( test )"
+# Tests fail with USE=-introspection, https://bugs.gentoo.org/655482
+REQUIRED_USE="test? ( introspection )
+	vala? ( introspection )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-libs/glib-2.44:2[${MULTILIB_USEDEP}]
+	crypt? ( >=dev-libs/libgcrypt-1.2.2:0=[${MULTILIB_USEDEP}] )
+	introspection? ( >=dev-libs/gobject-introspection-1.29:= )
+"
+PDEPEND=">=gnome-base/gnome-keyring-3
+"
+# PDEPEND to avoid circular dep (bug #547456)
+# gnome-keyring needed at runtime as explained at https://bugs.gentoo.org/475182#c2
+# Add ksecrets to PDEPEND when it's added to portage
+DEPEND="${RDEPEND}
+	dev-libs/libxslt
+	dev-util/gdbus-codegen
+	>=dev-util/gtk-doc-am-1.9
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig[${MULTILIB_USEDEP}]
+	test? (
+		$(python_gen_any_dep '
+			dev-python/mock[${PYTHON_USEDEP}]
+			dev-python/dbus-python[${PYTHON_USEDEP}]
+			introspection? ( dev-python/pygobject:3[${PYTHON_USEDEP}] )')
+		introspection? ( >=dev-libs/gjs-1.32 )
+	)
+	vala? ( $(vala_depend) )
+"
+
+python_check_deps() {
+	if use introspection; then
+		has_version --host-root "dev-python/pygobject:3[${PYTHON_USEDEP}]" || return
+	fi
+	has_version --host-root "dev-python/mock[${PYTHON_USEDEP}]" &&
+	has_version --host-root "dev-python/dbus-python[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+
+	# Drop unwanted CFLAGS modifications
+	sed -e 's/CFLAGS="$CFLAGS -\(g\|O0\|O2\)"//' -i configure || die
+}
+
+multilib_src_configure() {
+	local ECONF_SOURCE=${S}
+	gnome2_src_configure \
+		--enable-manpages \
+		--disable-strict \
+		--disable-coverage \
+		--disable-static \
+		$(use_enable crypt gcrypt) \
+		$(multilib_native_use_enable introspection) \
+		$(multilib_native_use_enable vala) \
+		LIBGCRYPT_CONFIG="${EPREFIX}/usr/bin/${CHOST}-libgcrypt-config"
+
+	if multilib_is_native_abi; then
+		ln -s "${S}"/docs/reference/libsecret/html docs/reference/libsecret/html || die
+	fi
+}
+
+multilib_src_test() {
+	# tests fail without gobject-introspection
+	multilib_is_native_abi && virtx emake check
+}
+
+multilib_src_install() {
+	gnome2_src_install
+}