[gentoo-commits] repo/gentoo:master commit in: media-sound/quodlibet/

["Tobias Klausmann" <klausman@gentoo.org>]

commit:     ff40fab6285914830341c58ea0677a296b1bb08f
Author:     Tobias Klausmann <klausman <AT> gentoo <DOT> org>
AuthorDate: Wed Apr 22 07:46:11 2020 +0000
Commit:     Tobias Klausmann <klausman <AT> gentoo <DOT> org>
CommitDate: Wed Apr 22 08:17:51 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ff40fab6

media-sound/quodlibet: Add v4.3.0 with newer Py compat

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Tobias Klausmann <klausman <AT> gentoo.org>

 media-sound/quodlibet/Manifest               |  1 +
 media-sound/quodlibet/quodlibet-4.3.0.ebuild | 64 ++++++++++++++++++++++++++++
 2 files changed, 65 insertions(+)

diff --git a/media-sound/quodlibet/Manifest b/media-sound/quodlibet/Manifest
index 43715e0929d..d25350b42bd 100644
--- a/media-sound/quodlibet/Manifest
+++ b/media-sound/quodlibet/Manifest
@@ -1 +1,2 @@
 DIST quodlibet-4.2.1.tar.gz 4908102 BLAKE2B 0c1535e925842d42aafd5ff819b33a5d4527995977dd5d56b84b26462c677d81fcfb6d1de60ce50004a4b4a3eaa69896e430d36d31d904175c38f9deb23c044b SHA512 3817611c887b7c1878ccf852311020ded0a813feec1067f861d1157de6331760166c34992a6e4fe225552ae6ed4472000585fe58a3397faf277ae250f6f3c138
+DIST quodlibet-4.3.0.tar.gz 5061542 BLAKE2B 31ec24f43a1750d065e14fe69d90a1646382ead13362633c08c9c44b17cb1dca02da37612bd30e1737212098fd26947cf637501ed79b34f03167b85cc11cbdc8 SHA512 6e3cd8bebb8abeb6acde6effb08a439479e293fed18633240a1508a015c083c814fb98722c36d3970917970259095499efeb27e323ab788252940714cae2fddc

diff --git a/media-sound/quodlibet/quodlibet-4.3.0.ebuild b/media-sound/quodlibet/quodlibet-4.3.0.ebuild
new file mode 100644
index 00000000000..0dd768bcf9e
--- /dev/null
+++ b/media-sound/quodlibet/quodlibet-4.3.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_6 python3_7 python3_8 )
+inherit distutils-r1 xdg-utils
+
+DESCRIPTION="audio library tagger, manager, and player for GTK+"
+HOMEPAGE="https://quodlibet.readthedocs.io/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/release-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="+dbus gstreamer +udev"
+
+RDEPEND="dev-libs/keybinder:3[introspection]
+	dev-python/feedparser[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	>=media-libs/mutagen-1.32[${PYTHON_USEDEP}]
+	net-libs/libsoup[introspection]
+	x11-libs/gtk+[introspection]
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		media-libs/gst-plugins-good:1.0
+		media-plugins/gst-plugins-meta:1.0
+		)
+	!gstreamer? ( media-libs/xine-lib )
+	dbus? (
+		app-misc/media-player-info
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		)
+	udev? ( virtual/udev )"
+DEPEND="dev-util/intltool"
+
+S="${WORKDIR}/${PN}-release-${PV}/${PN}"
+
+src_prepare() {
+	local qlconfig=${PN}/config.py
+
+	if ! use gstreamer; then
+		sed -i -e '/backend/s:gstbe:xinebe:' ${qlconfig} || die
+	fi
+
+	sed -i -e '/gst_pipeline/s:"":"alsasink":' ${qlconfig} || die
+
+	distutils-r1_src_prepare
+}
+
+src_install() {
+	distutils-r1_src_install
+	dodoc NEWS README
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}