[gentoo-commits] repo/gentoo:master commit in: net-p2p/qbittorrent/

["Mikle Kolyada" <zlogene@gentoo.org>]

commit:     3071caefd905f828241a4492711509996bdbe99f
Author:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
AuthorDate: Fri Apr 24 10:29:36 2020 +0000
Commit:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
CommitDate: Fri Apr 24 10:30:13 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3071caef

net-p2p/qbittorrent: Version bump (v4.2.4)

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Mikle Kolyada <zlogene <AT> gentoo.org>

 net-p2p/qbittorrent/Manifest                 |  1 +
 net-p2p/qbittorrent/qbittorrent-4.2.4.ebuild | 69 ++++++++++++++++++++++++++++
 2 files changed, 70 insertions(+)

diff --git a/net-p2p/qbittorrent/Manifest b/net-p2p/qbittorrent/Manifest
index 509218ca129..916c46379ba 100644
--- a/net-p2p/qbittorrent/Manifest
+++ b/net-p2p/qbittorrent/Manifest
@@ -1,2 +1,3 @@
 DIST qbittorrent-4.2.1.tar.gz 7824636 BLAKE2B 06aa493b4e59f8e064955c604846cd4e4d404988819aa4f0b7a555cd3d8c74f42d4b40b581bc5c2360e5b75f0ce33f77882051360453176a9540d03d4d5de82d SHA512 345c702a49d284fe28b45e52719a79195a784ba07339ea49c340d10d387482d3ba59335b2e41616de97e3813531e808c41239e597ef4b710fcebceb0c837483c
 DIST qbittorrent-4.2.3.tar.gz 7932722 BLAKE2B d16aa81ce683578eea5186a505a5f33da457ef672261520f0fe3af11008d516d7fce8de31e31190c380c9cc3e24d7acce053dbff952f7bb937a610416f23129e SHA512 766cff294b5e2aae99073e9894c683b68af6e7abdd1eae660e444593664f65918132b9fbd7b40843143f2559b4124145e2d08478c2b87b0b6df1ef574e17f763
+DIST qbittorrent-4.2.4.tar.gz 7965424 BLAKE2B 7d1f058e3aaa66a857721c4cc915057735bfcf2d24a2076e814c8801fcb7b107d33211f2916654c17dceed0b4c53869cb8b992853a676a55069db615ae5a4663 SHA512 0c6a6226c2503edfc79d077bafd006eab02b0d42cea815cd420044857f3e13157ae068b52c7d67299e5b0a6c0da4bf5ffa702c3bd69fb84b8b734ac17441d0f7

diff --git a/net-p2p/qbittorrent/qbittorrent-4.2.4.ebuild b/net-p2p/qbittorrent/qbittorrent-4.2.4.ebuild
new file mode 100644
index 00000000000..3244261dacc
--- /dev/null
+++ b/net-p2p/qbittorrent/qbittorrent-4.2.4.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit xdg-utils
+
+DESCRIPTION="BitTorrent client in C++ and Qt"
+HOMEPAGE="https://www.qbittorrent.org
+	  https://github.com/qbittorrent"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/${PN}/qBittorrent.git"
+else
+	SRC_URI="https://github.com/qbittorrent/qBittorrent/archive/release-${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
+	S="${WORKDIR}/qBittorrent-release-${PV}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+dbus debug webui +X"
+REQUIRED_USE="dbus? ( X )"
+
+RDEPEND="
+	>=dev-libs/boost-1.62.0-r1:=
+	dev-qt/qtcore:5
+	dev-qt/qtnetwork:5[ssl]
+	>=dev-qt/qtsingleapplication-2.6.1_p20130904-r1[qt5(+),X?]
+	dev-qt/qtxml:5
+	>=net-libs/libtorrent-rasterbar-1.2.0:0=
+	sys-libs/zlib
+	dbus? ( dev-qt/qtdbus:5 )
+	X? (
+		dev-libs/geoip
+		dev-qt/qtgui:5
+		dev-qt/qtsvg:5
+		dev-qt/qtwidgets:5
+	)"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5"
+
+BDEPEND="virtual/pkgconfig"
+
+DOCS=( AUTHORS Changelog CONTRIBUTING.md README.md TODO )
+
+src_configure() {
+	econf \
+	$(use_enable dbus qt-dbus) \
+	$(use_enable debug) \
+	$(use_enable webui) \
+	$(use_enable X gui)
+}
+
+src_install() {
+	emake STRIP="/bin/false" INSTALL_ROOT="${D}" install
+	einstalldocs
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}