[gentoo-commits] proj/kde:master commit in: kde-plasma/plasma-meta/, kde-plasma/plasma-desktop/, ...

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     b5b47447ef10649fadc4710541ebcc171e34c8ba
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Thu Apr 16 13:01:20 2020 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Thu Apr 16 13:56:29 2020 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=b5b47447

kde-plasma: Add 5.18.4.1 revbumps with gui-wm/kwinft support

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../libkscreen/libkscreen-5.18.4.1-r1.ebuild       |  44 ++++
 .../libkworkspace/libkworkspace-5.18.4.1-r1.ebuild |  63 ++++++
 .../plasma-desktop-5.18.4.1-r2.ebuild              | 180 +++++++++++++++++
 .../plasma-meta/plasma-meta-5.18.4.1-r1.ebuild     | 109 ++++++++++
 .../plasma-workspace-5.18.4.1-r1.ebuild            | 222 +++++++++++++++++++++
 5 files changed, 618 insertions(+)

diff --git a/kde-plasma/libkscreen/libkscreen-5.18.4.1-r1.ebuild b/kde-plasma/libkscreen/libkscreen-5.18.4.1-r1.ebuild
new file mode 100644
index 0000000000..7f73751346
--- /dev/null
+++ b/kde-plasma/libkscreen/libkscreen-5.18.4.1-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_QTHELP="true"
+ECM_TEST="forceoptional"
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Plasma screen management library"
+SRC_URI+=" https://dev.gentoo.org/~asturm/distfiles/${PN}-wrapland-support-5.18.4.tar.xz"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5/7"
+KEYWORDS="~amd64"
+IUSE="kwinft"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kwayland-${KFMIN}:5
+	x11-libs/libxcb
+	kwinft? ( gui-libs/wrapland:5 )
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=( "${WORKDIR}/${PN}-wrapland-support.patch" )
+
+# requires running session
+RESTRICT+=" test"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package kwinft Wrapland)
+	)
+
+	ecm_src_configure
+}

