[gentoo-commits] repo/gentoo:master commit in: x11-wm/qtile/

["Mikle Kolyada" <zlogene@gentoo.org>]

commit:     3ae281dbe4beb8989d388bc0bcceb42d9216c84a
Author:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
AuthorDate: Fri Apr 24 10:43:45 2020 +0000
Commit:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
CommitDate: Fri Apr 24 10:43:45 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3ae281db

x11-wm/qtile: Version bump (v0.15.1)

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Mikle Kolyada <zlogene <AT> gentoo.org>

 x11-wm/qtile/Manifest            |  1 +
 x11-wm/qtile/qtile-0.15.1.ebuild | 63 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 64 insertions(+)

diff --git a/x11-wm/qtile/Manifest b/x11-wm/qtile/Manifest
index 9d8a3cfa00e..276d5a35b88 100644
--- a/x11-wm/qtile/Manifest
+++ b/x11-wm/qtile/Manifest
@@ -1 +1,2 @@
 DIST qtile-0.14.2.tar.gz 492274 BLAKE2B b5418424a4cea6844d500ea00b4fa5c4b93d529503a3ece1f651c82cd1c63689d8ba95a706fd97e7d93cf823a6155196d724f18e47f9fe283e4df2586e55b56f SHA512 c6653e8dca24cef4b1cf48c26b2a0feb4bc125a1c966e0a3ea078fd1d1bba9c7306facf620438795aa2d2daecbd6e58bcda954753ab6b27f6c0cbead3766d8c0
+DIST qtile-0.15.1.tar.gz 522233 BLAKE2B cb5c35ab6b2e22d36c2ef69a3d6367033440a25a1c06dad5c4d455b67aa1ddf2c639451e051abcd40b5a76e93250a54271408bbe09008b44a5ebf0a520b3eb2e SHA512 57dfeeea212346c14b922303b5d2fd950292383a1da3be6bf5ca0880bedaa3adb7ffc121df617cf763fcd1208c44e34a7ba128a1f2a6e8d3042dd6906ece7e20

diff --git a/x11-wm/qtile/qtile-0.15.1.ebuild b/x11-wm/qtile/qtile-0.15.1.ebuild
new file mode 100644
index 00000000000..798fdf2473c
--- /dev/null
+++ b/x11-wm/qtile/qtile-0.15.1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit distutils-r1 virtualx
+
+if [[ ${PV} == 9999* ]] ; then
+	EGIT_REPO_URI="https://github.com/qtile/qtile.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/qtile/qtile/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="A full-featured, hackable tiling window manager written in Python"
+HOMEPAGE="http://qtile.org/"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="test"
+# docs require sphinxcontrib-blockdiag and sphinxcontrib-seqdiag
+
+RDEPEND="
+	x11-libs/cairo[X,xcb(+)]
+	x11-libs/pango
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/cairocffi-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/cffi-1.1.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.4.1[${PYTHON_USEDEP}]
+	>=dev-python/xcffib-0.8.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/xvfbwrapper[${PYTHON_USEDEP}]
+		x11-base/xorg-server[xephyr]
+		x11-apps/xeyes
+		x11-apps/xcalc
+		x11-apps/xclock
+	)
+"
+
+# display retry backoff slowness and failures
+RESTRICT="test"
+
+python_test() {
+	# force usage of built module
+	rm -rf "${S}"/libqtile || die
+	PYTHONPATH="${BUILD_DIR}/lib" py.test -v "${S}"/test || die "tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	local DOCS=( CHANGELOG README.rst )
+	distutils-r1_python_install_all
+
+	insinto /usr/share/xsessions
+	doins resources/qtile.desktop
+
+	exeinto /etc/X11/Sessions
+	newexe "${FILESDIR}"/${PN}-session ${PN}
+}