[gentoo-commits] repo/gentoo:master commit in: net-libs/libwebsockets/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     13525c63283c64214f70ad588e0b6635c4524bed
Author:     Jaco Kroon <jaco <AT> uls <DOT> co <DOT> za>
AuthorDate: Thu Apr  2 15:56:54 2020 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Sun Apr  5 07:17:54 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=13525c63

net-libs/libwebsockets: 4.0.0 version bump.

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Jaco Kroon <jaco <AT> uls.co.za>
Closes: https://github.com/gentoo/gentoo/pull/15211
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 net-libs/libwebsockets/Manifest                   |  1 +
 net-libs/libwebsockets/libwebsockets-4.0.0.ebuild | 77 +++++++++++++++++++++++
 2 files changed, 78 insertions(+)

diff --git a/net-libs/libwebsockets/Manifest b/net-libs/libwebsockets/Manifest
index 35312141b04..7d2feba9bbe 100644
--- a/net-libs/libwebsockets/Manifest
+++ b/net-libs/libwebsockets/Manifest
@@ -1 +1,2 @@
 DIST libwebsockets-3.2.1.tar.gz 9868342 BLAKE2B d822552c611f7cd0ee416bf9b9576c6052e196c1aa68b12c46a00865d3dcd131840218394317f191485fc61d8f3b7654d4a652a47f11d279a555522df84a2350 SHA512 a2d30a7a0416a26484743efdaa8635542480a74b0ef0f6e172dab5de4688486efb13457fc8a884d9916f76322cab0cbc9ab675f496558edd1dd9b833d087207d
+DIST libwebsockets-4.0.0.tar.gz 12330114 BLAKE2B 4c845b02793853e349df311f1772fc6988876dc21a262d952b41a1742f59c9d9d0f9a8f28ce8fa9cdc36e3342022dc46836b359b2a11dfd6ac3f39f8c3c1fc9e SHA512 9d15d708ea399ea50502c97d4689b987e28222c81c6ca499969821532490b4eb19b67bab6b431081888c34f36d41d4f74e3611bd2103eecc31d5c6a559bcdf84

diff --git a/net-libs/libwebsockets/libwebsockets-4.0.0.ebuild b/net-libs/libwebsockets/libwebsockets-4.0.0.ebuild
new file mode 100644
index 00000000000..baeee47a7b2
--- /dev/null
+++ b/net-libs/libwebsockets/libwebsockets-4.0.0.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="A flexible pure-C library for implementing network protocols"
+HOMEPAGE="https://libwebsockets.org/"
+SRC_URI="https://github.com/warmcat/libwebsockets/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0/16" # libwebsockets.so.16
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="access-log caps cgi client dbus generic-sessions http-proxy http2 ipv6
+	+lejp libev libevent libressl libuv peer-limits server-status smtp socks5
+	sqlite3 ssl static-libs threads zip"
+
+REQUIRED_USE="
+	generic-sessions? ( smtp sqlite3 )
+	http-proxy? ( client )
+	smtp? ( libuv )
+	?? ( libev libevent )
+"
+
+RDEPEND="
+	sys-libs/zlib
+	caps? ( sys-libs/libcap )
+	http-proxy? ( net-libs/libhubbub )
+	libev? ( dev-libs/libev )
+	libevent? ( dev-libs/libevent:= )
+	libuv? ( dev-libs/libuv:= )
+	sqlite3? ( dev-db/sqlite:= )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl?  ( dev-libs/libressl:0= )
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-lang/perl"
+
+PATCHES=(
+	"${FILESDIR}/libwebsockets-3.2.0-check_chown_result.patch"
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Git=ON
+		-DLWS_HAVE_LIBCAP=$(usex caps)
+		-DLWS_IPV6=$(usex ipv6)
+		-DLWS_ROLE_DBUS=$(usex dbus)
+		-DLWS_WITHOUT_CLIENT=$(usex !client)
+		-DLWS_WITHOUT_TEST_CLIENT=$(usex !client)
+		-DLWS_WITH_ACCESS_LOG=$(usex access-log)
+		-DLWS_WITH_CGI=$(usex cgi)
+		-DLWS_WITH_GENERIC_SESSIONS=$(usex generic-sessions)
+		-DLWS_WITH_HTTP2=$(usex http2)
+		-DLWS_WITH_HTTP_PROXY=$(usex http-proxy)
+		-DLWS_WITH_HUBBUB=$(usex http-proxy)
+		-DLWS_WITH_LEJP=$(usex lejp)
+		-DLWS_WITH_LIBEV=$(usex libev)
+		-DLWS_WITH_LIBEVENT=$(usex libevent)
+		-DLWS_WITH_LIBUV=$(usex libuv)
+		-DLWS_WITH_PEER_LIMITS=$(usex peer-limits)
+		-DLWS_WITH_SERVER_STATUS=$(usex server-status)
+		-DLWS_WITH_SMTP=$(usex smtp)
+		-DLWS_WITH_SOCKS5=$(usex socks5)
+		-DLWS_WITH_SQLITE3=$(usex sqlite3)
+		-DLWS_WITH_SSL=$(usex ssl)
+		-DLWS_WITH_STATIC=$(usex static-libs)
+		-DLWS_WITH_THREADPOOL=$(usex threads)
+		-DLWS_WITH_ZIP_FOPS=$(usex zip)
+		-DLWS_WITHOUT_TESTAPPS=ON
+	)
+
+	cmake_src_configure
+}