diff --git a/kde-plasma/libkworkspace/libkworkspace-5.18.4.1-r1.ebuild b/kde-plasma/libkworkspace/libkworkspace-5.18.4.1-r1.ebuild
new file mode 100644
index 0000000000..8d0693d563
--- /dev/null
+++ b/kde-plasma/libkworkspace/libkworkspace-5.18.4.1-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_TEST="true"
+KDE_ORG_NAME="plasma-workspace"
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Workspace library to interact with the Plasma session manager"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64"
+IUSE=""
+
+COMMON_DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=kde-plasma/kscreenlocker-${PVCUT}:5
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXau
+"
+DEPEND="${COMMON_DEPEND}
+	|| (
+		>=kde-plasma/kwin-${PVCUT}:5
+		>=gui-wm/kwinft-$(ver_cut 1-2):5
+	)
+"
+RDEPEND="${COMMON_DEPEND}
+	!<kde-plasma/plasma-workspace-5.14.2:5
+"
+
+S="${S}/${PN}"
+
+PATCHES=( "${FILESDIR}/${PN}-5.16.80-standalone.patch" )
+
+src_prepare() {
+	# delete colliding libkworkspace translations, let ecm_src_prepare do its magic
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find ../po -type f -name "*po" -and -not -name "libkworkspace*" -delete || die
+		rm -rf po/*/docs || die
+		cp -a ../po ./ || die
+	fi
+	ecm_src_prepare
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		cat >> CMakeLists.txt <<- _EOF_ || die
+			ki18n_install(po)
+		_EOF_
+	fi
+
+	sed -e "/set/s/GENTOO_PV/$(ver_cut 1-3)/" \
+		-i CMakeLists.txt || die "Failed to prepare CMakeLists.txt"
+}

diff --git a/kde-plasma/plasma-desktop/plasma-desktop-5.18.4.1-r2.ebuild b/kde-plasma/plasma-desktop/plasma-desktop-5.18.4.1-r2.ebuild
new file mode 100644
index 0000000000..b48df34661
--- /dev/null
+++ b/kde-plasma/plasma-desktop/plasma-desktop-5.18.4.1-r2.ebuild
@@ -0,0 +1,180 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="KDE Plasma desktop"
+
+# Avoid pulling in xf86-input-{evdev,libinput} DEPEND just for 1 header
+SHA_EVDEV="425ed601"
+SHA_LIBINPUT="e52daf20"
+XORG_URI="https://gitlab.freedesktop.org/xorg/driver/PKG/-/raw"
+SRC_URI+="
+	${XORG_URI/PKG/xf86-input-evdev}/${SHA_EVDEV}/include/evdev-properties.h -> evdev-properties.h-${SHA_EVDEV}
+	${XORG_URI/PKG/xf86-input-libinput}/${SHA_LIBINPUT}/include/libinput-properties.h -> libinput-properties.h-${SHA_LIBINPUT}
+"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64"
+IUSE="emoji +fontconfig ibus scim +semantic-desktop touchpad"
+
+COMMON_DEPEND="
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/attica-${KFMIN}:5
+	>=kde-frameworks/kactivities-${KFMIN}:5
+	>=kde-frameworks/kactivities-stats-${KFMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kded-${KFMIN}:5
+	>=kde-frameworks/kdelibs4support-${KFMIN}:5
+	>=kde-frameworks/kemoticons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/krunner-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=kde-frameworks/sonnet-${KFMIN}:5
+	|| (
+		>=kde-plasma/kwin-${PVCUT}:5
+		>=gui-wm/kwinft-$(ver_cut 1-2):5
+	)
+	>=kde-plasma/libksysguard-${PVCUT}:5
+	>=kde-plasma/plasma-workspace-${PVCUT}:5
+	media-libs/phonon[qt5(+)]
+	x11-libs/libX11
+	x11-libs/libXcursor
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libxcb[xkb]
+	x11-libs/libxkbfile
+	emoji? (
+		app-i18n/ibus[emoji]
+		dev-libs/glib:2
+		media-fonts/noto-emoji
+	)
+	fontconfig? (
+		media-libs/fontconfig
+		media-libs/freetype
+		x11-libs/libXft
+		x11-libs/xcb-util-image
+	)
+	ibus? (
+		app-i18n/ibus[emoji?]
+		dev-libs/glib:2
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libxcb
+		x11-libs/xcb-util-keysyms
+	)
+	scim? ( app-i18n/scim )
+	semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:5 )
+	touchpad? ( x11-drivers/xf86-input-synaptics )
+"
+DEPEND="${COMMON_DEPEND}
+	dev-libs/boost
+	x11-base/xorg-proto
+	fontconfig? ( x11-libs/libXrender )
+"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/qqc2-desktop-style-${KFMIN}:5
+	>=kde-plasma/breeze-${PVCUT}:5
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+	>=kde-plasma/oxygen-${PVCUT}:5
+	sys-apps/util-linux
+	x11-apps/setxkbmap
+	!<kde-plasma/kdeplasma-addons-5.15.80
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-5.18.4.1-override-include-dirs.patch" # downstream patch
+)
+
+src_unpack() {
+	kde.org_src_unpack
+	mkdir "${WORKDIR}/include" || die "Failed to prepare evdev/libinput dir"
+	cp "${DISTDIR}"/evdev-properties.h-${SHA_EVDEV} \
+		"${WORKDIR}"/include/evdev-properties.h || die "Failed to copy evdev"
+	cp "${DISTDIR}"/libinput-properties.h-${SHA_LIBINPUT} \
+		"${WORKDIR}"/include/libinput-properties.h || die "Failed to copy libinput"
+}
+
+src_prepare() {
+	ecm_src_prepare
+
+	if ! use ibus; then
+		sed -e "s/Qt5X11Extras_FOUND AND XCB_XCB_FOUND AND XCB_KEYSYMS_FOUND/false/" \
+			-i applets/kimpanel/backend/ibus/CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package fontconfig Fontconfig)
+		-DEvdev_INCLUDE_DIRS="${WORKDIR}"/include
+		-DXORGLIBINPUT_INCLUDE_DIRS="${WORKDIR}"/include
+		$(cmake_use_find_package scim SCIM)
+		$(cmake_use_find_package semantic-desktop KF5Baloo)
+		$(cmake_use_find_package touchpad Synaptics)
+	)
+	if ! use emoji && ! use ibus; then
+		mycmakeargs+=( -DCMAKE_DISABLE_FIND_PACKAGE_IBus=ON )
+	fi
+
+	ecm_src_configure
+}
+
+src_test() {
+	# parallel tests fail, foldermodeltest,positionertest hang, bug #646890
+	# needs D-Bus, bug #634166
+	local myctestargs=(
+		-j1
+		-E "(foldermodeltest|positionertest|test_kio_fonts)"
+	)
+
+	ecm_src_test
+}

diff --git a/kde-plasma/plasma-meta/plasma-meta-5.18.4.1-r1.ebuild b/kde-plasma/plasma-meta/plasma-meta-5.18.4.1-r1.ebuild
new file mode 100644
index 0000000000..440bc316ff
--- /dev/null
+++ b/kde-plasma/plasma-meta/plasma-meta-5.18.4.1-r1.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Merge this to pull in all Plasma 5 packages"
+HOMEPAGE="https://kde.org/plasma-desktop"
+
+LICENSE="metapackage"
+SLOT="5"
+KEYWORDS="~amd64"
+IUSE="bluetooth +browser-integration consolekit crypt +desktop-portal discover
++display-manager elogind grub gtk +handbook kwinft +legacy-systray networkmanager
+pam plymouth pulseaudio qrcode +sddm sdk systemd thunderbolt +wallpapers"
+
+REQUIRED_USE="?? ( consolekit elogind systemd )"
+
+RDEPEND="
+	>=kde-plasma/breeze-${PV}:${SLOT}
+	>=kde-plasma/drkonqi-${PV}:${SLOT}
+	>=kde-plasma/kactivitymanagerd-${PV}:${SLOT}
+	>=kde-plasma/kde-cli-tools-${PV}:${SLOT}
+	>=kde-plasma/kdecoration-${PV}:${SLOT}
+	>=kde-plasma/kdeplasma-addons-${PV}:${SLOT}
+	>=kde-plasma/kgamma-${PV}:${SLOT}
+	>=kde-plasma/khotkeys-${PV}:${SLOT}
+	>=kde-plasma/kinfocenter-${PV}:${SLOT}
+	>=kde-plasma/kmenuedit-${PV}:${SLOT}
+	>=kde-plasma/kscreen-${PV}:${SLOT}
+	>=kde-plasma/kscreenlocker-${PV}:${SLOT}
+	>=kde-plasma/ksshaskpass-${PV}:${SLOT}
+	>=kde-plasma/ksysguard-${PV}:${SLOT}
+	>=kde-plasma/kwayland-integration-${PV}:${SLOT}
+	!kwinft? ( >=kde-plasma/kwin-${PV}:${SLOT} )
+	kwinft? ( >=gui-wm/kwinft-$(ver_cut 1-2):${SLOT} )
+	>=kde-plasma/kwrited-${PV}:${SLOT}
+	>=kde-plasma/libkscreen-${PV}:${SLOT}[kwinft?]
+	>=kde-plasma/libksysguard-${PV}:${SLOT}
+	>=kde-plasma/milou-${PV}:${SLOT}
+	>=kde-plasma/oxygen-${PV}:${SLOT}
+	>=kde-plasma/plasma-desktop-${PV}:${SLOT}
+	>=kde-plasma/plasma-integration-${PV}:${SLOT}
+	>=kde-plasma/plasma-workspace-${PV}:${SLOT}
+	>=kde-plasma/polkit-kde-agent-${PV}:${SLOT}
+	>=kde-plasma/powerdevil-${PV}:${SLOT}
+	>=kde-plasma/systemsettings-${PV}:${SLOT}
+	>=kde-plasma/user-manager-${PV}:${SLOT}
+	sys-apps/dbus[elogind?,systemd?]
+	sys-auth/polkit[elogind?,systemd?]
+	sys-fs/udisks:2[elogind?,systemd?]
+	bluetooth? ( >=kde-plasma/bluedevil-${PV}:${SLOT} )
+	browser-integration? ( >=kde-plasma/plasma-browser-integration-${PV}:${SLOT} )
+	consolekit? ( >=sys-auth/consolekit-1.0.1 )
+	crypt? ( >=kde-plasma/plasma-vault-${PV}:${SLOT} )
+	desktop-portal? ( >=kde-plasma/xdg-desktop-portal-kde-${PV}:${SLOT} )
+	discover? ( >=kde-plasma/discover-${PV}:${SLOT} )
+	display-manager? (
+		sddm? (
+			>=kde-plasma/sddm-kcm-${PV}:${SLOT}
+			x11-misc/sddm[consolekit?,elogind?,systemd?]
+		)
+		!sddm? ( x11-misc/lightdm )
+	)
+	grub? ( >=kde-plasma/breeze-grub-${PV}:${SLOT} )
+	gtk? (
+		>=kde-plasma/breeze-gtk-${PV}:${SLOT}
+		>=kde-plasma/kde-gtk-config-${PV}:${SLOT}
+	)
+	handbook? ( kde-apps/khelpcenter:5 )
+	legacy-systray? ( >=kde-plasma/xembed-sni-proxy-${PV}:${SLOT} )
+	networkmanager? (
+		>=kde-plasma/plasma-nm-${PV}:${SLOT}
+		net-misc/networkmanager[consolekit?,elogind?,systemd?]
+		qrcode? ( kde-frameworks/prison[qml] )
+	)
+	pam? (
+		>=kde-plasma/kwallet-pam-${PV}:${SLOT}
+		sys-auth/pambase[consolekit?,elogind?,systemd?]
+	)
+	plymouth? (
+		>=kde-plasma/breeze-plymouth-${PV}:${SLOT}
+		>=kde-plasma/plymouth-kcm-${PV}:${SLOT}
+	)
+	pulseaudio? ( >=kde-plasma/plasma-pa-${PV}:${SLOT} )
+	sdk? ( >=kde-plasma/plasma-sdk-${PV}:${SLOT} )
+	thunderbolt? ( >=kde-plasma/plasma-thunderbolt-${PV}:${SLOT} )
+	wallpapers? ( >=kde-plasma/plasma-workspace-wallpapers-${PV}:${SLOT} )
+"
+
+pkg_postinst() {
+	local i selected use_pkg_map=(
+		consolekit:sys-auth/consolekit
+		elogind:sys-auth/elogind
+		systemd:sys-apps/systemd
+	)
+	for i in ${use_pkg_map[@]}; do
+		use ${i%:*} && selected="${i%:*}"
+	done
+	for i in ${use_pkg_map[@]}; do
+		if ! use ${i%:*} && has_version ${i#*:}; then
+			ewarn "An existing installation of ${i#*:} was detected even though"
+			ewarn "${PN} was configured with USE ${selected} instead of ${i%:*}."
+			ewarn "There can only be one session manager at runtime, otherwise random issues"
+			ewarn "may occur. Please make sure USE ${i%:*} is nowhere enabled in make.conf"
+			ewarn "or package.use and remove ${i#*:} before raising bugs."
+			ewarn "For more information, visit https://wiki.gentoo.org/wiki/KDE"
+		fi
+	done
+}

diff --git a/kde-plasma/plasma-workspace/plasma-workspace-5.18.4.1-r1.ebuild b/kde-plasma/plasma-workspace/plasma-workspace-5.18.4.1-r1.ebuild
new file mode 100644
index 0000000000..c52810787d
--- /dev/null
+++ b/kde-plasma/plasma-workspace/plasma-workspace-5.18.4.1-r1.ebuild
@@ -0,0 +1,222 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="forceoptional"
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="KDE Plasma workspace"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64"
+IUSE="appstream +calendar feedback geolocation gps qalculate qrcode +semantic-desktop systemd"
+
+REQUIRED_USE="gps? ( geolocation )"
+
+# drop qtgui subslot operator when QT_MINIMAL >= 5.14.0
+COMMON_DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+	>=dev-qt/qtgui-${QTMIN}:5=[jpeg]
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kactivities-${KFMIN}:5
+	>=kde-frameworks/kactivities-stats-${KFMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kded-${KFMIN}:5
+	>=kde-frameworks/kdelibs4support-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kidletime-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kpackage-${KFMIN}:5
+	>=kde-frameworks/kpeople-${KFMIN}:5
+	>=kde-frameworks/krunner-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwayland-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=kde-plasma/kscreenlocker-${PVCUT}:5
+	|| (
+		>=kde-plasma/kwin-${PVCUT}:5
+		>=gui-wm/kwinft-$(ver_cut 1-2):5
+	)
+	>=kde-plasma/libkscreen-${PVCUT}:5
+	>=kde-plasma/libksysguard-${PVCUT}:5
+	>=kde-plasma/libkworkspace-${PVCUT}:5
+	media-libs/phonon[qt5(+)]
+	sys-libs/zlib
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libxcb
+	x11-libs/libXfixes
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/xcb-util
+	x11-libs/xcb-util-image
+	appstream? ( dev-libs/appstream[qt5] )
+	calendar? ( >=kde-frameworks/kholidays-${KFMIN}:5 )
+	feedback? ( dev-libs/kuserfeedback:5 )
+	geolocation? ( >=kde-frameworks/networkmanager-qt-${KFMIN}:5 )
+	gps? ( sci-geosciences/gpsd )
+	qalculate? ( sci-libs/libqalculate:= )
+	qrcode? ( >=kde-frameworks/prison-${KFMIN}:5 )
+	semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:5 )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	x11-base/xorg-proto
+"
+RDEPEND="${COMMON_DEPEND}
+	app-text/iso-codes
+	>=dev-qt/qdbus-${QTMIN}:5
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+	>=dev-qt/qtpaths-${QTMIN}:5
+	>=dev-qt/qtquickcontrols-${QTMIN}:5[widgets]
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-apps/kio-extras-19.04.3:5
+	>=kde-frameworks/kquickcharts-${KFMIN}:5
+	>=kde-frameworks/kdesu-${KFMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-plasma/ksysguard-${PVCUT}:5
+	>=kde-plasma/milou-${PVCUT}:5
+	>=kde-plasma/plasma-integration-${PVCUT}:5
+	x11-apps/xmessage
+	x11-apps/xprop
+	x11-apps/xrdb
+	x11-apps/xsetroot
+	systemd? ( sys-apps/dbus[user-session] )
+	!systemd? ( sys-apps/dbus )
+	!<kde-plasma/plasma-desktop-5.16.80:5
+"
+PDEPEND="
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+"
+
+PATCHES=( "${FILESDIR}/${PN}-5.14.2-split-libkworkspace.patch" )
+
+RESTRICT+=" test"
+
+pkg_setup() {
+	ecm_pkg_setup
+
+	local md5
+	local srcfile=/etc/plasma/XX/10-agent-XX.sh
+	local newdir="${EPREFIX}"/etc/xdg/plasma-workspace
+
+	if [[ -f "${EROOT}"${srcfile//XX/startup} ]]; then
+		md5=$(md5sum "${EROOT}"${srcfile//XX/startup})
+		if [[ ${md5%% *} != 90caaabb40b56bfbe65388841a6dd6ca ]]; then
+			elog "Existing modified ${EPREFIX}${srcfile//XX/startup} detected."
+			elog "Copying to ${newdir}/env/10-agent-startup.sh..."
+			cp -v "${EROOT}"${srcfile//XX/startup} "${T}"/ || die
+		fi
+	fi
+
+	if [[ -f "${EROOT}"${srcfile//XX/shutdown} ]]; then
+		md5=$(md5sum "${EROOT}"${srcfile//XX/shutdown})
+		if [[ ${md5%% *} != d7bffa0273f92abd999c7c3c43dbc23d ]]; then
+			elog "Existing modified ${EPREFIX}${srcfile//XX/shutdown} detected."
+			elog "Copying to ${newdir}/shutdown/10-agent-shutdown.sh..."
+			cp -v "${EROOT}"${srcfile//XX/shutdown} "${T}"/ || die
+		fi
+	fi
+}
+
+src_prepare() {
+	ecm_src_prepare
+
+	if [[ ! -f "${T}"/10-agent-startup.sh ]]; then
+		cp "${FILESDIR}"/10-agent-startup.sh "${T}"/ || die
+	fi
+	if [[ ! -f "${T}"/10-agent-shutdown.sh ]]; then
+		cp "${FILESDIR}"/10-agent-shutdown.sh "${T}"/ || die
+	fi
+
+	cmake_comment_add_subdirectory libkworkspace
+	# delete colliding libkworkspace translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find po -type f -name "*po" -and -name "libkworkspace*" -delete || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_xembed-sni-proxy=OFF
+		$(cmake_use_find_package appstream AppStreamQt)
+		$(cmake_use_find_package calendar KF5Holidays)
+		$(cmake_use_find_package feedback KUserFeedback)
+		$(cmake_use_find_package geolocation KF5NetworkManagerQt)
+		$(cmake_use_find_package qalculate Qalculate)
+		$(cmake_use_find_package qrcode KF5Prison)
+		$(cmake_use_find_package semantic-desktop KF5Baloo)
+	)
+
+	use geolocation && mycmakeargs+=( $(cmake_use_find_package gps libgps) )
+
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+
+	# default startup and shutdown scripts
+	insinto /etc/xdg/plasma-workspace/env
+	doins "${T}"/10-agent-startup.sh
+
+	insinto /etc/xdg/plasma-workspace/shutdown
+	doins "${T}"/10-agent-shutdown.sh
+	fperms +x /etc/xdg/plasma-workspace/shutdown/10-agent-shutdown.sh
+}
+
+pkg_postinst () {
+	ecm_pkg_postinst
+
+	# Clean up pre-5.17.4 scripts
+	if [[ -e "${EROOT}"/etc/plasma/startup/10-agent-startup.sh ]]; then
+		rm "${EROOT}"/etc/plasma/startup/10-agent-startup.sh || die
+		elog "Removed obsolete ${EPREFIX}/etc/plasma/startup/10-agent-startup.sh"
+	fi
+	if [[ -e "${EROOT}"/etc/plasma/shutdown/10-agent-shutdown.sh ]]; then
+		rm "${EROOT}"/etc/plasma/shutdown/10-agent-shutdown.sh || die
+		elog "Removed obsolete ${EPREFIX}/etc/plasma/shutdown/10-agent-shutdown.sh"
+	fi
+
+	elog "To enable gpg-agent and/or ssh-agent in Plasma sessions,"
+	elog "edit ${EPREFIX}/etc/xdg/plasma-workspace/env/10-agent-startup.sh"
+	elog "and ${EPREFIX}/etc/xdg/plasma-workspace/shutdown/10-agent-shutdown.sh"
+}